home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib33b.dsk / DEMO.PROGRAM.bas < prev    next >
BASIC Source File  |  2023-02-26  |  3KB  |  38 lines
  1. 10  REM   *********************
  2. 20  REM   * PRINTWORKS        *
  3. 30  REM   * DEMO.PROGRAM      *
  4. 40  REM   * BY BOB THRASHER   *
  5. 50  REM   * COPYRIGHT(C) 1988 *
  6. 60  REM   * MICROSPARC, INC   *
  7. 70  REM   * CONCORD, MA 01742 *
  8. 80  REM   *********************
  9. 90  HIMEM: 8192 -1024 *( PEEK(48896) = 76):PF = ( PEEK(48896) = 76): PRINT  CHR$(12) CHR$(21): HGR :D$ =  CHR$(4): PRINT D$"BRUNPRINTWORKS": IF PF  THEN  PRINT D$"PR#A$30A"
  10. 100  ONERR  GOTO 300
  11. 110  POKE 775,1: TEXT : HOME : PRINT "PRINTWORKS DETAILED DEMO": PRINT "COPYRIGHT(C) 1988 MICROSPARC, INC.": FOR X = 1 TO 34: PRINT "=";: NEXT : PRINT : PRINT 
  12. 120  PRINT "Enter FILENAME of font to display:": PRINT : PRINT "Enter  ?  for a disk CATALOG": PRINT : PRINT "(press RETURN alone to QUIT)": PRINT : INPUT ":>";N$: IF N$ = ""  THEN  HOME : END 
  13. 130  IF  LEFT$(N$,1) = "?"  THEN 250
  14. 140  IF  LEN(N$) >(30 -15 *PF)  THEN  PRINT : PRINT "Filename too long...": PRINT : GOSUB 240: GOTO 110
  15. 150  PRINT : PRINT D$"BLOAD"N$",A$7000": POKE 788,0: POKE 789,112: POKE 777,0: POKE 775,2
  16. 160  CALL 782: FOR X = 0 TO 5: POKE 768,X *10: FOR Y = 0 TO 15: POKE 769,0: POKE 770,Y *2 +4: PRINT  CHR$(X *16 +Y +32);: NEXT : NEXT 
  17. 170  FOR X = 0 TO 2: POKE 768,65 +X *9: POKE 769,0: POKE 770,0: POKE 772,X +1: PRINT "Sample printing.  Horiz. leading="X +1: NEXT : POKE 772,1
  18. 180  POKE 768,95: POKE 769,0: POKE 770,0: FOR X = 0 TO 4  STEP 2: POKE 771,X: PRINT "Sample printing.  Vert. leading="X: NEXT : POKE 771,1
  19. 190 A$ = "An example of vertical print control": POKE 769,0: POKE 770,0: FOR X = 1 TO  LEN(A$): POKE 768,130 + SIN(X/4) *5: PRINT  MID$ (A$,X,1);: NEXT 
  20. 200  POKE 768,150: FOR X = 0 TO 3: POKE 769,X: POKE 770,0: PRINT "Horiz. print control": NEXT 
  21. 210  HCOLOR= 3: FOR X = 150 TO 190: HPLOT 140,X TO 279,X: NEXT : POKE 773,255: POKE 768,153
  22. 220  POKE 770,22: PRINT "An example of": POKE 770,22: PRINT "Inverse printing": POKE 770,22: PRINT "ABCDEFGHI": POKE 770,22: PRINT "1234567890": POKE 773,0
  23. 230  GET A$: PRINT : GOTO 110
  24. 240  PRINT "Press ANY KEY to continue :";: GET A$: PRINT : RETURN 
  25. 250  PRINT : PRINT : PRINT "CATALOG by SLOT,DRIVE";: IF PF  THEN  PRINT " or PREFIX:";
  26. 260  PRINT "?";: GET A$: PRINT A$: PRINT : IF A$ = "P"  THEN 280
  27. 270  PRINT  LEFT$("CATALOG",7 -4 *PF)",S";: GOSUB 370:CS = A: PRINT A",D";: GOSUB 370:CD = A: PRINT A: PRINT : PRINT D$; LEFT$("CATALOG",7 -4 *PF)",S"CS",D"CD: GOSUB 240: GOTO 110
  28. 280  PRINT "Enter complete prefix:": INPUT ":>";A$: IF  LEFT$(A$,1) < >"/"  THEN A$ = "/" +A$
  29. 290  PRINT : PRINT D$"CAT"A$: GOSUB 240: GOTO 110
  30. 300  IF  PEEK(222) = 255  THEN  RESUME 
  31. 310  TEXT : HOME :ER =  PEEK(222):LN =  PEEK(218) + PEEK(219) *256: IF ER = 16  OR ER >21  THEN  PRINT "APPLESOFT";: GOTO 330
  32. 320  PRINT "DOS or ProDOS";
  33. 330  PRINT " error # "ER" in line # "LN: PRINT : IF ER = 6  THEN  PRINT "Either the file was not found,": PRINT "or the DISK selected is not online"
  34. 340  IF ER = 8  THEN  PRINT "I/O error during file load"
  35. 350  IF ER = 3  THEN  PRINT "Device not connected"
  36. 360  PRINT "PRESS A KEY TO CONTINUE";: GET A$: GOTO 110
  37. 370  GET A$:A =  VAL(A$): IF A <1  OR A >7  THEN 370
  38. 380  RETURN