home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib32b.dsk / START.CLIPART.bas < prev    next >
BASIC Source File  |  2023-02-26  |  5KB  |  84 lines
  1. 10  REM  **************************
  2. 20  REM  **************************
  3. 30  REM  **                      **
  4. 40  REM  ** START.CLIPART        **
  5. 50  REM  ** by Robert C. Moore   **
  6. 60  REM  **                      **
  7. 70  REM  **                      **
  8. 80  REM  **  Copyright (c) 1987  **
  9. 90  REM  **  by MicroSPARC, Inc. **
  10. 100  REM **  Concord, MA  01742  **
  11. 110  REM **                      **
  12. 120  REM **************************
  13. 130  REM **************************
  14. 140 :
  15. 150  REM  START.CLIPART program
  16. 160  REM  for Nibble Clip Art
  17. 170 :
  18. 180  ONERR  GOTO 790
  19. 190 D$ =  CHR$(4):V$ = "VERIFY":B$ = ",S6,D1": PRINT D$V$"GALLERY"B$: PRINT D$V$"CLIP.ART": PRINT D$V$"START.CLIPART": PRINT D$V$"BACKGROUND": PRINT D$V$"UNPACK.FAST"
  20. 200  PRINT D$V$"PICFILE.CREATE": PRINT D$V$"UPK.OBJ"
  21. 210  PRINT  CHR$(7) CHR$(7)
  22. 220 :
  23. 230  POKE 216,0: GOSUB 610:R$ = ",S3,D2": POKE 966,0:DOS = 0: IF  PEEK(978) < >190  THEN DOS = 1: POKE 966,1:R$ = ",S3,D1"
  24. 240  ONERR  GOTO 680
  25. 250  IF  PEEK(230) = 32  AND  PEEK(966) <2  AND  PEEK(967) <2  AND  PEEK(968) = 85  AND  PEEK(969) = 170  AND  PEEK(970) = 225 GOTO 410
  26. 260  FOR L = 0 TO 3: POKE 8188 +L, PEEK(60 +L): NEXT 
  27. 270  POKE 230,32: POKE 968,85: POKE 969,170: POKE 970,225: IF DOS  THEN  PRINT D$"BLOAD RAMCHECK"B$: POKE 807, VAL( MID$ (R$,6,1)): POKE 808,16 * VAL( MID$ (R$,3,1)): CALL 768: POKE 967,1 - PEEK(6): GOTO 320
  28. 280  ONERR  GOTO 300
  29. 290  PRINT D$"VERIFY/RAM": POKE 967,1: GOTO 310
  30. 300  CALL  -3288: POKE 967,0
  31. 310  ONERR  GOTO 680
  32. 320  IF  PEEK(967) = 0 GOTO 410
  33. 330  VTAB 23: HTAB 4: PRINT "TRANSFERRING UTILITIES TO RAM DISK"
  34. 340  PRINT D$"OPEN MG.EXEC"B$: PRINT D$"CLOSE MG.EXEC": PRINT D$"DELETE MG.EXEC"B$: PRINT D$"OPEN MG.EXEC"B$: PRINT D$"WRITE MG.EXEC"
  35. 350  PRINT "LOAD GALLERY"B$: PRINT "SAVE GALLERY"R$: PRINT "LOAD CLIP.ART"B$: PRINT "SAVE CLIP.ART"R$: PRINT "LOAD START.CLIPART"B$: PRINT "SAVE START.CLIPART"R$
  36. 360  PRINT "BLOAD BACKGROUND"B$: PRINT "BSAVE BACKGROUND,A$1C00,L$5A"R$
  37. 370  PRINT "BLOAD UNPACK.FAST"B$: PRINT "BSAVE UNPACK.FAST,A$300,L$9A"R$
  38. 380  PRINT "BLOAD PICFILE.CREATE"B$: PRINT "BSAVE PICFILE.CREATE,A$1C00,L$3F1"R$
  39. 390  PRINT "BLOAD UPK.OBJ"B$: PRINT "BSAVE UPK.OBJ,A$300,L$B9"R$
  40. 400  PRINT "RUN START.CLIPART"R$: PRINT D$"CLOSE": VTAB 7: PRINT D$"EXEC MG.EXEC"B$: END 
  41. 410  ONERR  GOTO 550
  42. 420  IF  PEEK(116) = 146  THEN  PRINT D$"CLOSE MG.EXEC"
  43. 430 RAM =  PEEK(967):O$ = "PRODOS": IF DOS  THEN O$ = "DOS3.3": PRINT D$"MAXFILES 2"
  44. 440  VTAB 15: HTAB 14: PRINT "<C> CLIP ART": VTAB 18: HTAB 14: PRINT "<G> GALLERY": VTAB 21: HTAB 14: PRINT "<Q> QUIT": POKE 49168,0: GOSUB 650
  45. 450  IF K = 195  OR K = 227 GOTO 490
  46. 460  IF K = 199  OR K = 231 GOTO 510
  47. 470  IF K = 155  OR K = 209  OR K = 241 GOTO 730
  48. 480  GOTO 440
  49. 490  VTAB 15: HTAB 14: INVERSE : PRINT "<C>": NORMAL :SD$ = B$: IF RAM  THEN SD$ = R$
  50. 500  PRINT D$"RUN CLIP.ART"SD$
  51. 510  VTAB 18: HTAB 14: INVERSE : PRINT "<G>": NORMAL :SD$ = B$: IF RAM  THEN SD$ = R$
  52. 520  PRINT D$"RUN GALLERY"SD$
  53. 530 :
  54. 540  REM  ERROR HANDLER
  55. 550  CALL 64477: CALL  -3288: VTAB 22: PRINT "PLEASE PLACE THE MINI-GRAPHICS DISK": PRINT "IN DRIVE 1 AND PRESS <RETURN>.":L = K
  56. 560  GOSUB 650: IF K < >141  AND K < >155 GOTO 560
  57. 570  IF K = 141  THEN K = L: GOTO 450
  58. 580  GOSUB 610: GOTO 440
  59. 590 :
  60. 600  REM  PRINT TITLE
  61. 610  TEXT : HOME : NORMAL : PRINT  CHR$(17); CHR$(21); CHR$(24): VTAB 1: FOR L = 0 TO 39: PRINT  CHR$(95);: NEXT : VTAB 3: HTAB 6: PRINT "NIBBLE MINI-GRAPHICS UTILITIES": VTAB 5: HTAB 12: PRINT "BY ROBERT C. MOORE"
  62. 620  VTAB 6: FOR L = 0 TO 39: PRINT  CHR$(95);: NEXT : VTAB 9: HTAB 12: PRINT "COPYRIGHT (C) 1987": HTAB 12: PRINT "BY MICROSPARC, INC": HTAB 12: PRINT "52 DOMINO DRIVE": HTAB 12: PRINT "CONCORD, MA  01742": RETURN 
  63. 630 :
  64. 640  REM  GET KEYCODE
  65. 650  WAIT 49152,128:K =  PEEK(49152): POKE 49168,0: RETURN 
  66. 660 :
  67. 670  REM  BOOT SLOT ERROR
  68. 680  CALL 64477: CALL  -3288: HOME : VTAB 10: PRINT " PROBLEM READING THE MINI-GRAPHICS DISK ": PRINT "IS THE DISK CONTROLLER IN SLOT "; MID$ (B$,3,1);"?"
  69. 690  PRINT : PRINT "IF NOT, CHANGE B$ IN LINE 210 OF": PRINT : PRINT "START.CLIPART, CLIP.ART, AND GALLERY."
  70. 700  FOR L = 0 TO 5999: NEXT : CALL 64477: GOTO 740
  71. 710 :
  72. 720  REM  EXIT TO APPLESOFT
  73. 730  POKE 49168,0: HOME : PRINT "READY FOR "O$" OR APPLESOFT COMMAND...": IF DOS  THEN  PRINT D$"MAXFILES 3"
  74. 740  POKE 968,0: POKE 969,0: POKE 970,0: POKE 216,0: FOR L = 0 TO 3: POKE 60 +L, PEEK(8188 +L): NEXT 
  75. 750  HIMEM: 38400
  76. 760  END 
  77. 770 :
  78. 780  REM  BINARY FILES NOT FOUND
  79. 790 E =  PEEK(222):EL =  PEEK(218) +256 * PEEK(219): POKE 216,0: CALL  -3288
  80. 800  IF E = 6  THEN A$ = "UTILITY FILE(S) NOT ON THIS DISK": GOTO 830
  81. 810  IF E = 8  THEN A$ = "I/O ERROR--CHECK DRIVE DOOR": GOTO 830
  82. 820 A$ = "ERROR " + STR$(E) +" IN LINE " + STR$(EL)
  83. 830  HOME : VTAB 12: PRINT A$
  84. 840  VTAB 21: PRINT "RETURN TO CONTINUE, ESC TO QUIT";: GET Z$: ON Z$ < > CHR$(27) GOTO 180: END