home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib29a.dsk / NOVEMBER.1986 / TOOL2PF.bas < prev   
BASIC Source File  |  2023-02-26  |  2KB  |  40 lines
  1. 1  REM  **********************
  2. 2  REM  * TOOL2PF            *
  3. 3  REM  * CHARACTER SET      *
  4. 4  REM  * CONVERTER          *
  5. 5  REM  * BY DONALD W. MILLER*
  6. 6  REM  * COPYRIGHT (C) 1986 *
  7. 7  REM  * BY MICROSPARC, INC.*
  8. 8  REM  * CONCORD, MA  01742 *
  9. 9  REM  **********************
  10. 10  TEXT : HOME : NORMAL 
  11. 20  PRINT "TOOLKIT TO PROWRITER FONT CONVERTER"
  12. 30  PRINT "BY DONALD W. MILLER"
  13. 40  PRINT "COPYRIGHT 1986 BY MICROSPARC, INC."
  14. 50  FOR X = 1 TO 39: PRINT "=";: NEXT 
  15. 60  POKE 34,4: PRINT 
  16. 70  ONERR  GOTO 240
  17. 80 F$ = "PF.CONVERT": PRINT  CHR$(4)"BLOAD "F$
  18. 90 F$ = "": VTAB 10: PRINT "ENTER NAME OF TOOLKIT CHARACTER SET": VTAB 18: PRINT "ENTER '1' TO CATALOG DRIVE 1": PRINT "ENTER '2' TO CATALOG DRIVE 2": PRINT 
  19. 100  PRINT "<RETURN> ALONE EXITS PROGRAM": PRINT : VTAB 12: POKE  -16368,0: INPUT TK$: IF TK$ = ""  THEN 190
  20. 110  IF TK$ = "1"  OR TK$ = "2"  THEN  HOME : GOSUB 220: GOSUB 210: HOME : GOTO 90
  21. 120  IF  RIGHT$(TK$,4) < >".SET"  THEN TK$ = TK$ +".SET"
  22. 130 F$ = TK$: PRINT  CHR$(4)"BLOAD"TK$",A$6000"
  23. 140 TK$ =  LEFT$(TK$, LEN(TK$) -4)
  24. 150  HOME : VTAB 10: PRINT "CONVERSION IN PROGRESS..."
  25. 160  CALL 768
  26. 170  PRINT  CHR$(4)"BSAVE"TK$".PF,A$6300,L$300"
  27. 180  HOME : VTAB 10: PRINT "CONVERSION COMPLETED.": GOSUB 200: HOME : GOTO 90
  28. 190  TEXT : HOME : POKE 216,0: END 
  29. 200  VTAB 22: HTAB 1: PRINT "PRESS <RETURN> TO CONTINUE";: GET CH$: POKE  -16384,0: RETURN 
  30. 210  PRINT : PRINT "PRESS <RETURN> TO CONTINUE";: GET CH$: POKE  -16384,0: RETURN 
  31. 220 DV =  VAL(TK$): PRINT  CHR$(4) LEFT$("CATALOG",7 -4 *( PEEK(48896) = 76));",D"DV: RETURN 
  32. 230  REM  ERROR HANDLING ROUTINE
  33. 240 ER =  PEEK(222):EL =  PEEK(219) *256 + PEEK(218)
  34. 250  HOME : VTAB 7: PRINT  CHR$(4)"CLOSE"
  35. 260  IF ER = 6  THEN  PRINT "FILE "F$" NOT FOUND": GOTO 300
  36. 270  IF ER = 8  THEN  PRINT "I/O ERROR": GOTO 300
  37. 280  IF ER = 16  THEN  PRINT "SYNTAX ERROR IN LINE "EL: GOTO 300
  38. 290  PRINT "ERROR IN LINE "EL
  39. 300  IF F$ < >"PF.CONVERT"  THEN  VTAB 23: PRINT "PRESS <RETURN> TO RESTART";: GET CH$: CALL  -3288: POKE  -16368,0: HOME : GOTO 90
  40. 310  VTAB 18: PRINT "THIS PROGRAM REQUIRES THE BINARY FILE": PRINT "'PF.CONVERT' TO BE ON THE SAME DISK": END