home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib40b.dsk / REMEMBER.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  44 lines
  1. 10  REM  *************************
  2. 20  REM  * REMEMBER              *
  3. 30  REM  * BY D.D. JOHANNESEN    *
  4. 40  REM  * COPYRIGHT (C) 1991    *
  5. 50  REM  * MINDCRAFT PUBL. CORP. *
  6. 60  REM  * CONCORD, MA  01742    *
  7. 70  REM  *************************
  8. 80  DIM MN$(12),DM(12),ED(12)
  9. 90 D$ =  CHR$(4):CR$ =  CHR$(13):C$ = " CALENDAR"
  10. 100  HOME : VTAB 6
  11. 110  HTAB 12: PRINT "CALENDAR STARTUP": HTAB 11: PRINT "BY D.D. JOHANNESEN": HTAB 8: PRINT "(C) 1991 MINDCRAFT PUBL."
  12. 120  PRINT D$;"OPEN";C$
  13. 130  PRINT D$;"READ";C$
  14. 140  FOR I = 1 TO 12: INPUT MN$(I): INPUT DM(I): INPUT ED(I): NEXT 
  15. 150  FOR I = 0 TO 6: INPUT DY$(I): NEXT 
  16. 160  PRINT D$;"CLOSE";C$
  17. 170  READ Y
  18. 180 DT = (Y -1704) *365.25
  19. 190  IF DT =  INT(DT)  THEN SW = 1
  20. 200  PRINT CR$;"ENTER DATE PLEASE";CR$;" (M,D) - ";
  21. 210  INPUT M,D
  22. 220  IF M <1  OR M >12  OR D <1  OR D >(DM(M) +(M = 2  AND SW))  THEN  PRINT CR$;"INVALID DATE!";CR$: GOTO 200
  23. 230  POKE 768,M: POKE 769,D: POKE 770,Y -1900
  24. 240  HOME 
  25. 250 DY = ED(M) +D +(M >1  AND SW)
  26. 260  IF M = 12  THEN ED(1) = 365 +SW
  27. 270  ONERR  GOTO 370
  28. 280  READ EV$,ME,DE,YE
  29. 290 EV = ED(ME) +DE +(ME >1  AND SW)
  30. 300 DI = EV -DY: IF DI <0  OR DI >15  THEN 280
  31. 310 DA =  INT(DT) +ED(ME) -(ME <3  AND SW) +DE
  32. 320 DW =  INT(7 *(DA/7 - INT(DA/7)) +.5)
  33. 330  IF DI = 0  THEN  PRINT EV$;" IS TODAY.": GOTO 360
  34. 340  PRINT EV$;: IF  LEN(EV$ +DY$(DW)) >20  THEN  PRINT 
  35. 350  PRINT " WILL BE ";DY$(DW);"DAY, ";MN$(ME);" ";DE;CR$
  36. 360  GOTO 280
  37. 370  POKE 216,0: END 
  38. 380  DATA  1990
  39. 390  DATA  "APPLE EATER'S USER GROUP",11,10,90
  40. 400  DATA  "UNLCE SAM'S BIRTHDAY",7,4,1776
  41. 410  DATA  "TAXMAN",4,15,00
  42. 420  DATA  "AUNT TILLIE'S ANNIVERSARY",8,8,8
  43. 430  DATA  "VETERAN'S DAY",11,11,90
  44. 440  DATA  "CHRISTMAS",12,25,00