home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib30a.dsk / JANUARY.1987 / MOVE.DEMO.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  49 lines
  1. 10  REM  ************************
  2. 20  REM  * MOVE.DEMO            *
  3. 30  REM  * BY STEVEN BIRGE      *
  4. 40  REM  * COPYRIGHT (C) 1987   *
  5. 50  REM  * BY MICROSPARC, INC.  *
  6. 60  REM  * CONCORD, MA  01742   *
  7. 70  REM  ************************
  8. 80  HIMEM: 37376: REM  $9200 BELOW DATA BUFFER
  9. 90  ONERR  GOTO 490
  10. 100  PRINT  CHR$(4);"BLOAD MOVE": REM  PLACE MACHINE LANGUAGE ROUTINE AT $300
  11. 110  POKE 216,0: TEXT : HOME : NORMAL : PRINT "MOVE DEMO": PRINT "BY STEVEN BIRGE": PRINT "COPYRIGHT 1987 BY MICROSPARC, INC.": POKE 34,5
  12. 120  VTAB 10: PRINT "CREATING DEMO FILE, PLEASE WAIT..."
  13. 130  REM  CREATE DEMO FILE
  14. 140  PRINT  CHR$(4);"OPEN TEST.FILE"
  15. 150  PRINT  CHR$(4);"CLOSE TEST.FILE"
  16. 160  PRINT  CHR$(4);"DELETE TEST.FILE"
  17. 170  PRINT  CHR$(4);"OPEN TEST.FILE"
  18. 180  PRINT  CHR$(4);"WRITE TEST.FILE"
  19. 190  FOR J = 0 TO 25
  20. 200 E$ =  CHR$(J +65): REM  E$=EACH LETTER OF ALPHABET
  21. 210  FOR K = 1 TO 10: PRINT E$;
  22. 220  NEXT K,J
  23. 230  PRINT : PRINT "IT WORKS!"
  24. 240  PRINT  CHR$(4);"CLOSE"
  25. 250  REM  TEST POSITION COMMAND
  26. 260  HOME : PRINT "NOW TESTING POSITION COMMAND"
  27. 270  PRINT  CHR$(4);"OPEN TEST.FILE"
  28. 280  PRINT  CHR$(4);"POSITION TEST.FILE,F1"
  29. 290  PRINT  CHR$(4);"READ TEST.FILE"
  30. 300  INPUT A$
  31. 310  PRINT  CHR$(4);"CLOSE"
  32. 320  PRINT : PRINT A$: PRINT : FOR X = 1 TO 2000: NEXT 
  33. 330  REM  TEST MOVE ROUTINES
  34. 340  PRINT : PRINT "NOW TESTING MOVE ROUTINES": PRINT 
  35. 350 N$ = "/NIBBLE.1987/JANUARY.1987/TEST.FILE": REM  N$ MUST CONTAIN THE FULL PATHNAME FOR THE FILE
  36. 360  POKE 774, LEN(N$): REM  PUT LENGTH OF PATHNAME AT $306
  37. 370  FOR N = 1 TO  LEN(N$)
  38. 380  POKE 774 +N, ASC( RIGHT$(N$, LEN(N$) -N +1)): REM  PUT N$ IN $307 ON
  39. 390  NEXT 
  40. 400  CALL 851: REM  $353 OPEN FILE
  41. 410  CALL 877: CALL 877: REM  READ AFTER FIRST CR
  42. 420 E = 0:A$ = ""
  43. 430 E$ =  CHR$( PEEK(37376 +E)): REM  READ CHARACTER
  44. 440  IF E$ =  CHR$(13)  THEN 460: REM  CR
  45. 450 A$ = A$ +E$:E = E +1: GOTO 430
  46. 460  CALL 888: REM  CLOSE FILE
  47. 470  PRINT A$
  48. 480  TEXT : VTAB 20: END 
  49. 490  HOME : VTAB 7: PRINT "THIS PROGRAM REQUIRES THE BINARY FILE": PRINT "'MOVE' TO BE ON THE SAME DISK": END