home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Nibble Magazine
/
nib42a.dsk
/
JUNE.1992
/
WHICH.KEY.bas
< prev
Wrap
BASIC Source File
|
2023-02-26
|
2KB
|
37 lines
10 REM **********************
20 REM * WHICH KEY? *
30 REM * by Paul Raymer *
40 REM * and Mark Craven *
50 REM * Copyright (C) 1992 *
60 REM * MindCraft Publ. *
70 REM * Lincoln, MA 01773 *
80 REM **********************
90 TEXT : HOME : CLEAR
100 PRINT CHR$(4)"PR#3"
110 PRINT "WHICH KEY by Paul Raymer and Mark Craven": PRINT "Copyright (C) 1992, MindCraft Publ. Corp."
120 VTAB 4: POKE 1403,5: PRINT "Display contents of (49189)? ";: GET AN$: IF AN$ = "Y" OR AN$ = "y" THEN FLAG = 1
130 HOME
140 GOSUB 310
150 VTAB 5: POKE 1403,1: GET A$
160 IF A$ = CHR$(27) THEN 350
170 A = PEEK(49189)
180 IF FLAG THEN VTAB 3: POKE 1403,0: CALL -868: PRINT "PEEK (49189) = ";A
190 VTAB 5: POKE 1403,0
200 IF A = >128 THEN : PRINT "Apple key pressed":A = A -128
210 IF A = >64 THEN PRINT "Option Key pressed":A = A -64
220 IF A > = 32 THEN PRINT "Mystery Key!":A = A -32
230 IF A > = 16 THEN PRINT "Keypad key ";A$;" pressed":A = A -16
240 IF A > = 8 THEN PRINT "Repeat condition":A = A -8
250 IF A > = 4 THEN PRINT "Caps Lock on":A = A -4
260 IF A > = 2 THEN PRINT "Control key pressed":A = A -2
270 IF A = 1 THEN PRINT "Shift key pressed":A = A -1
280 IF A = 0 THEN PRINT : POKE 1403,26: PRINT "PRESS SPACE BAR TO CONTINUE ";: GET AN$: PRINT
290 POKE 49168,0
300 GOTO 130
310 VTAB 15: PRINT "Press ANY number of the following PLUS any character:"
320 PRINT : PRINT "Shift key, Control key, Caps Lock, any keypad key, Option key, Apple key or...hold any key for a while."
330 PRINT : POKE 1403,34: PRINT "(ESC) to quit"
340 RETURN
350 PRINT CHR$(4)"PR#0"
360 PRINT CHR$(27) CHR$(17)
370 HOME : END