home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib32a.dsk / OCTOBER.1987 / SUPER.SHOW.bas < prev   
BASIC Source File  |  2023-02-26  |  2KB  |  53 lines
  1. 10  REM  **********************
  2. 20  REM  *     SUPER.SHOW     *
  3. 30  REM  *   BY TOM DORRIS    *
  4. 40  REM  * COPYRIGHT (C) 1987 *
  5. 50  REM  * BY MICROSPARC, INC *
  6. 60  REM  * CONCORD, MA  01742 *
  7. 70  REM  **********************
  8. 80  REM 
  9. 90  REM  * DRAW OVAL FIGURE
  10. 100  ONERR  GOTO 530
  11. 110  PRINT  CHR$(4)"BRUN SUPER.HIRES"
  12. 120  POKE 216,0
  13. 130  &  HGR : FOR I = 0 TO 15: &  STORE I,I,I,0: NEXT 
  14. 140  FOR I = 0 TO 319:YP = 96 -( SIN((I -140)/38) *30): FOR J = 0 TO 15: &  HCOLOR= J: &  HPLOT I,YP +J: NEXT J,I
  15. 150 PA = 1.570795:PB = 4.712385:DP = .0174532778
  16. 160 O = 0:E = 15:XC = 160:YC = 100:R = 50:RY = R
  17. 170  FOR I = PA TO PB  STEP DP
  18. 180  FOR R = O TO E
  19. 190  &  HCOLOR= R
  20. 200 X = XC +R * COS(I):Y = YC +RY * SIN(I)
  21. 210  &  HPLOT X,Y
  22. 220  &  HPLOT Y +60,X -60
  23. 230  &  HPLOT XC +XC -X,Y
  24. 240  &  HPLOT Y +60,YC +(YC -(X -60))
  25. 250  NEXT R
  26. 260  NEXT 
  27. 270  REM  * DRAW COLOR BAR
  28. 280  FOR I = 0 TO 179: &  HCOLOR=  INT(I/11): FOR J = 20 TO 30: &  HPLOT 70 +I,J: NEXT J,I
  29. 290  REM  * DRAW OUTLINE OF SCREEN
  30. 300  FOR I = 0 TO 319: &  HCOLOR=  INT(I/20): &  HPLOT I,0: &  HPLOT 319 -I,199: NEXT I
  31. 310  FOR I = 0 TO 199: &  HCOLOR=  INT(I/12.5): &  HPLOT 0,I: &  HPLOT 319,199 -I: NEXT 
  32. 320  REM  * BEGIN COLOR ANIMATION
  33. 330  REM  * FIRST STAGE
  34. 340 DL = 100: FOR R = 0 TO 1: FOR G = 0 TO 1: FOR B = 0 TO 1: GOSUB 480: NEXT B,G,R
  35. 350 R = 0:B = 0:G = 0:DL = 1: GOSUB 480
  36. 360  REM  * SECOND STAGE
  37. 370 DL = 100
  38. 380  FOR R1 = 0 TO 1: FOR B1 = 0 TO 1: FOR G1 = 0 TO 1: GOSUB 510: NEXT G1,B1,R1
  39. 390  REM  * THIRD AND FINAL STAGE
  40. 400  FOR R = 0 TO 1: FOR B = 0 TO 1: FOR G = 0 TO 1
  41. 410  FOR I = 0 TO 15: &  STORE I,R *I,B *I,G *I
  42. 420  FOR J = 1 TO 100: NEXT J: &  STORE I,0,0,0: NEXT I
  43. 430  FOR I = 15 TO 0  STEP  -1: &  STORE I,R *I,B *I,G *I: FOR J = 1 TO 100: NEXT J: &  STORE I,0,0,0
  44. 440  NEXT I,G,B,R
  45. 450  FOR I = 0 TO 15: &  STORE I,I,I,I: NEXT 
  46. 460 C =  INT( RND(1) *15) +1:R =  INT( RND(1) *15) +1:B =  INT( RND(1) *15) +1:G =  INT( RND(1) *15) +1: &  STORE C,R,B,G: FOR I = 1 TO 200: NEXT : IF  PEEK( -16384) <128  THEN 460
  47. 470  &  TEXT : END 
  48. 480  FOR I = 0 TO 15: &  STORE I,R *I,B *I,G *I: FOR J = 1 TO DL: NEXT J,I
  49. 490  RETURN 
  50. 500  REM  * SECOND COLOR LOADING
  51. 510  FOR I = 1 TO 15: &  STORE I,R1 *I,B1 *I,G1 *I:X = I -1: &  STORE X,R1 *X,B1 *X,G1 *X: FOR J = 1 TO DL: NEXT J: &  STORE I,R *I,B *I,G *I: &  STORE X,R *X,B *X,G *X: NEXT I
  52. 520  RETURN 
  53. 530  HOME : PRINT "UNABLE TO LOAD SUPER.HIRES": END