home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib38a.dsk / FEBRUARY.1990 / DHR.PROGRAM.bas next >
BASIC Source File  |  2023-02-26  |  2KB  |  43 lines
  1. 10  REM  *************************
  2. 20  REM  * DHR.PROGRAM           *
  3. 30  REM  * BY ROGER WAGNER       *
  4. 40  REM  * COPYRIGHT(C) 1990     *
  5. 50  REM  * MINDCRAFT PUBL. CORP. *
  6. 60  REM  * CONCORD, MA. 01742    *
  7. 70  REM  *************************
  8. 80  REM  DOUBLE HI-RES PROGRAM
  9. 90 D$ =  CHR$(4)
  10. 100  HGR 
  11. 110  POKE 49246,0: REM  $C05E = DHR "ON"
  12. 120  REM  LOAD AUX BANK PART OF IMAGE
  13. 130  POKE 49153,0: REM  $C001 = ENABLE 80STORE
  14. 140  POKE 49237,0: REM  $C055 = PG2 = AUX BANK
  15. 150  PRINT D$;"BLOADPICTURE2,A$2000,L$2000"
  16. 160  REM  LOAD MAIN BANK PART OF IMAGE
  17. 170  POKE 49152,0: REM  $C000 = 80STORE = PAGE2 USE
  18. 180  POKE 49236,0: REM  $C054 = PG1 = MAIN BANK
  19. 190  PRINT D$;"BLOADPICTURE2,A$2000,L$2000,B$2000"
  20. 200  REM  "B$2000" LOADS PART OF FILE STARTING FROM BYTE $2000
  21. 210  REM  USER PROGRAM HERE THAT CREATES NEW SCREEN
  22. 220  REM  SAMPLE: HERE'S SOME BRUTE-FORCE CODE TO DRAW
  23. 230  REM  ON THE DHR SCREEN WITH POKES
  24. 240  POKE 49153,0: REM  ENABLE BANK USE OF PG2 SW
  25. 250  FOR H = 20 TO 60: REM  SCREEN HAS 80 BYTE POSITIONS
  26. 260  IF H/2 < > INT(H/2)  THEN 300: REM  LINE 300 IF H IS ODD
  27. 270  POKE 49237,0: REM  ENABLE AUX BANK
  28. 280  POKE 8744 +H/2,255: REM  PUT BYTE ON SCREEN
  29. 290  GOTO 320
  30. 300  POKE 49236,0: REM  ENABLE MAIN BANK
  31. 310  POKE 8744 +H/2,255: REM  PUT BYTE ON SCREEN
  32. 320  NEXT H
  33. 330  POKE 49152,0: REM  RESTORE NORMAL PG2 SW USE
  34. 340  REM  SAVE NEW DHR SCREEN
  35. 350  REM  SAVE AUX BANK PART OF IMAGE
  36. 360  POKE 49153,0: REM  $C001 = ENABLE 80STORE
  37. 370  POKE 49237,0: REM  $C055 = PG2 = AUX BANK
  38. 380  PRINT D$;"BSAVE PICTURE2,A$2000,L$2000"
  39. 390  REM  SAVE MAIN BANK PART OF IMAGE
  40. 400  POKE 49152,0: REM  $C000 = 80STORE = PAGE2 USE
  41. 410  POKE 49236,0: REM  $C054 = PG1 = MAIN BANK
  42. 420  PRINT D$;"BSAVE PICTURE2,A$2000,L$2000,B$2000"
  43. 430  REM  "B$2000" SAVES PART OF FILE STARTING AT BYTE $2000