home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib32a.dsk / OCTOBER.1987 / LOAD.SAVE.bas < prev    next >
BASIC Source File  |  2023-02-26  |  3KB  |  49 lines
  1. 10  REM  **********************
  2. 20  REM  *     LOAD.SAVE      *
  3. 30  REM  *   BY TOM DORRIS    *
  4. 40  REM  * COPYRIGHT (C) 1987 *
  5. 50  REM  * BY MICROSPARC, INC *
  6. 60  REM  * CONCORD, MA  01742 *
  7. 70  REM  **********************
  8. 80 T$ = "BIN": IF  PEEK(48896) < >76  THEN  HOME : PRINT "THIS PROGRAM REQUIRES PRODOS": END 
  9. 90  TEXT : HOME : VTAB 8: HTAB 16: PRINT "LOAD.SAVE": VTAB 10: HTAB 7: PRINT "SUPER HIRES LOADER AND SAVER"
  10. 100  PRINT : HTAB 14: PRINT "BY TOM DORRIS": PRINT : PRINT " COPYRIGHT 1987 BY MICROSPARC, INC."
  11. 110  PRINT : HTAB 6: PRINT "PRESS RETURN TO CONTINUE...";: GET A$: PRINT 
  12. 120 D$ =  CHR$(4): GOSUB 460
  13. 130  HOME 
  14. 140  HTAB 5: VTAB 5: PRINT "CHOOSE YOUR OPTION:"
  15. 150  HTAB 5: VTAB 7: PRINT "1. LOAD PICTURE": HTAB 5: PRINT "2. SAVE PICTURE": HTAB 5: PRINT "3. QUIT"
  16. 160  HTAB 5: VTAB 11: PRINT "-->";: GET A$: IF A$ <"1"  OR A$ >"3"  THEN 160
  17. 170  PRINT A$
  18. 180  IF A$ = "3"  THEN  HOME : END 
  19. 190  IF A$ = "2"  THEN 240
  20. 200  HOME : HTAB 5: VTAB 5: PRINT "ENTER THE NAME OF THE FILE TO": HTAB 5: PRINT "LOAD.  INCLUDE ANY PREFIX NEEDED."
  21. 210  HTAB 5: VTAB 9: INPUT "-->";A$: IF   NOT  LEN(A$)  THEN 130
  22. 220  HOME : HTAB 5: VTAB 5: PRINT "INSERT DISK CONTAINING PICTURE.": HTAB 5: VTAB 19: PRINT "PRESS RETURN TO LOAD...";: GET B$: PRINT 
  23. 230  POKE 49193,163: GOSUB 380: GET A$: POKE 49193,1: GOTO 130
  24. 240  POKE 49193,163: GET A$: POKE 49193,1
  25. 250  HOME : HTAB 5: VTAB 5: PRINT "ENTER THE NAME OF THE FILE TO SAVE": HTAB 5: PRINT "PICTURE AS.  NAME SHOULD INCLUDE": HTAB 5: PRINT "ANY PREFIX NEEDED."
  26. 260  HTAB 5: VTAB 9: INPUT "-->";A$: IF   NOT  LEN(A$)  THEN 130
  27. 270  HOME : HTAB 5: VTAB 5: PRINT "INSERT DISK YOU WISH TO SAVE": HTAB 5: PRINT "PICTURE ONTO.": HTAB 5: VTAB 19: PRINT "PRESS RETURN TO SAVE...";: GET B$: PRINT 
  28. 280  POKE 49193,163
  29. 290  FOR I = 1 TO 4
  30. 300  POKE 771,0: POKE 772,I *32: POKE 773,225
  31. 310  POKE 775,0: POKE 776,64: POKE 777,0: POKE 791,(I +1) *32
  32. 320  CALL 768: REM  *** LOAD NEXT PICTURE SEGMENT INTO WORKING MEMORY ***
  33. 330  PRINT D$"BSAVE "A$",A$4000,L$2000,B"(I -1) *8192
  34. 340  NEXT : POKE 49193,1: GOTO 130
  35. 350  REM  *** LOAD PICTURE ROUTINE ***
  36. 360  REM  *** LOAD IN PICTURE IN 4 EQUAL SECTIONS ***
  37. 370  END 
  38. 380  FOR QW = 1 TO 4
  39. 390  PRINT D$"BLOAD "A$",A$4000,L$2000,B"(QW -1) *8192",T"T$
  40. 400  POKE 771,0: POKE 772,64: POKE 773,0
  41. 410  POKE 775,0: POKE 776,32 *QW: POKE 777,225
  42. 420  POKE 791,96
  43. 430  CALL 768: REM  *** MOVE LOADED SECTION TO DISPLAY MEMORY ***
  44. 440  NEXT : REM  *** LOAD NEXT SECTION ***
  45. 450  RETURN 
  46. 460  FOR I = 0 TO 26: READ A: POKE 768 +I,A:C = C +A: NEXT 
  47. 470  IF C < >3025  THEN  HOME : PRINT "DATA STATEMENT ERROR!": END 
  48. 480  RETURN 
  49. 490  DATA  162,0,191,0,64,0,159,0,32,225,232,208,245,238,4,3,238,8,3,173,4,3,201,96,208,232,96