home *** CD-ROM | disk | FTP | other *** search
/ Commodore 64 Scene Diskmags Assortment / Playback_07_1992_-_de.d64 / maskendemo (.txt) < prev    next >
Commodore BASIC  |  2023-02-26  |  2KB  |  89 lines
  1. 10 rem maskendemo===================c64
  2. 20 rem by alfons mittelmeyer
  3. 30 rem
  4. 40 rem c64
  5. 50 rem basic v2.0
  6. 60 rem ================================
  7. 70 gosub 110:gosub 180:goto 240
  8. 80 rem --------------------------------
  9. 90 rem  maschinenteil nachladen
  10. 100 rem -------------------------------
  11. 110 if peek(49154)=174thenreturn
  12. 120 sys57812"sysmc",8,0:poke780,0
  13. 130 poke781,254:poke782,191
  14. 140 sys65493:return
  15. 150 rem -------------------------------
  16. 160 rem  variablendefinition
  17. 170 rem -------------------------------
  18. 180 in=49465:at=49152
  19. 190 wo=49172:ef=49337
  20. 200 sf=49482:so=49497:return
  21. 210 rem ===============================
  22. 220 rem anwenderprogramm
  23. 230 rem -------------------------------
  24. 240 goto 800
  25. 250 rem -------------------------
  26. 260 rem feldausgabe
  27. 270 rem -------------------------
  28. 280 for i=0 to fz:sysat,fx%(i),fy%(i):print"<";
  29. 290 printw$left$(f$(i)+left$(le$,fz%(i)),fz%(i))g$">";
  30. 300 next:return
  31. 310 rem -----------------------
  32. 320 rem  feldeingabe
  33. 330 rem -----------------------
  34. 340 sysat,fx%(i)+1,fy%(i)
  35. 350 printw$;
  36. 360 sysef,fz%(i),n,f$(i)
  37. 370 printg$;
  38. 380 return
  39. 390 rem --------------------------
  40. 400 rem maskeneingabe
  41. 410 rem --------------------------
  42. 420 for i=0tofz
  43. 430 gosub 340
  44. 440 on n goto 480,460
  45. 450 next:return
  46. 460 ifi>0theni=i-1
  47. 470 goto430
  48. 480 i=fz:goto450
  49. 490 rem ---------------------------
  50. 500 rem felddatas
  51. 510 rem ---------------------------
  52. 520 fz=4:fori=0tofz
  53. 530 readfx%(i),fy%(i),fz%(i)
  54. 540 next:return
  55. 550 data 8,6,25
  56. 560 data 8,7,25
  57. 570 data 8,8,30
  58. 580 data 8,9,30
  59. 590 data 8,10,12
  60. 600 rem -------------------------
  61. 610 rem  textausgabe
  62. 620 rem -------------------------
  63. 630 sysat,11,3:print"[193]dressen"
  64. 640 sysat,11,4:print"--------"
  65. 650 sysat,0,6:print"[206]ame:"
  66. 660 sysat,0,7:print"[214]orname:"
  67. 670 sysat,0,8:print"[211]trasse:"
  68. 680 sysat,0,9:print"[207]rt:"
  69. 690 sysat,0,10:print"[212]elefon:"
  70. 700 return
  71. 710 rem ---------------------------
  72. 720 rem  variablendefinition
  73. 730 rem ---------------------------
  74. 740 le$="          ":le$=le$+le$
  75. 750 le$=le$+le$:cl$=chr$(147)
  76. 760 w$=chr$(5):g$=chr$(153):return
  77. 770 rem --------------------------
  78. 780 rem hauptprogramm
  79. 790 rem --------------------------
  80. 800 poke53280,0:rem rahmenfarbe
  81. 810 poke53281,0:rem hintergrundfarbe
  82. 820 gosub740:gosub520
  83. 830 printchr$(14)g$cl$:gosub630
  84. 840 gosub280:syssf:gosub420
  85. 850 printcl$w$"[197]rfasste [196]aten"g$
  86. 860 print:fori=0tofz:printf$(i):next
  87. 870 sysso:end
  88. 880 rem =====e n d e ==============
  89.