home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib29b.dsk / AUTO.LOG.ON.bas < prev    next >
BASIC Source File  |  2023-02-26  |  3KB  |  96 lines
  1. 10  REM  ************************
  2. 20  REM  * AUTO.LOG.ON          *
  3. 30  REM  * BY FRED AMUNDSEN     *
  4. 40  REM  * COPYRIGHT (C) 1986   *
  5. 50  REM  * BY MICROSPARC, INC.  *
  6. 60  REM  * CONCORD, MA  01742   *
  7. 70  REM  ************************
  8. 80  REM  BULLETIN BOARD NAME:
  9. 90 BB$ = "NIBBLE HOT LINE"
  10. 100  REM  BULLETIN BOARD NUMBER:
  11. 110 NUMBER$ = "1-617-369-8920"
  12. 120  REM  YOUR FIRST NAME:
  13. 130 NAME$ = "FRED"
  14. 140  REM  YOUR MODEM IS IN SLOT NUMBER:
  15. 150 SLOT = 2
  16. 160  REM  ALTERNATE THE BULLATIN BOARD PROMPTS AND YOUR RESPONSES
  17. 170  DATA  "FIRST NAME:","FRED"
  18. 180  DATA  "LAST NAME:","AMUNDSEN"
  19. 190  REM  INSERT MORE DATA DTATEMENTS HERE AS NECESSARY
  20. 200  DATA  EOF,EOF
  21. 210 BELL$ =  CHR$(7)
  22. 220 D$ =  CHR$(4): REM  CONTROL D
  23. 230 DIAL$ =  CHR$(17): REM  CONTROL Q
  24. 240 MODEM = 1656 +SLOT
  25. 250 FLAGS = 1912 +SLOT
  26. 260  GOSUB 920: REM  SETUP RECEIVE RTN
  27. 270  GOTO 500: REM  MAINLINE
  28. 280  REM  RECEIVE SUBROUTINE
  29. 290 L2 =  LEN(Q$)
  30. 300  POKE 0,L2
  31. 310  REM  PAGE 3 ROUTINE
  32. 320  PRINT D$;"PR#0"
  33. 330  PRINT D$;"IN#";SLOT
  34. 340  CALL 768
  35. 350  RETURN 
  36. 360  REM  XMIT
  37. 370  PRINT D$;"IN#0"
  38. 380  PRINT D$;"PR#";SLOT
  39. 390  INVERSE 
  40. 400  FOR K = 1 TO  LEN(S$)
  41. 410  PRINT  MID$ (S$,K,1);
  42. 420  FOR I = 1 TO 100: NEXT I
  43. 430  NEXT K
  44. 440  PRINT 
  45. 450  NORMAL : RETURN 
  46. 460  REM  WAIT SUBROUTINE
  47. 470  FOR K = 1 TO 500
  48. 480  NEXT K
  49. 490  RETURN 
  50. 500  REM  MAINLINE
  51. 510  TEXT : HOME : VTAB 3: PRINT "AUTO LOG-ON": PRINT "BY FRED AMUNDSEN": PRINT "COPYRIGHT 1986 BY MICROSPARC, INC.": VTAB 8
  52. 520  PRINT "CALLING ";BB$;"...": PRINT 
  53. 530  PRINT D$;"PR#";SLOT
  54. 540  PRINT DIAL$;NUMBER$
  55. 550  IF  PEEK(MODEM) <127  THEN 780
  56. 560  PRINT BELL$;BELL$
  57. 570  GOSUB 460: REM  PAUSE
  58. 580  REM  SEND A FEW CARRIAGE RETURNS BEFORE BEGINNING
  59. 590  PRINT : FOR I = 1 TO 100: NEXT I: PRINT 
  60. 600  PRINT : PRINT 
  61. 610  READ Q$,S$: GOSUB 840
  62. 620  IF Q$ = "EOF"  THEN  GOTO 660
  63. 630  GOSUB 280: REM  RECEIVE
  64. 640  IF  PEEK(MODEM) <127  THEN  END : REM  DISCONNECTED
  65. 650  GOSUB 360: GOTO 610: REM  XMIT
  66. 660  REM  START TERM PROGRAM
  67. 670  PRINT D$;"PR#0"
  68. 680  INVERSE 
  69. 690  PRINT : PRINT 
  70. 700  PRINT "OK ";NA$;" TAKE OVER FROM HERE"
  71. 710  NORMAL 
  72. 720  PRINT : PRINT 
  73. 730  PRINT BELL$
  74. 740  PRINT D$;"IN#";SLOT
  75. 750  POKE FLAGS,138
  76. 760  INPUT A$
  77. 770  END 
  78. 780  REM  NO ANSWER
  79. 790  PRINT D$;"PR#0"
  80. 800  PRINT D$;"IN#0"
  81. 810  PRINT : PRINT "NO ANSWER. PLEASE STAND BY": VTAB 23
  82. 820  FOR I = 1 TO 6000: NEXT I
  83. 830  GOTO 500
  84. 840 CTR = 848
  85. 850  FOR K = 1 TO  LEN(Q$)
  86. 860 J =  ASC( MID$ (Q$,K,1)) +128
  87. 870  POKE CTR,J
  88. 880 CTR = CTR +1
  89. 890  NEXT K
  90. 900  RETURN 
  91. 910  REM  RECEIVE SUBROUTINE AT PAGE 3
  92. 920  POKE 768,162: POKE 769,0: POKE 770,32: POKE 771,12: POKE 772,253: POKE 773,32: POKE 774,237: POKE 775,253: POKE 776,221:
  93. 930  POKE 777,80: POKE 778,3: POKE 779,208: POKE 780,243: POKE 781,232: POKE 782,228: POKE 783,0: POKE 784,208: POKE 785,240:
  94. 940  POKE 786,96
  95. 950  RETURN 
  96. 960  END