home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib42a.dsk / JANUARY.1992 / TEXT.ENCRYPT.bas < prev   
BASIC Source File  |  2023-02-26  |  3KB  |  74 lines
  1. 10  REM  ***********************
  2. 20  REM  *     TEXT.ENCRYPT    *
  3. 30  REM  * Sample program for  *
  4. 40  REM  *     AmperCipher     *
  5. 50  REM  *   by Rich Skrenta   *
  6. 60  REM  *  Copyright (C) 1992 *
  7. 70  REM  * Mincraft Publ. Corp.*
  8. 80  REM  *  Lincoln, MA 01773  *
  9. 90  REM  ***********************
  10. 100  GOSUB 120: GOSUB 260: GOTO 600
  11. 110  REM  ** PRINT THE TITLE PAGE **
  12. 120  TEXT : HOME 
  13. 130  VTAB 2: HTAB 10: PRINT "TEXT FILE ENCRYPTOR"
  14. 140  HTAB 3: PRINT "A sample program for AmperCipher"
  15. 150  VTAB 5: HTAB 11: PRINT "by Richard Skrenta"
  16. 160  VTAB 8: HTAB 9: PRINT "Copyright (C) 1991, by"
  17. 170  HTAB 7: PRINT "MindCraft Publishing Corp."
  18. 180  REM  ** SET UP AMPERCIPHER **
  19. 190 D$ =  CHR$(4)
  20. 200  PRINT D$"BRUN AMPERCIPHER"
  21. 210  REM  ** WAIT FOR A 'RETURN' **
  22. 220  VTAB 16: PRINT "Insert the disk with your text file and press <Return>...";
  23. 230  GET A$: IF A$ < > CHR$(13)  THEN 230
  24. 240  PRINT : RETURN 
  25. 250  REM  ** PROMPT FOR OPERATION **
  26. 260  HOME : VTAB 8: HTAB 9: PRINT "E)ncrypt  or  D)ecrypt ?";
  27. 270  GET A$
  28. 280  IF A$ = "E"  THEN S = 1
  29. 290  IF A$ = "D"  THEN S = 2
  30. 300  IF S = 0  THEN  PRINT  CHR$(7);: GOTO 270
  31. 310  REM  ** GET INPUT FILESPEC **
  32. 320  HOME : VTAB 8: PRINT "Enter the name of the file that you wishto ";
  33. 330  IF S = 1  THEN  PRINT "encrypt:"
  34. 340  IF S = 2  THEN  PRINT "decrypt:"
  35. 350  PRINT : INPUT ">";F1$
  36. 360  IF  LEN(F1$) = 0  THEN  PRINT  CHR$(7): GOTO 320
  37. 370  REM  ** GET OUTPUT FILESPEC **
  38. 380  HOME : VTAB 8: PRINT "Enter the name of the file you want to  save the ";
  39. 390  IF S = 1  THEN  PRINT "en";
  40. 400  IF S = 2  THEN  PRINT "de";
  41. 410  PRINT "crypted text in:"
  42. 420  PRINT : INPUT ">";F2$
  43. 430  IF  LEN(F2$) = 0  THEN  PRINT  CHR$(7): GOTO 380
  44. 440  REM  ** GET THE PASSWORD STRING **
  45. 450  HOME : VTAB 8
  46. 460  PRINT "Enter the password that you wish to "
  47. 470  IF S = 1  THEN  PRINT "en";
  48. 480  IF S = 2  THEN  PRINT "de";
  49. 490  PRINT "crypt the file ";F1$;" with:"
  50. 500  PRINT : INPUT ">";P$
  51. 510  IF  LEN(P$) = 0  THEN  PRINT  CHR$(7): GOTO 450
  52. 520  REM  ** VERIFY INFORMATION **
  53. 530  HOME : VTAB 6
  54. 540  IF S = 1  THEN  PRINT "En";
  55. 550  IF S = 2  THEN  PRINT "De";
  56. 560  PRINT "crypting the file ";F1$
  57. 570  PRINT : PRINT "and storing the result in ";F2$;"..."
  58. 580  RETURN 
  59. 590  REM  ** WORK ON THE FILES... **
  60. 600  ONERR  GOTO 720
  61. 610  PRINT D$;"OPEN";F1$
  62. 620  PRINT D$;"OPEN";F2$
  63. 630  PRINT D$;"READ";F1$
  64. 640 A$ = ""
  65. 650  GET X$: IF X$ =  CHR$(13)  THEN 670
  66. 660 A$ = A$ +X$: GOTO 650
  67. 670  IF  LEN(A$) = 0  THEN 700
  68. 680  IF S = 1  THEN  & E,A$,P$: GOTO 700
  69. 690  & D,A$,P$
  70. 700  PRINT : PRINT D$;"WRITE";F2$
  71. 710  PRINT A$: GOTO 630
  72. 720  PRINT D$;"CLOSE";F1$
  73. 730  PRINT D$;"CLOSE";F2$
  74. 740  PRINT : PRINT "Done!": END