home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib42b.dsk / INPUT.DEMO.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  84 lines
  1. 10  REM   ********************
  2. 20  REM  *      AIU DEMO      *
  3. 30  REM  * BY H.B. CLYDE, JR. *
  4. 40  REM  *                    *
  5. 50  REM  * COPYRIGHT (C) 1992 *
  6. 60  REM  * MINDCRAFT PUBL. CO.*
  7. 70  REM   ********************
  8. 80  REM  **NOTE: BLOAD AIU BEFORE RUNNING THIS PROGRAM **
  9. 90  REM 
  10. 100 IN$ = " ": REM  MUST BE FIRST VARIABLE DEFINED
  11. 110  REM 
  12. 120  REM  SET UP ADDRESSES IN
  13. 130  REM  VARIABLES FOR EASY
  14. 140  REM  REFERENCING
  15. 150 PFG = 254: REM  PROMPT FLAG
  16. 160 MXL = 255: REM  MAX. LENGTH
  17. 170 AIU = 768: REM  THE ROUTINE
  18. 180  REM 
  19. 190  REM  ML%( ) CONTAINS NO. OF
  20. 200  REM  CHARACTERS ALLOWED FOR
  21. 210  REM  EACH OF THE 3 ENTRIES
  22. 220 ML%(1) = 20: REM  NAME-20
  23. 230 ML%(2) = 30: REM  ADDRESS-30
  24. 240 ML%(3) = 12: REM  PHONE-12
  25. 250  REM 
  26. 260  REM  DETERMINE WHETHER OR
  27. 270  REM  NOT TO PROMPT INPUT
  28. 280  REM  WITH UNDERLINES
  29. 290  HOME 
  30. 300  VTAB 10: HTAB 7: PRINT "DO YOU WANT UNDERLINE PROMPTS?";
  31. 310  GET P$
  32. 320  IF P$ < >"Y"  AND P$ < >"y"  AND P$ < >"N"  AND P$ < >"n"  THEN 310
  33. 330  IF P$ = "Y"  OR P$ = "y"  THEN  POKE PFG,1
  34. 340  IF P$ = "N"  OR P$ = "n"  THEN  POKE PFG,0
  35. 350  REM 
  36. 360  REM  CLEAR SCREEN, PRINT
  37. 370  REM  FIELD NAMES AND RESET
  38. 380  REM  THE CUSOR TO VTAB 1
  39. 390  HOME 
  40. 400  PRINT "NAME....:
  41. 410  PRINT "ADDRESS.:
  42. 420  PRINT "PHONE...:
  43. 430  VTAB 6: HTAB 10: PRINT "<ESC> RESTARTS LINE"
  44. 440  VTAB 1
  45. 450  REM 
  46. 460  REM  APPLESOFT INPUT USING
  47. 470  REM  INPUTS THE 3 LINES
  48. 480  FOR X = 1 TO 3
  49. 490  POKE MXL,ML%(X): REM  LENGTH
  50. 500  HTAB 10: REM  FOR INPUT
  51. 510  CALL AIU: REM  THE ROUTINE
  52. 520 A$(X) =  MID$ (IN$,1)
  53. 530  NEXT X
  54. 540  REM 
  55. 550  REM  NOW PROVE IT WORKS BY
  56. 560  REM  WRITING A$ ARRAY TO
  57. 570  REM  DISK AND READING THE
  58. 580  REM  DATA BACK AS B$ ARRAY
  59. 590  REM 
  60. 600  REM  NORMAL SYNTAX TO WRITE
  61. 610  VTAB 6: HTAB 7: INVERSE : PRINT "WRITING A$ (1-3) TO THE DISK"
  62. 620  PRINT  CHR$(4)"OPEN AIU.DEMO.TEXT"
  63. 630  PRINT  CHR$(4)"DELETE AIU.DEMO.TEXT"
  64. 640  PRINT  CHR$(4)"OPEN AIU.DEMO.TEXT"
  65. 650  PRINT  CHR$(4)"WRITE AIU.DEMO.TEXT"
  66. 660  FOR Y = 1 TO 3
  67. 670  PRINT A$(Y)
  68. 680  NEXT 
  69. 690  PRINT  CHR$(4)"CLOSE"
  70. 700  REM  
  71. 710  REM  CALL ROUTINE TO READ
  72. 720  VTAB 6: HTAB 7: INVERSE : PRINT "READING DATA BACK AS B$(1-3)": NORMAL 
  73. 730  PRINT  CHR$(4)"OPEN AIU.DEMO.TEXT"
  74. 740  PRINT  CHR$(4)"READ AIU.DEMO.TEXT"
  75. 750  FOR Y = 1 TO 3
  76. 760  CALL AIU:B$(Y) =  MID$ (IN$,1)
  77. 770  NEXT 
  78. 780  PRINT  CHR$(4)"CLOSE"
  79. 790  REM 
  80. 800  REM  THE FINAL PROOF
  81. 810  VTAB 6: HTAB 1: CALL  -868
  82. 820  FOR Z = 1 TO 3
  83. 830  PRINT "B$("Z")="B$(Z)
  84. 840  NEXT