home *** CD-ROM | disk | FTP | other *** search
/ Amiga Elysian Archive / AmigaElysianArchive.iso / comm / term23_2.lha / Source_Code / termSource / Format.asm < prev    next >
Assembly Source File  |  1992-08-18  |  3KB  |  113 lines
  1. *--------------------------------------------------------------------------
  2. *
  3. * $Id: Format.asm,v 1.3 92/08/15 20:12:44 olsen Sta Locker: olsen $
  4. * $Revision: 1.3 $
  5. * $Date: 92/08/15 20:12:44 $
  6. *
  7. * ANSI-`C' style string routines not necessarily to be found in amiga.lib
  8. *
  9. * Copyright © 1990-1992 by Olaf `Olsen' Barthel & MXM
  10. *    All Rights Reserved
  11. * 
  12. *--------------------------------------------------------------------------
  13.  
  14. CALL    macro
  15.     xref    _LVO\1
  16.     jsr    _LVO\1(a6)
  17.     endm
  18.  
  19.     csect    text,0,0,1,2
  20.  
  21. *--------------------------------------------------------------------------
  22.  
  23.     xdef    _SPrintf
  24.     xdef    _VSPrintf
  25.  
  26.     xdef    _atol
  27.  
  28. *--------------------------------------------------------------------------
  29.  
  30. _SPrintf:
  31.     movem.l    a2/a3/a6,-(sp)        ; Save registers
  32.  
  33.     move.l     4+12(sp),a3        ; Get destination buffer
  34.     move.l     8+12(sp),a0        ; Get format string
  35.     lea    12+12(sp),a1        ; Get arguments
  36.     lea    stuffchar(pc),a2    ; Get formatting routine
  37.  
  38.     move.l    4,a6            ; Get ExecBase
  39.     CALL    RawDoFmt        ; Format the string
  40.  
  41.     movem.l    (sp)+,a2/a3/a6        ; Restore registers
  42.  
  43.     rts
  44.  
  45. *--------------------------------------------------------------------------
  46.  
  47. _VSPrintf:
  48.     movem.l    a2/a3/a6,-(sp)
  49.  
  50.     move.l     4+12(sp),a3
  51.     move.l     8+12(sp),a0
  52.     move.l    12+12(sp),a1
  53.     lea    stuffchar(pc),a2
  54.  
  55.     move.l    4,a6
  56.     CALL    RawDoFmt
  57.  
  58.     movem.l    (sp)+,a2/a3/a6
  59.  
  60.     rts
  61.  
  62. stuffchar:
  63.     move.b    d0,(a3)+
  64.     rts
  65.  
  66. *--------------------------------------------------------------------------
  67. *
  68. *    A tiny replacement for atol(), implemented through StrToLong.
  69. *
  70. *--------------------------------------------------------------------------
  71.  
  72. _atol:    move.l    4(sp),d1    ; Save argument
  73.  
  74.     movem.l    d2/a6,-(sp)    ; Save registers
  75.  
  76.     pea.l    0        ; Push a zero on the stack
  77.  
  78.     lea.l    (sp),a0        ; Get a pointer to the value
  79.     move.l    a0,d2        ; Get it into a convenient register
  80.  
  81.     move.l    _DOSBase(a4),a6    ; Get DOSBase
  82.  
  83.     CALL    StrToLong    ; Convert the string
  84.  
  85.     move.l    (sp)+,d0    ; Get the conversion result
  86.  
  87.     movem.l    (sp)+,d2/a6    ; Restore registers
  88.  
  89.     rts
  90.  
  91. *--------------------------------------------------------------------------
  92. *
  93. *    These two lines are actually to make BLINK believe that some kind
  94. *    of startup code will clear the Data/BSS segment before running the
  95. *    main program. Since this is no longer necessary with Kickstart 2.x
  96. *    these two lines save about 34 KBytes of disk space.
  97. *
  98. *--------------------------------------------------------------------------
  99.  
  100.     lea    __BSSBAS,a0
  101.     move.l    #__BSSLEN,d0
  102.  
  103. *--------------------------------------------------------------------------
  104.  
  105.     csect    __MERGED
  106.  
  107.     xref    _DOSBase
  108.  
  109.     xref    __BSSBAS
  110.     xref    __BSSLEN
  111.  
  112.     end
  113.