home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib30b.dsk / DETECTIVE.DEMO.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  51 lines
  1. 10  REM  **********************
  2. 20  REM  *   DETECTIVE.DEMO   *
  3. 30  REM  *  BY JOHN R. VOKEY  *
  4. 40  REM  * COPYRIGHT (C) 1987 *
  5. 50  REM  * BY MICROSPARC, INC *
  6. 60  REM  * CONCORD, MA  01742 *
  7. 70  REM  **********************
  8. 80  REM  DISPLAY TITLE PAGE
  9. 90  PRINT  CHR$(14); CHR$(21): HOME :DRIVE = 43624:SLOT = DRIVE +2
  10. 100  COLOR= 2: GOSUB 470
  11. 110  POKE 33,38: POKE 32,1: POKE 34,1: POKE 35,23
  12. 120  FOR I = 5 TO 21: READ S$
  13. 130  FOR J = 23 TO I  STEP  -1
  14. 140  VTAB J: GOSUB 490
  15. 150  NEXT : NEXT 
  16. 160  DATA  DOS DEVICE DETECTIVE,DEVICE-INDEPENDENT DOS,BY JOHN VOKEY,,,,,,,,COPYRIGHT (C) 1987
  17. 170  DATA  MICROSPARC INC.
  18. 180  DATA  CONCORD MA 01742
  19. 190  DATA  ,,,,
  20. 200  REM  INSTALL PATCH
  21. 210  PRINT : PRINT  CHR$(4)"BRUN DETECTIVE,A$2000"
  22. 220  VTAB 10: HTAB 12: PRINT "<PATCH INSTALLED>"
  23. 230  REM  DELAY FOR 1000 OR KEY
  24. 240  VTAB 24: HTAB 15: INVERSE 
  25. 250  PRINT "PRESS <RETURN>";: NORMAL : POKE  -16368,0: FOR I = 1 TO 500: IF  PEEK( -16384) <128  THEN  NEXT 
  26. 260  REM  DISPLAY INSTRUCTIONS
  27. 270  VTAB 7: CALL  -958: FOR I = 9 TO 12: READ S$: FOR J = 23 TO I  STEP  -1: VTAB J
  28. 280  GOSUB 490
  29. 290  NEXT : NEXT : VTAB 24: HTAB 15: INVERSE : PRINT "              ";: NORMAL : REM  14 SPACES
  30. 300  DATA  PLEASE INSERT THE DETECTIVE DISK
  31. 310  DATA  INTO ANY DRIVE ON THE SYSTEM,(OR NOT AT ALL!)
  32. 320  DATA  THEN PRESS <RETURN>
  33. 330  ONERR  GOTO 510
  34. 340  POKE  -16368,0
  35. 350  REM  AWAIT KEYPRESS
  36. 360  VTAB 13: HTAB 19: GET S$: IF S$ < > CHR$(13)  AND S$ < > CHR$(27)  THEN 360
  37. 370  IF S$ =  CHR$(27)  THEN 450
  38. 380  REM  SEARCH FOR FILE
  39. 390  PRINT : IF   NOT ERR  THEN  PRINT  CHR$(4)"VERIFY DETECTIVE"
  40. 400  IF ERR  THEN  VTAB 20: HTAB 6: PRINT  CHR$(7);"DETECTIVE IS NOT ON THE SYSTEM"
  41. 410  IF   NOT ERR  THEN  VTAB 20: HTAB 6: PRINT  CHR$(7);"DETECTIVE IS IN SLOT " PEEK(SLOT)", DRIVE " PEEK(DRIVE)
  42. 420 ERR = 0: VTAB 24: HTAB 15: INVERSE : PRINT "<ESC> TO EXIT ";: NORMAL 
  43. 430  GOTO 360
  44. 440  REM  EXIT
  45. 450  POKE  -16368,0: TEXT : HOME : POKE 216,0: END 
  46. 460  REM  FRAME SUBROUTINE
  47. 470  HLIN 0,39 AT 1: FOR K = 1 TO 47  STEP 2: PLOT 0,K: PLOT 39,K: NEXT : HLIN 0,39 AT 47: RETURN 
  48. 480  REM  PRINT SUBROUTINE
  49. 490  HTAB (41 - LEN(S$))/2: PRINT S$;: CALL  -958: RETURN 
  50. 500  REM  ON ERR TRAP
  51. 510 ERR =  PEEK(222): RESUME