home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib33b.dsk / HUNGRY.DOT.DEMO.bas < prev    next >
Encoding:
BASIC Source File  |  1990-01-01  |  1.3 KB  |  41 lines
  1. 10  POKE 768,1: POKE 769,0: POKE 770,4
  2. 20  POKE 771,0: POKE 772,4: POKE 773,0
  3. 30  POKE 232,0: POKE 233,3: REM  $E8,E9=$300
  4. 40  REM  SET UP SCREEN
  5. 50  HGR : ROT= 0: SCALE= 1
  6. 60  POKE  -16302,0: REM  FULL SCREEN DISPLAY
  7. 70  HCOLOR= 3: HPLOT 0,0: REM  PLOT A POINT
  8. 80  CALL 62454: REM  CLEAR TO COLOR
  9. 90  HCOLOR= 0
  10. 100  FOR Y = 56 TO 136: REM  ERASE CENTER
  11. 110  HPLOT 80,Y TO 200,Y
  12. 120  NEXT Y
  13. 130  REM  DRAW BORDER
  14. 140  HPLOT 0,0 TO 279,0 TO 279,191 TO 0,191 TO 0,0
  15. 150  HPLOT 3,3 TO 276,3 TO 276,188 TO 3,188 TO 3,3
  16. 160  HPLOT 4,4 TO 275,4 TO 275,187 TO 4,187 TO 4,4
  17. 170  HCOLOR= 3
  18. 180  REM  SET UP SHAPES & VELOCITIES
  19. 190  FOR I = 1 TO 25: REM  DRAW 'STARS'
  20. 200 X = 120 - RND(1) *120 +80
  21. 210 Y = 80 - RND(1) *80 +56
  22. 220  HPLOT X,Y
  23. 230  NEXT I
  24. 240 XV = 1:YV = 1:X = 140:Y = 96
  25. 250  ONERR  GOTO 390
  26. 260  REM  MOVE IT AROUND
  27. 270  XDRAW 1 AT X,Y
  28. 280 YV = YV +.005: REM  'GRAVITY'
  29. 290  IF  PEEK( -16384) >127  THEN  TEXT : END 
  30. 300  IF  PEEK(234) = 0  THEN 340: REM  COLLISION
  31. 310  XDRAW 1 AT X,Y
  32. 320 X = X +XV:Y = Y +YV
  33. 330  GOTO 260
  34. 340  REM  RE-CALC VELOCITY
  35. 350 XV = 1 - RND(1) *2: IF  ABS(XV) <.5  THEN XV = XV *2
  36. 360 YV = 1 - RND(1) *2: IF  ABS(YV) <.5  THEN YV = YV *2
  37. 370 S =  PEEK( -16336) + PEEK( -16336) + PEEK( -16336)
  38. 380  GOTO 260
  39. 390  REM  BOUNDARY COLLISION ('ILLEGAL QTY ERROR')
  40. 400 X = 140:Y = 96
  41. 410  GOTO 260