home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib30a.dsk / MARCH.1987 / AW.DATE.128.bas next >
BASIC Source File  |  2023-02-26  |  4KB  |  71 lines
  1. 10  REM  ************************
  2. 20  REM  * AW.DATE.128          *
  3. 30  REM  * BY FERNANDO SALAZAR  *
  4. 40  REM  * COPYRIGHT (C) 1987   *
  5. 50  REM  * BY MICROSPARC, INC.  *
  6. 60  REM  * CONCORD, MA  01742   *
  7. 70  REM  ************************
  8. 80  REM  ----------------------------------
  9. 90  REM  PRINT TITLE, CHECK DATA STATEMENTS
  10. 100  REM ----------------------------------
  11. 110  LOMEM: 25088:D$ =  CHR$(4): TEXT : HOME : VTAB 2: HTAB 8: PRINT "APPLEWRITER DATE-PATCHER": PRINT "  -----------------------------------": POKE 34,5: HOME 
  12. 120  PRINT "CHECKING DATA STATEMENTS...":CSUM = 0: FOR I = 1 TO 247: READ A:CSUM = CSUM +A: NEXT I
  13. 130  IF CSUM < >24747  THEN  PRINT "-- DATA STATEMENTS INCORRECT!! --": PRINT : PRINT "  CHECK PROGRAM AND RE-TRY.": PRINT CSUM: GOTO 540
  14. 140  RESTORE : ONERR  GOTO 710
  15. 150  REM 
  16. 160  REM   -- VARIABLES--
  17. 170  REM 
  18. 180  REM  <APPLEWRITER ADDRESSES>
  19. 190  REM 
  20. 200  REM  TLOC = ADDRESS OF [Q]-H TEXT DESCRIPTION
  21. 210  REM  ALOC = ADDRESS OF [Q]-H RTS-TO ADDRESS
  22. 220  REM 
  23. 230  REM  <PATCH ADDRESSES>
  24. 240  REM 
  25. 250  REM  PLOC = ORIGIN OF PATCH
  26. 260  REM    F$ = FILENAME TO PATCH
  27. 270  REM 
  28. 280  REM  ---------------------------------
  29. 290  REM  PRINT VERSION MSG, INIT VARIABLES
  30. 300  REM  ---------------------------------
  31. 310  HOME : PRINT "  THIS PROGRAM PATCHES ONLY THE": PRINT "  80-COL 46K VERSION OF APPLEWRITER.": PRINT : PRINT "DO YOU WANT TO CONTINUE? Y/N";: GET A$: IF A$ < >"Y"  AND A$ < >"y"  AND A$ < >"N"  AND A$ < >"n"  THEN 310
  32. 320  IF A$ = "N"  OR A$ = "n"  THEN 540
  33. 330 TLOC = 23965:ALOC = 24105:PLOC = 24608:F$ = "AWD.SYS"
  34. 340  REM  -----------------------------
  35. 350  REM  GET AWRITER DISK, VERIFY FILE
  36. 360  REM  -----------------------------
  37. 370  HOME : PRINT "INSERT A BACKUP COPY OF APPLEWRITER 2.0": PRINT "AND PRESS [RETURN]": GET Z$
  38. 380  PRINT D$"PREFIX /AW2MASTER": POKE 216,0
  39. 390  HOME : PRINT : HTAB 15: PRINT "WORKING...": PRINT D$"BLOAD ";F$;",A$2000,TSYS"
  40. 400 P$ = "H. Toggle Data Line Display":A$ = "": FOR I = 0 TO 26:A$ = A$ + CHR$( PEEK(TLOC +I)): NEXT 
  41. 410  IF P$ < >A$  THEN  PRINT  CHR$(7): HOME : PRINT "-- UNABLE TO VERIFY APPLEWRITER FILE --": GOTO 540
  42. 420  REM  -----------
  43. 430  REM  APPLY PATCH
  44. 440  REM  -----------
  45. 450  FOR I = PLOC TO PLOC +246: READ A: POKE I,A: NEXT 
  46. 460 P$ = "H. Set System Date         ": REM  27 CHARS TOTAL
  47. 470  FOR I = 1 TO 27:A =  ASC( MID$ (P$,I,1)): POKE TLOC -1 +I,A: NEXT 
  48. 480 PLOC = PLOC -1: POKE ALOC,(PLOC -256 * INT(PLOC/256)): POKE ALOC +1, INT(PLOC/256)
  49. 490  REM  --------------------
  50. 500  REM  SAVE PATCHED PROGRAM
  51. 510  REM  --------------------
  52. 520  PRINT D$"UNLOCK ";F$: PRINT D$"BSAVE ";F$;",A$2000,E$6116,TSYS": PRINT D$"LOCK ";F$: PRINT D$"PREFIX /"
  53. 530  HOME : PRINT : PRINT "  DATE-PATCH COMPLETE."
  54. 540  VTAB 20: POKE 34,0: END 
  55. 550  DATA  162,96,169,232,32,77,80,162,0,32,2,35,201,13,240,72,201,8,240,45
  56. 560  DATA  201,21,208,7,224,7,176,237,189,6,97,201,48,144,230,201,58,176,226,157
  57. 570  DATA  6,97,224,8,144,5,176,217,189,6,97,32,3,32,232,224,2,240,245,224
  58. 580  DATA  5,240,241,208,200,202,16,3,232,240,194,232,202,169,136,32,3,32,224,5
  59. 590  DATA  240,246,224,2,240,242,208,177,160,0,32,205,96,133,2,240,31,201,13,176
  60. 600  DATA  27,200,200,32,205,96,133,3,240,18,166,2,221,192,96,176,11,200,200,32
  61. 610  DATA  205,96,133,1,201,85,176,8,169,135,32,3,32,76,32,96,6,2,6,2
  62. 620  DATA  6,2,6,2,6,2,38,1,165,2,5,3,141,144,191,165,1,141,145,191
  63. 630  DATA  96,32,30,32,31,32,31,32,32,31,32,31,32,185,6,97,41,15,170,200
  64. 640  DATA  185,6,97,41,15,133,0,169,0,24,202,48,4,105,10,144,249,101,0,96
  65. 650  DATA  13,13,77,77,45,68,68,45,89,89,44,32,82,69,84,85,82,78,32,116
  66. 660  DATA  111,32,97,99,99,101,112,116,58,32,48,49,45,48,49,45,56,54,136,136
  67. 670  DATA  136,136,136,136,136,136,0
  68. 680  REM  -----------------
  69. 690  REM  DOS ERROR HANDLER
  70. 700  REM  -----------------
  71. 710  PRINT  CHR$(7): PRINT "-- NOT AN APPLEWRITER DISK! --": PRINT "PRESS [RETURN] TO RE-TRY.": GET Z$: GOTO 380