home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib32a.dsk / NOVEMBER.1987 / COLOR.CONTROL.bas < prev    next >
BASIC Source File  |  2023-02-26  |  4KB  |  108 lines
  1. 10  REM  ***********************
  2. 20  REM  * COLOR.CONTROL       *
  3. 30  REM  * BY BRYAN A. THORELL *
  4. 40  REM  * COPYRIGHT (C) 1987  *
  5. 50  REM  * BY MICROSPARC, INC. *
  6. 60  REM  * CONCORD, MA  01742  *
  7. 70  REM  ***********************
  8. 80 D$ =  CHR$(4): REM   PRODOS COMMAND CHARACTER
  9. 90  PRINT D$;"PR#3": REM   TURN ON 80-COLUMN CARD
  10. 100  ONERR  GOTO 930
  11. 110  REM  
  12. 120  REM     TITLE ROUTINE & SCREEN SETUP
  13. 130  REM  
  14. 140  PRINT 
  15. 150  HOME 
  16. 160 Y = 5:X = 22
  17. 170  VTAB Y: HTAB X
  18. 180  PRINT " ____________________________________": REM  36 UNDERLINES
  19. 190  HTAB X
  20. 200  PRINT "|                                    |": REM  36 SPACES
  21. 210  HTAB X
  22. 220  PRINT "|   COLOR.CONTROL by Bryan Thorell   |": REM  3/3 SPACES
  23. 230  HTAB X
  24. 240  PRINT "|  Copyright 1987 by MicroSPARC,Inc. |"
  25. 250  HTAB X
  26. 260  PRINT "|____________________________________|": REM  36 UNDERLINES
  27. 270  VTAB 16: HTAB 1
  28. 280  FOR L = 1 TO 79
  29. 290  PRINT "_";
  30. 300  NEXT L
  31. 310  PRINT 
  32. 320  REM 
  33. 330  REM    Command Parser
  34. 340  REM 
  35. 350  VTAB 18: HTAB 1
  36. 360  PRINT "Enter (Color, Help, #, ?)  > ";
  37. 370  INPUT "";C$
  38. 380  REM 
  39. 390 S$ = "*"
  40. 400  IF C$ = "?"  OR C$ = "/"  THEN  GOSUB 760: GOTO 350
  41. 410  IF C$ = "HELP"  OR C$ = "Help"  OR C$ = "help"  THEN  GOSUB 700: GOTO 350
  42. 420  IF C$ = "BLACK"  OR C$ = "Black"  OR C$ = "black"  OR C$ = "0"  THEN S$ = "0"
  43. 430  IF C$ = "YELLOW"  OR C$ = "Yellow"  OR C$ = "yellow"  OR C$ = "1"  THEN S$ = "1"
  44. 440  IF C$ = "RED"  OR C$ = "Red"  OR C$ = "red"  OR C$ = "2"  THEN S$ = "2"
  45. 450  IF C$ = "BLUE"  OR C$ = "Blue"  OR C$ = "blue"  OR C$ = "3"  THEN S$ = "3"
  46. 460  IF C$ = "ORANGE"  OR C$ = "Orange"  OR C$ = "orange"  OR C$ = "4"  THEN S$ = "4"
  47. 470  IF C$ = "GREEN"  OR C$ = "Green"  OR C$ = "green"  OR C$ = "5"  THEN S$ = "5"
  48. 480  IF C$ = "PURPLE"  OR C$ = "Purple"  OR C$ = "purple"  OR C$ = "6"  THEN S$ = "6"
  49. 490  IF S$ = "*"  THEN 350
  50. 500  REM 
  51. 510  REM    SETUP PRINTER
  52. 520  REM 
  53. 530  GOSUB 860
  54. 540  VTAB 20: HTAB 1
  55. 550  PRINT "Turn on PRINTER and press RETURN.";
  56. 560  GET RET$: IF RET$ < > CHR$(13)  THEN 560
  57. 570  PRINT : PRINT D$;"PR#1"
  58. 580  PRINT  CHR$(27) + CHR$(75) +S$;
  59. 590  PRINT D$;"PR#0"
  60. 600  PRINT 
  61. 610  GOSUB 860
  62. 620  VTAB 20: HTAB 1
  63. 630  PRINT "Loading AppleWorks, Please Wait..."
  64. 640  PRINT D$;"-PROGRAM"
  65. 650  NEW : END 
  66. 660  REM 
  67. 670  REM    HELP
  68. 680  REM 
  69. 690  GOSUB 860
  70. 700  VTAB 20: HTAB 1
  71. 710  PRINT "This program allows you to select the color that you wish to print your"
  72. 720  PRINT "AppleWorks files in.  (You must have an ImageWriter // Printer)  You can select"
  73. 730  PRINT "the colors by the number (1-6) or by the name (RED, BLUE, ETC.).  HELP"
  74. 740  PRINT "gives this message; '?' lists all possible colors."
  75. 750  RETURN 
  76. 760  REM 
  77. 770  REM    LIST COLORS
  78. 780  REM 
  79. 790  GOSUB 860
  80. 800  VTAB 20: HTAB 1
  81. 810  PRINT "BLACK   YELLOW   RED   BLUE   ORANGE   GREEN   PURPLE"
  82. 820  RETURN 
  83. 830  REM 
  84. 840  REM    CLEAR BOTTOM SECTION
  85. 850  REM 
  86. 860  FOR M = 1 TO 4
  87. 870  VTAB 19 +M: CALL  -868
  88. 880  NEXT M
  89. 890  RETURN 
  90. 900  REM 
  91. 910  REM    ERROR HANDLING SECTION
  92. 920  REM 
  93. 930 ERR =  PEEK(222)
  94. 940 ELN =  PEEK(219) *256 + PEEK(218)
  95. 950 MG$ = "Message: ":E$ = "Misc. Error #" + STR$(ERR) +" in line " + STR$(ELN)
  96. 960  IF ERR = 6  THEN E$ = "Insert disk with Color/AppleWorks on it."
  97. 970  IF ERR = 8  THEN E$ = "I/O Error"
  98. 980  IF ERR = 255  THEN E$ = "Please do not press Control-C"
  99. 990 MG$ = MG$ +E$
  100. 1000  GOSUB 860
  101. 1010  VTAB 20: HTAB 1
  102. 1020  PRINT MG$
  103. 1030  VTAB 22: HTAB 1
  104. 1040  PRINT "Press RETURN to continue.";
  105. 1050  GET RET$: IF RET$ < > CHR$(13)  THEN 1050
  106. 1060  PRINT 
  107. 1070  IF ERR = 6  THEN  GOTO 610
  108. 1080  GOTO 140: REM    RESTART PROGRAM