home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib30a.dsk / MARCH.1987 / WINDOWS.DEMO.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  33 lines
  1. 10  REM  ************************
  2. 20  REM  * WINDOWS.DEMO         *
  3. 30  REM  * BY LARRY ABRAMS      *
  4. 40  REM  * COPYRIGHT (C) 1987   *
  5. 50  REM  * BY MICROSPARC, INC.  *
  6. 60  REM  * CONCORD, MA  01742   *
  7. 70  REM  ************************
  8. 71  FOR X = 770 TO 789: READ Y: POKE X,Y: NEXT X: DATA   56,32,31,254,176,2,144,6,169,255,141,0,3,96,169,1,141,0,3,96
  9. 72  POKE 768,0: CALL 770: IF  PEEK(768) < >255  THEN  GOTO 79
  10. 73  IF  PEEK(64435) < >6  THEN  GOTO 79
  11. 74  IF  PEEK(64448) < >224  AND  PEEK(64448) < >0  THEN  GOTO 79
  12. 75  IF  PEEK(64448) = 224  THEN F$ = "WINDOWS.IIE"
  13. 76  IF  PEEK(64448) = 0  THEN F$ = "WINDOWS.IIC"
  14. 77  GOTO 80
  15. 78  END 
  16. 79  PRINT "THIS PROGRAM REQUIRES AN ENHANCED IIE": PRINT "OR IIC. IT WILL NOT RUN ON A II, II+,": PRINT "OR IIGS.": END 
  17. 80  PRINT  CHR$(4)"PR#3"
  18. 90  PRINT "WINDOWS DEMONSTRATION": PRINT "BY LARRY ABRAMS": PRINT "COPYRIGHT 1987 BY MICROSPARC, INC.": PRINT 
  19. 100  PRINT : ONERR  GOTO 240
  20. 110  PRINT  CHR$(4)"BLOAD "F$: HIMEM: 36864
  21. 120  POKE 216,0:WINDOW = 38116:INVRS = 38078: LIST 
  22. 130  REM  WINDOW DEMO
  23. 140 VS = 3:VE = 10:HS = 10:HE = 60: CALL WINDOW,VS,VE,HS,HE,0
  24. 150  VTAB 4: POKE 1403,15: PRINT "This window was invoked from BASIC by:": VTAB 6: POKE 1403,20: PRINT "CALL WINDOW,VS,VE,HS,HE,0"
  25. 160  VTAB 9: POKE 1403,13: PRINT "Press any key for INVERSE WINDOW or ";: INVERSE : PRINT "Q";: NORMAL : PRINT "uit: ";: GET A$
  26. 170  CALL WINDOW,VS,VE,HS,HE,1
  27. 180  IF A$ =  CHR$(81)  OR A$ =  CHR$(113)  THEN  VTAB 23: END 
  28. 190  REM  INVERSE DEMO
  29. 200 VS = 12:VE = 18:HS = 1:HE = 75: CALL INVRS,VS,VE,HS,HE,0
  30. 210  VTAB 14: POKE 1403,15: INVERSE : PRINT "This INVERSE window was invoked from BASIC by:": VTAB 16: POKE 1403,24: PRINT "CALL INVRS,VS,VE,HS,HE,0": NORMAL 
  31. 220  VTAB 24: POKE 1403,0: GET A$: CALL WINDOW,VS,VE,HS,HE,1
  32. 230  GOTO 130
  33. 240  HOME : PRINT "WINDOWS OBJECT FILE NOT FOUND.": END