home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Nibble Magazine
/
nib29a.dsk
/
SEPTEMBER.1986
/
MATHLAND.bas
next >
Wrap
BASIC Source File
|
2023-02-26
|
1KB
|
36 lines
10 REM **********************
20 REM * MATHLAND *
30 REM * BY HAP GAYLORD *
40 REM * COPYRIGHT (C) 1986 *
50 REM * BY MICROSPARC, INC *
60 REM * CONCORD, MA 01742 *
70 REM **********************
80 CF = 2
90 HGR2
100 R = 0:P = 0:H = 0
110 C = 0:A = 0:Z = 0
120 T = 1:L = 1:K = 192:D = 0:G = 0
130 P = K
140 FOR C = T +D TO 1 STEP -CF
150 A = T +L:R = A -C: IF R >100 THEN 300
160 REM **************************
170 REM * LINE 200 CONTAINS A *
180 REM * FUNCTION TO BE PLOTTED *
190 REM **************************
200 Z = ( SIN(R/10) + SIN(C/10)) *20 +20
210 H = K -Z -R: IF H > = P OR H <0 THEN 240
220 P = H: HCOLOR= 3: HPLOT A -1,P
230 REM ** ADD GOTO 280 HERE IF UNDERSIDE IS NOT DESIRED
240 IF R = L OR R = L +1 THEN G = H +5: GOTO 280
250 IF H < = G THEN 280
260 G = H: IF H >191 THEN 280
270 HCOLOR= 2: HPLOT A -1,G
280 NEXT C
290 REM
300 IF A = 280 THEN 350
310 T = T +1: IF T >180 THEN T = 180:L = L +1:D = D +1: IF D = CF THEN D = 0
320 GOTO 130
330 REM ** BEEP WHEN DONE
340 POKE -16368,0
350 CALL -198: FOR I = 1 TO 750: NEXT I:X = PEEK( -16384): IF X <128 GOTO 350
360 TEXT : HOME : END