home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib28b.dsk / LAM.DEMO1.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  47 lines

  1. 1  REM  **********************
  2. 2  REM  *     LAM.DEMO1      *
  3. 3  REM  *   BY MARK CRAVEN   *
  4. 4  REM  * COPYRIGHT (C) 1986 *
  5. 5  REM  * BY MICROSPARC, INC *
  6. 6  REM  * CONCORD, MA  01742 *
  7. 7  REM  **********************
  8. 8  REM  MODIFIED TO WORK ON IIGS
  9. 9  REM  BY S. KARATSORIDIS
  10. 10  REM  USING METHOD FOUND AT
  11. 11  REM  HTTP://WWW.LLX.COM/~NPARKER/A2/SHLAM.HTML
  12. 50  REM  DEFINE MONITOR INPUT STRING
  13. 60 I$ = "2000<4000.5FFFM F328G"
  14. 70  REM 
  15. 80  REM  MOVES RANGE $4000-$5FFF
  16. 90  REM  (HIRES P2) TO PAGE 1
  17. 100  REM  THEN RETURNS TO BASIC
  18. 110  REM 
  19. 120  HOME : TEXT : HGR2 
  20. 130  HGR : POKE 230,64: REM  CLEAR PAGE 1 BUT PLOT ON PAGE 2
  21. 140  REM  DRAWS FIGURE OUT OF SIGHT ON PAGE 2 BEFORE MOVING IT TO PAGE 1
  22. 150  HCOLOR= 3: REM  WHITE
  23. 160 Y = 80:X = 30
  24. 170  HPLOT X,Y TO X,Y -40 TO X +30,Y TO X +30,Y -40: REM  N
  25. 180  HPLOT X +55,Y TO X +55,Y -15: HPLOT X +55,Y -20: REM  I
  26. 190  HPLOT X +80,Y -35 TO X +80,Y TO X +100,Y TO X +100,Y -15 TO X +80,Y -15: REM  B
  27. 200  HPLOT X +110,Y -35 TO X +110,Y TO X +130,Y TO X +130,Y -15 TO X +110,Y -15: REM  B
  28. 210  HPLOT X +150,Y TO X +150,Y -35: REM  L
  29. 220  HPLOT X +173,Y -8 TO X +185,Y -8 TO X +185,Y -15 TO X +170,Y -15 TO X +170,Y TO X +185,Y: REM  E
  30. 230 X = 25
  31. 240  FOR I = 1 TO 20: HPLOT X +5 *I,Y +5 +2 *I TO X +200 -5 *I,Y +5 +2 *I: NEXT 
  32. 250  VTAB 22: HTAB 1
  33. 260  PRINT "PRESS <RETURN> TO MOVE PICTURE": PRINT "PRESS <ESC> TO QUIT"
  34. 270  VTAB 24: POKE  -16368,0: GET X$: IF X$ =  CHR$(13)  THEN 340
  35. 280  IF X$ =  CHR$(27)  THEN  TEXT : HOME : END 
  36. 290  GOTO 250
  37. 300  REM 
  38. 310  REM  INPUT MONITOR COMMANDS
  39. 320  REM  INTO KEYBOARD BUFFER
  40. 330  REM 
  41. 340  FOR I = 1 TO  LEN(I$)
  42. 350  POKE 511 +I, ASC( MID$ (I$,I)) +128
  43. 360  NEXT 
  44. 370  POKE 72,0: POKE 223, PEEK(248): REM  ZERO STATUS REGISTER TO AVOID 'HANG'; ALSO SAVE STACK POINTER FOR RESUME HANDLER
  45. 380  CALL 65392: REM  $FF70,-144-->SCAN THE KEYBOARD INPUT BUFFER
  46. 390  HOME : VTAB 23: HTAB 1: PRINT "PRESS <RETURN>";: POKE  -16368,0: GET X$
  47. 400  GOTO 130: REM  DO IT AGAIN