home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib36b.dsk / SETUP.bas < prev    next >
BASIC Source File  |  2023-02-26  |  3KB  |  58 lines
  1. 10  REM  ************************
  2. 20  REM  * SETUP                *
  3. 30  REM  * BY PAUL MEYERS       *
  4. 40  REM  * COPYRIGHT (C) 1989   *
  5. 50  REM  * MINDCRAFT PUBL. CORP.*
  6. 60  REM  * CONCORD, MA 01742    *
  7. 70  REM  ************************
  8. 80  ONERR  GOTO 580
  9. 90  IF  PEEK(718) < >169  THEN  PRINT  CHR$(4)"BRUN SUPER.CURSOR": POKE 216,0
  10. 100  CALL 718
  11. 110  HOME 
  12. 120 CL =  PEEK( -16353)
  13. 130  IF CL <127  THEN CW = 40: GOTO 150
  14. 140 CW = 80
  15. 150  FOR I = 1 TO CW: PRINT "*";: NEXT 
  16. 160  PRINT "*";: POKE 36, -1 +CW: PRINT "*";
  17. 170  PRINT "*";
  18. 180 A$ = "SUPER.CURSOR": GOSUB 550
  19. 190  POKE 36, -1 +CW: PRINT "*";
  20. 200  PRINT "*";:A$ = "By Paul Meyers": GOSUB 550
  21. 210  POKE 36, -1 +CW: PRINT "*";
  22. 220  PRINT "*";:A$ = "COPYRIGHT (C) 1989": GOSUB 550: POKE 36, -1 +CW: PRINT "*";
  23. 230  PRINT "*";:A$ = "MINDCRAFT PUBL. CORP. ": GOSUB 550: POKE 36, -1 +CW: PRINT "*";
  24. 240  PRINT "*";: POKE 36, -1 +CW: PRINT "*";
  25. 250  FOR I = 1 TO CW: PRINT "*";: NEXT 
  26. 260  PRINT : PRINT 
  27. 270  POKE 36,0
  28. 280 C =  PEEK(963): POKE 36,0: VTAB 10: PRINT "The current character is ";: IF C < = 127  THEN C = C +128
  29. 290  PRINT  CHR$(C)
  30. 300 L =  PEEK(964): VTAB 11: CALL  -868: PRINT "The speed is "L
  31. 310 F =  PEEK(965): VTAB 12: POKE 36,0: CALL  -868: PRINT "The flash option is ";: IF F <128  THEN  PRINT "on": GOTO 330
  32. 320  PRINT "off"
  33. 330 T =  PEEK(966): VTAB 13: POKE 36,0: CALL  -868: PRINT "The twirl option is ";: IF T >127  THEN  PRINT "on": GOTO 350
  34. 340  PRINT "off"
  35. 350  PRINT : POKE 36,3: PRINT "1-Change character"
  36. 360  POKE 36,3: PRINT "2-Change speed"
  37. 370  POKE 36,3: PRINT "3-Change flash option"
  38. 380  POKE 36,3: PRINT "4-Change twirl option"
  39. 390  POKE 36,3: PRINT "5-Quit"
  40. 400  VTAB 21: POKE 36,0: CALL  -868: PRINT "Please enter choice:";: GET A$: PRINT A$:A =  VAL(A$): IF A <1  OR A >5  THEN  PRINT  CHR$(7): GOTO 400
  41. 410  ON A GOTO 420,440,460,490,530
  42. 420  GOSUB 570: INPUT "New character value:";N: IF N <0  OR N >255  THEN 420
  43. 430  POKE 963,N: GOTO 270
  44. 440  GOSUB 570: INPUT "New speed for the cursor:";S: IF S <0  OR S >255  THEN 440
  45. 450  POKE 964,S: GOTO 270
  46. 460  GOSUB 570: PRINT "Flash on? (Y/N):";: GET F$: IF F$ < >"Y"  AND F$ < >"y"  AND F$ < >"N"  AND F$ < >"n"  THEN 460
  47. 470  IF F$ = "Y"  OR F$ = "y"  THEN  POKE 965,1: GOTO 270
  48. 480  POKE 965,255: GOTO 270
  49. 490  GOSUB 570: PRINT "Twirl on? (Y/N):";
  50. 500  GET T$: PRINT T$: IF T$ < >"Y"  AND T$ < >"y"  AND T$ < >"N"  AND T$ < >"n"  THEN 490
  51. 510  IF T$ = "Y"  OR T$ = "y"  THEN  POKE 966,255: GOTO 270
  52. 520  POKE 966,1: GOTO 270
  53. 530  GOSUB 570: PRINT "Are you sure?";: GET A$: IF A$ = "Y"  THEN  HOME : POKE 216,0: END 
  54. 540  POKE 36,0: CALL  -868: GOTO 400
  55. 550 S =  INT((CW - LEN(A$))/2)
  56. 560  POKE 36, -1 +S: PRINT A$;: RETURN 
  57. 570  POKE 36,0: VTAB 21: CALL  -868: RETURN 
  58. 580  HOME : PRINT  CHR$(7): PRINT "Disk error": PRINT "Please check disk or replace with disk  that contains the file Super.Cursor"