home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib39b.dsk / ENV.PRINTER.bas < prev    next >
BASIC Source File  |  2023-02-26  |  7KB  |  91 lines
  1. 10  REM    ******************************
  2. 20  REM    * ENV.PRINTER                *
  3. 30  REM    * BY BILL M. PUMPHREY        *
  4. 40  REM    * COPYRIGHT(C) 1990          *
  5. 50  REM    * MINDCRAFT PUBL. CORP.      *
  6. 60  REM    * CONCORD, MA 01742          *
  7. 70  REM    ******************************
  8. 80  PRINT  CHR$(21): HOME 
  9. 90  PRINT "ENVELOPE PRINTER BY BILL PUMPHREY": HTAB 2: PRINT "(C) 1990 MINDCRAFT PUBL. CORP.": POKE 34,3
  10. 100  VTAB 4: HTAB 1: PRINT "WHAT TYPE OF PRINTER ARE YOU USING": PRINT "E FOR EPSON OR I FOR IMAGEWRITER (E,I)?";: GET P$: PRINT : PRINT : IF P$ = "E"  OR P$ = "e"  THEN IP = 0: GOTO 590
  11. 110  IF P$ = "I"  OR P$ = "i"  THEN IP = 1: GOTO 590
  12. 120  GOTO 100
  13. 130  HOME : VTAB 7: PRINT "BEFORE INSERTING ENVELOPE INTO PRINTER, PUT PIECE OF PAPER UNDER THE FLAP,      PROTRUDING DOWN SO THAT IT WILL SUPPRESSTHE PAPER OUT CONTROL.": PRINT 
  14. 140  PRINT "WITH PRINTER POWER OFF, INSERT ENVELOPE INTO PRINTER AND SCROLL IT UP UNTIL IT  CAN BE RETAINED BY THE PAPERBAIL."
  15. 150  PRINT 
  16. 160  IF E$ < >""  THEN  PRINT "DO YOU WANT THE SAME ";: INVERSE : PRINT "RETURN";: NORMAL : PRINT " ADDRESS AS  PREVIOUSLY PRINTED? Y/N ";: GET Z$: IF Z$ = "Y"  OR Z$ = "y"  THEN 280
  17. 170  PRINT : PRINT : PRINT "IF YOU WANT YOUR RETURN ADDRESS TYPED INTHE UPPER LEFT HAND CORNER, TYPE 'Y'.";: GET Z$: PRINT : IF Z$ < >"Y"  AND Z$ < >"y"  THEN 320
  18. 180  HOME 
  19. 190  PRINT  TAB( 13);: PRINT "RETURN ADDRESS": NORMAL : PRINT 
  20. 200  PRINT " USE NO COMMAS!!!  ENTER 'E' TO RETURN   TO THE PREVIOUS ENTRY FOR CORRECTION   "
  21. 210  PRINT 
  22. 220  INPUT "RETURN NAME ";A$
  23. 230  INPUT "RETURN COMPANY ";B$: IF B$ = "E"  OR B$ = "e"  THEN  PRINT : GOTO 220
  24. 240  INPUT "RETURN ADDRESS ";C$: IF C$ = "E"  OR C$ = "e"  THEN  PRINT : GOTO 230
  25. 250  INPUT "RETURN CITY ";D$: IF D$ = "E"  OR D$ = "e"  THEN  PRINT : GOTO 240
  26. 260  INPUT "RETURN STATE & ZIP & COUNTRY (IF APPLI- CABLE) ";E$: IF E$ = "E"  OR E$ = "e"  THEN  PRINT : GOTO 250
  27. 270  PRINT : PRINT "RETURN TO PRINT/ENTER 'E' TO START OVER";: GET Z$: PRINT : IF Z$ = "E"  OR Z$ = "e"  THEN  NORMAL : GOTO 180
  28. 275  IF  PEEK(48896) < >76  THEN  PRINT  CHR$(13)
  29. 280  HOME : PRINT  CHR$(4)"PR#1": IF A$ < >""  THEN  PRINT A$
  30. 290  IF B$ < >""  THEN  PRINT B$
  31. 300  IF C$ < >""  THEN  PRINT C$
  32. 310  PRINT D$;", ";E$: PRINT  CHR$(4)"PR# 0"
  33. 320  IF A < >0  THEN  HOME : VTAB 12: PRINT "DO YOU WANT THE SAME VERTICAL SPACING   AND TABULATION AS PREVIOUSLY? Y/N ";: GET Z$: IF Z$ = "Y"  OR Z$ = "y"  THEN 380
  34. 330  IF A < >0  AND (Z$ = "N"  OR Z$ = "n")  THEN  HOME : VTAB 12
  35. 340  HOME : PRINT "ENTER NUMBER OF LINES BELOW THE CURRENT PRINTER HEAD POSITION WHERE YOU WANT TO START PRINTING THE ADDRESS": PRINT "(5 WITH RETURN ADDRESS": INPUT "10 WITHOUT RETURN ADDRESS)";A
  36. 350  PRINT : PRINT "ENTER THE NUMBER OF SPACES TO INDENT    FROM THE LEFT MARGIN": PRINT "(20 FOR SMALL ENVELOPES": INPUT "35 FOR BUSINESS ENVELOPES)";B
  37. 360  IF A = 0  THEN A = 1
  38. 370  IF B = 0  THEN B = 1
  39. 380  HOME 
  40. 390  PRINT  TAB( 12);: PRINT "ADDRESSEE ADDRESS": NORMAL : PRINT 
  41. 400  PRINT : PRINT " USE NO COMMAS!!!  ENTER 'E' TO RETURN   TO THE PREVIOUS ENTRY FOR CORRECTION   ": NORMAL 
  42. 410  INPUT "NAME ";F$
  43. 420  INPUT "TITLE ";G$: IF G$ = "E"  THEN  PRINT : GOTO 410
  44. 430  INPUT "COMPANY ";H$: IF H$ = "E"  THEN  PRINT : GOTO 420
  45. 440  INPUT "ADDRESS ";I$: IF I$ = "E"  THEN  PRINT : GOTO 430
  46. 450  INPUT "CITY ";J$: IF J$ = "E"  THEN  PRINT : GOTO 440
  47. 460  PRINT "STATE & ZIP & COUNTRY (IF APPLICABLE) ": INPUT "";K$: IF K$ = "E"  OR K$ = "e"  THEN  PRINT : GOTO 450
  48. 470  PRINT : INVERSE : PRINT "RETURN TO PRINT/ENTER 'E' TO START OVER";: NORMAL : GET Z$: PRINT : IF Z$ = "E"  OR Z$ = "e"  THEN 380
  49. 475  IF  PEEK(48896) < >76  THEN  PRINT  CHR$(13)
  50. 480  PRINT  CHR$(4)"PR# 1"
  51. 490  FOR I = 1 TO (A -1): PRINT : NEXT I
  52. 500  PRINT  TAB( B);F$;
  53. 510  IF G$ = ""  THEN  PRINT : GOTO 530
  54. 520  PRINT ", ";G$
  55. 530  IF H$ < >""  THEN  PRINT  TAB( B);H$
  56. 540  PRINT  TAB( B);I$
  57. 550  PRINT  TAB( B);J$;", ";: PRINT K$
  58. 560  PRINT  CHR$(4)"PR# 0"
  59. 570  HOME : VTAB 12: PRINT "      ENTER 'R' TO                        RETURN TO TYPE ANOTHER ENVELOPE  ";: GET Z$: PRINT : IF Z$ = "r"  OR Z$ = "R"  THEN 130
  60. 580  END 
  61. 590  HOME 
  62. 600  VTAB 4: HTAB 1: PRINT "CHOOSE ONE OF EACH OPTION.              PRINTER DEFAULTS ARE 'S'  AND '1'.      TURN ON YOUR PRINTER."
  63. 610  VTAB 8: INVERSE : PRINT "            PRINT INTENSITY             ": NORMAL 
  64. 620  PRINT "     S = SINGLE STRIKE (NORMAL)"
  65. 630  PRINT "     D = DOUBLE STRIKE (EPSON ONLY)"
  66. 640  PRINT "     E = EMPHASIZED TYPE "
  67. 650  PRINT : INVERSE : PRINT "                TYPE SIZE               ": NORMAL 
  68. 660  PRINT "1 = NORMAL WIDTH TYPE (10 CPI)"
  69. 670  PRINT "2 = NORMAL WIDTH/COMPRESSED (17 CPI)"
  70. 680  PRINT "3 = DOUBLE WIDTH (5 CPI)"
  71. 690  PRINT "4 = DOUBLE WIDTH/COMPRESSED (8 CPI)"
  72. 700  PRINT : INVERSE : PRINT "    ENTER 'C' TO CONTINUE               ";
  73. 710  NORMAL : PRINT : PRINT "YOUR CHOICES: ";: GET Z$: PRINT Z$
  74. 720  IF (Z$ = "S"  OR Z$ = "s")  AND   NOT IP  THEN  PRINT  CHR$(4)" PR# 1": PRINT  CHR$(27) CHR$(70) CHR$(27) CHR$(72): PRINT "NORMAL TYPE": PRINT  CHR$(4)" PR# 0": GOTO 590
  75. 730  IF (Z$ = "S"  OR Z$ = "s")  AND IP  THEN  PRINT  CHR$(4)"PR#1": PRINT  CHR$(27); CHR$(78) CHR$(27) CHR$(34) CHR$(15): PRINT "NORMAL TYPE": PRINT  CHR$(4)"PR#0": GOTO 590
  76. 740  IF (Z$ = "D"  OR Z$ = "d")  AND   NOT IP  THEN  PRINT  CHR$(4)" PR# 1": PRINT  CHR$(27) CHR$(71): PRINT "DOUBLE STRIKE": PRINT  CHR$(4)" PR# 0": GOTO 590
  77. 750  IF (Z$ = "E"  OR Z$ = "e")  AND   NOT IP  THEN  PRINT  CHR$(4)" PR# 1": PRINT  CHR$(27) CHR$(72) CHR$(27) CHR$(69): PRINT "EMPHASIZED TYPE": PRINT  CHR$(4)" PR# 0": GOTO 590
  78. 760  IF (Z$ = "E"  OR Z$ = "e")  AND IP  THEN  PRINT  CHR$(4)"PR#1": PRINT  CHR$(27); CHR$(33): PRINT "BOLDFACE": PRINT  CHR$(4)" PR# 0": GOTO 590
  79. 770  IF Z$ = "1"  AND   NOT IP  THEN  HOME : PRINT  CHR$(4)" PR# 1": PRINT  CHR$(20): PRINT  CHR$(18): PRINT "NORMAL WIDTH": PRINT  CHR$(4)" PR# 0": GOTO 590
  80. 780  IF Z$ = "1"  AND IP  THEN  PRINT  CHR$(4)"PR#1": PRINT  CHR$(15): PRINT  CHR$(27) CHR$(78): PRINT "NORMAL WIDTH": PRINT  CHR$(4)"PR#0": GOTO 590
  81. 790  IF Z$ = "2"  AND   NOT IP  THEN  HOME : PRINT  CHR$(4)" PR# 1": PRINT  CHR$(27) CHR$(70) CHR$(27) CHR$(72) CHR$(15): PRINT "NORMAL WIDTH COMPRESSED": PRINT  CHR$(4)" PR# 0": GOTO 590
  82. 800  IF Z$ = "2"  AND IP  THEN  PRINT  CHR$(4)"PR#1": PRINT  CHR$(15): PRINT  CHR$(27) CHR$(81): PRINT "NORMAL WIDTH COMPRESSED": PRINT  CHR$(4)"PR#0": GOTO 590
  83. 810  IF Z$ < >"3"  THEN 840
  84. 820  IF   NOT IP  THEN  PRINT  CHR$(4)"PR#1": PRINT  CHR$(14): PRINT "DOUBLE WIDTH";: PRINT  CHR$(14): PRINT  CHR$(4)"PR#0": GOTO 590
  85. 830  PRINT  CHR$(4)"PR#1": PRINT  CHR$(27) CHR$(78): PRINT  CHR$(14): PRINT "DOUBLE WIDTH": PRINT  CHR$(4)"PR#0": GOTO 590
  86. 840  IF Z$ < >"4"  THEN 870
  87. 850  IF   NOT IP  THEN  PRINT  CHR$(4)" PR# 1": PRINT  CHR$(27) CHR$(70) CHR$(27) CHR$(72) CHR$(15): PRINT "DOUBLE WIDTH COMPRESSED": PRINT  CHR$(4)" PR# 0": GOTO 590
  88. 860  PRINT  CHR$(4)"PR#1": PRINT  CHR$(14) CHR$(27) CHR$(81): PRINT "DOUBLE WIDTH COMPRESSED": PRINT  CHR$(4)"PR#0": GOTO 590
  89. 870  IF Z$ = "C"  OR Z$ = "c"  THEN 130
  90. 880  IF Z$ < >"C"  AND Z$ < >"c"  THEN 590
  91. 890  HOME : END