480 HOME : VTAB 12: HTAB 10:NFILES = 0: PRINT "NO LOGBOOKS ON THIS DISK": VTAB 22: PRINT "PRESS RETURN FOR MENU";: GET Z$: PRINT : RETURN
490 EF = 2: HOME : VTAB 12: HTAB 10: PRINT "READING LOGBOOK NAMES": ONERR GOTO 4440
500 PRINT D$;"OPEN JOGCAT"
510 PRINT D$;"READ JOGCAT"
520 INPUT NFILES
530 FOR I = 1 TO NFILES
540 INPUT FILE(I)
550 NEXT
560 PRINT D$;"CLOSE"
570 RETURN
580 REM MENU
590 EF = 3: HOME : VTAB 7: HTAB 11: PRINT "WOULD YOU LIKE TO": ONERR GOTO 4440
600 FOR I = 1 TO 4
610 VTAB I *2 +8: HTAB 12: INVERSE : PRINT I;: NORMAL : PRINT CHR$(32);PICK$(I)
620 NEXT
630 VTAB 19: HTAB 11: PRINT "CHOICE = ? ";
640 GET S$
650 PRINT :PICK = VAL(S$)
660 IF PICK <1 OR PICK >4 THEN 630
670 : REM NO FILES
680 IF (PICK = 2 OR PICK = 3) AND NFILES = 0 THEN HOME : VTAB 12: HTAB 1: PRINT "THERE AREN'T ANY LOGBOOKS ON FILE.": VTAB 22: PRINT "PRESS RETURN FOR MENU";: GET Z$: PRINT : GOTO 590
690 ON PICK GOSUB 710,2540,4330
700 RETURN
710 REM NEW BOOK
720 : REM ENTER YEAR
730 GOSUB 910
740 : REM CHECK FOR DUPLICATE & ASK TO CONTINUE
750 DUP$ = "":CNT$ = ""
760 IF NFILES >0 THEN GOSUB 1030
770 IF DUP$ = "YES" THEN GOSUB 1080
780 IF CNT$ = "NO" THEN 900
790 : REM SET VALUES TO 0
800 GOSUB 1210
810 : REM ENTER NO. OF JOGS
820 GOSUB 1280
830 : REM LOG JOGS
840 FOR I = 1 TO N
850 GOSUB 1360
860 NEXT I
870 : REM SAVE FILE
880 IF DUP$ = "" THEN NFILES = NFILES +1:FILE(NFILES) = YEAR
890 GOSUB 4110
900 RETURN
910 REM YEAR
920 HOME
930 PRINT "PLEASE ENTER A FOUR-DIGIT YEAR FOR"
940 PRINT "YOUR LOGBOOK."
950 VTAB 4: HTAB 10: PRINT SPC( 20)
960 VTAB 4: HTAB 1: INPUT "YEAR = ? ";Y$
970 YEAR = INT( VAL(Y$))
980 IF YEAR <BY OR YEAR >2100 THEN VTAB 22: HTAB 6: PRINT "PLEASE ENTER ";BY;" TO 2100 !": GOTO 950
990 DY = 365:DAY(2) = 28
1000 IF YEAR/4 = INT(YEAR/4) THEN DY = 366:DAY(2) = 29
1010 FILE$ = "JOG" + STR$(YEAR)
1020 RETURN
1030 REM CHECK FOR DUPLICATE
1040 FOR I = 1 TO NFILES
1050 IF FILE(I) = YEAR THEN DUP$ = "YES"
1060 NEXT
1070 RETURN
1080 REM DUPLICATE
1090 HOME
1100 INVERSE : PRINT FILE$;: NORMAL : PRINT " IS ALREADY ON FILE. IT WILL"
2370 IF (COL = 13 AND A = 8) OR (COL = 37 AND A < >8 AND A < >13) THEN PRINT BELL$: GOTO 2330
2380 IF A = 8 THEN GOSUB 2430
2390 IF A < >8 AND A < >13 THEN PRINT L$;:P$ = P$ +L$:COL = COL +1
2400 IF A < >13 THEN 2330
2410 NORMAL
2420 RETURN
2430 REM MOVE CURSOR LEFTWARD
2440 IF LEN(P$) = 1 THEN P$ = ""
2450 IF LEN(P$) >1 THEN P$ = LEFT$(P$, LEN(P$) -1)
2460 COL = COL -1
2470 PRINT CHR$(8); SPC( 1)
2480 RETURN
2490 REM COMMENTS
2500 VTAB 18: HTAB 3: PRINT "COMMENTS:"
2510 ROW = 18:PH$ = CM$(K): GOSUB 2300
2520 IF COL < >13 THEN CM$(K) = P$
2530 RETURN
2540 REM OLD BOOK
2550 REM ENTER YEAR
2560 GOSUB 910
2570 : REM CHECK FOR YEAR ON FILE
2580 DUP$ = "": GOSUB 1030
2590 IF DUP$ = "" THEN HOME : INVERSE : PRINT FILE$;: NORMAL : PRINT " IS NOT ON FILE.": VTAB 22: HTAB 3: PRINT "PRESS RETURN FOR MENU";: GET Z$: PRINT : GOTO 2680
2600 REM READ DATA
2610 GOSUB 2690
2620 REM SELECT FROM MENU
2630 GOSUB 2780
2640 ON CHOICE GOSUB 1360,2930,3900
2650 IF CHOICE < >4 THEN 2630
2660 : REM SAVE DATA
2670 GOSUB 4110
2680 RETURN
2690 REM READ
2700 EF = 4: HOME : VTAB 12: HTAB 12: PRINT "READING DATA ...": ONERR GOTO 4440
2710 PRINT D$;"OPEN" +FILE$
2720 PRINT D$;"READ" +FILE$
2730 FOR I = 1 TO DY
2740 INPUT MILES(I),TIME(I),LC$(I),CM$(I)
2750 NEXT
2760 PRINT D$;"CLOSE" +FILE$
2770 RETURN
2780 REM MENU
2790 HOME
2800 VTAB 7: HTAB 10: PRINT "WOULD YOU LIKE TO"
2810 INVERSE :ROW = 10
2820 FOR I = 1 TO 4: VTAB ROW: HTAB 11: PRINT I:ROW = ROW +2: NEXT