home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib41b.dsk / PHONETIC.CODER.bas < prev    next >
BASIC Source File  |  2023-02-26  |  1KB  |  45 lines

  1. 10  REM  *************************
  2. 12  REM  * PHONETIC.CODER        *
  3. 14  REM  * BY JOSEPH LARSON      *
  4. 16  REM  * COPYRIGHT (C) 1991    *
  5. 18  REM  * MINDCRAFT PUBL. CORP. *
  6. 20  REM  * LINCOLN, MA 01773     *
  7. 22  REM  *************************
  8. 30  DATA  A,0,B,1,C,2,D,3,E,0,F,1
  9. 40  DATA  G,2,H,0,I,0,J,2,K,2,L,4
  10. 50  DATA  M,5,N,5,O,0,P,1,Q,2,R,6
  11. 60  DATA  S,2,T,3,U,0,V,1,W,0,X,2
  12. 70  DATA  Y,0,Z,2
  13. 80  DIM CL$(26),CO$(26): PRINT "Phonetic Coder by Joseph Larson": PRINT "Copyright (C) 1991, MindCraft Publ.": PRINT 
  14. 90  FOR A = 1 TO 26
  15. 100  READ CL$(A): READ CO$(A)
  16. 110  NEXT A
  17. 120  PRINT "Enter a word to encode (ALL CAPS):"
  18. 130  INPUT IN$
  19. 140  IF  LEN(IN$) = 0  THEN  PRINT "Nothing to Encode": END 
  20. 150 PH$ = ""
  21. 160  FOR A = 1 TO 26
  22. 170  IF  LEFT$(IN$,1) = CL$(A)  THEN PH$ = PH$ +CL$(A)
  23. 180  NEXT A
  24. 190  IF  LEN(PH$) = 0  THEN  PRINT "Word must begin with a letter!": PRINT : GOTO 120
  25. 200  IF  LEN(IN$) = 1  THEN B = 2: GOTO 350
  26. 210 PR$ =  LEFT$(PH$,1): REM  PREVIOUS DIGIT
  27. 220 B = 2: REM  POSITION IN PH$
  28. 230  FOR A = 2 TO  LEN(IN$)
  29. 240 DIG$ = "0"
  30. 250  FOR C = 1 TO 26
  31. 260  IF  MID$ (IN$,A,1) = CL$(C)  THEN DIG$ = CO$(C)
  32. 270  NEXT C
  33. 280  IF DIG$ = "0"  THEN 340
  34. 290  IF DIG$ = PR$  THEN 340
  35. 300 PH$ = PH$ +DIG$
  36. 310 PR$ = DIG$
  37. 320 B = B +1
  38. 330  IF B >4  THEN 380
  39. 340  NEXT A
  40. 350  FOR A = B TO 4
  41. 360 PH$ = PH$ +"0"
  42. 370  NEXT A
  43. 380  PRINT "The Phonetic Code for ";IN$
  44. 390  PRINT "                   is ";PH$
  45. 400  PRINT : PRINT : GOTO 120