1530 XDRAW D1 +10 AT 114,100: XDRAW D2 +10 AT 144,100
1540 T = D1 +D2
1550 IF AR(T) = 1 THEN EN = 1: GOTO 1570
1560 AR(T) = 1:TS = TS +T:TR = TR +1:F = 1: ON T -1 GOSUB 1600,1610,1620,1630,1640,1650,1660,1680,1690,1710,1730:F = 0
1570 RETURN
1580 FOR K = 2 TO 12: IF AR(K) = 0 THEN ON K -1 GOSUB 1600,1610,1620,1630,1640,1650,1660,1680,1690,1710,1730
1590 NEXT : RETURN
1600 XDRAW 3 AT 15,42: RETURN
1610 XDRAW 4 AT 35,42: RETURN
1620 XDRAW 5 AT 55,42: RETURN
1630 XDRAW 6 AT 75,42: RETURN
1640 XDRAW 7 AT 95,42: RETURN
1650 XDRAW 8 AT 115,42: RETURN
1660 IF F = 0 THEN XDRAW 9 AT 135,42: HCOLOR= 0: HPLOT 136,44 TO 136,49: RETURN
1670 XDRAW 9 AT 135,42: HCOLOR= 3: HPLOT 136,44 TO 136,49: RETURN
1680 XDRAW 10 AT 155,42: RETURN
1690 XDRAW 2 AT 175,42
1700 XDRAW 1 AT 188,42: RETURN
1710 XDRAW 2 AT 208,42
1720 XDRAW 2 AT 221,42: RETURN
1730 XDRAW 2 AT 241,42
1740 XDRAW 3 AT 254,42: RETURN
1750 REM Instructions
1760 HOME :A$ = "HIGH ROLLER": INVERSE : GOSUB 2010:A$ = "===========": GOSUB 2010: NORMAL
1770 PRINT : PRINT "The object of HIGH ROLLER is to get a": PRINT "higher score than your opponent. Each": PRINT "player may roll the dice as many as 11"
1780 PRINT "times per turn. Each time that the dice are rolled, the number corresponding to"
1790 PRINT "total of the dice is removed from the": PRINT "tally board. After each roll the player may choose to roll again or end the"
1800 PRINT "current turn. Ending the turn will add": PRINT "the current points for the round to the": PRINT "player's game total."
1810 PRINT : PRINT "If a player continues to roll and rolls a combination that has been rolled priorduring the current turn, the player's"
1820 PRINT "turn ends and all the points from the": PRINT "current round are forfeit.": GOSUB 1880
1830 HOME : PRINT "Clearing all eleven numbers from the": PRINT "tally board scores a bonus of 77 points."
1840 PRINT "The game may be played between two": PRINT "people, or one person may play against": PRINT "the computer. Games may be 2 to 10": PRINT "rounds in length."
1850 PRINT : PRINT "At the end of the game the scores will": PRINT "be displayed and the winner will be": PRINT "given credit. In addition, if the": PRINT "scores are high enough, they will be"
1860 PRINT "placed on the HIGH ROLLER honor roll.": GOSUB 1880
1870 HOME : VTAB 12:A$ = "Good luck!!!": GOSUB 2010: FOR I = 1 TO 5000: NEXT : GOTO 270
1880 VTAB 23:A$ = "(M)ore or (G)ame ?": GOSUB 2010
1890 X = PEEK( -16384):I = RND(1)
1900 IF X = 205 OR X = 237 THEN POKE -16368,0: HOME : RETURN
1910 IF X = 199 OR X = 231 THEN POKE -16368,0: POP : GOTO 460
1920 GOTO 1890
1930 REM SUBROUTINE TO ADJUST SCORE SPACING
1940 IF PS <10 THEN HTAB 34: RETURN
1950 IF PS <100 THEN HTAB 33: RETURN
1960 HTAB 32: RETURN
1970 IF HS(I) <10 THEN HTAB 34: RETURN
1980 IF HS(I) <100 THEN HTAB 33: RETURN
1990 HTAB 32: RETURN
2000 REM CENTERING ROUTINE
2010 HTAB 20 - LEN(A$)/2: PRINT A$: RETURN
2020 REM ERROR HANDLING ROUTINE
2030 ER = PEEK(222)
2040 IF EL = 1 THEN 2130
2050 IF ER = 255 AND EL = 0 THEN 2170
2060 IF ER = 6 AND EL = 2 THEN 2090
2070 HOME : VTAB 12: PRINT "Error #"ER" has occurred.": PRINT "The error occurred in line " PEEK(218) + PEEK(219) *256".": PRINT : PRINT "Please refer to your BASIC and DOS manual."