home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib29a.dsk / DECEMBER.1986 / INT.BUG.TEST.bas < prev    next >
BASIC Source File  |  2023-02-26  |  1KB  |  30 lines
  1. 10  REM  **********************
  2. 20  REM  * INT.BUG.TEST       *
  3. 30  REM  * BY WILLIAM PETERS  *
  4. 40  REM  *                    *
  5. 50  REM  * COPYRIGHT 1986 BY  *
  6. 60  REM  * MICROSPARC, INC.   *
  7. 70  REM  * CONCORD, MA  01742 *
  8. 80  REM  **********************
  9. 90  TEXT : HOME : NORMAL 
  10. 100  VTAB 22: PRINT "PRESS <RETURN> TO END": VTAB 1: INPUT " ADDITIVE FRACTION = 1/";F$:F =  VAL(F$): IF F = 0  THEN  TEXT : HOME : END 
  11. 110 K = 1/F: CALL  -958
  12. 120  INPUT "START AT (INTEGER): ";A$:A =  VAL(A$)
  13. 130 L = .00000001: REM  SEVEN ZEROES
  14. 140  HOME : PRINT "ADDITIVE FRACTION IS 1/"F: PRINT : PRINT "   A                INT(VAL(STR$(A)))": REM  16 SPACES
  15. 150  PRINT "             INT(A)             INT(A+L)": PRINT : POKE 34,5: REM  14 SPACES AND 15 SPACES
  16. 160  VTAB 22: PRINT "PRESS <RETURN> TO STOP": POKE 35,21: POKE  -16368,0: VTAB 6
  17. 170  FOR Q = 1 TO 1000
  18. 180  IF  PEEK( -16384) >127  THEN Q = 1001: POKE  -16368,0: REM  QUIT IF KEY PRESSSED
  19. 190 A = A +K
  20. 200 B =  INT(A)
  21. 210 C =  INT( VAL( STR$(A)))
  22. 220 D =  INT(A +L)
  23. 230  PRINT A;: HTAB 16: PRINT B;: HTAB 25: PRINT C;: HTAB 34: PRINT D
  24. 240  IF B < >C  OR B < >D  THEN  PRINT : PRINT "ERROR IN INT FUNCTION!": GOSUB 280
  25. 250  NEXT Q
  26. 260  GOTO 90
  27. 270  REM  PAUSE AND QUERY SUBROUTINE
  28. 280  VTAB 22: PRINT  CHR$(7);: PRINT "<ESC> TO STOP, <RETURN> TO CONTINUE";: GET W$
  29. 290  IF W$ =  CHR$(27)  THEN  POP : GOTO 90
  30. 300  VTAB 22: HTAB 1: CALL  -958: PRINT "PRESS <RETURN> TO STOP": HOME : RETURN