home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib28b.dsk / FILE.MAKER.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  44 lines
  1. 10  REM  **********************
  2. 20  REM  *     FILE.MAKER     *
  3. 30  REM  *   BY L. GLASSER    *
  4. 40  REM  * COPYRIGHT (C) 1986 *
  5. 50  REM  * BY MICROSPARC, INC *
  6. 60  REM  * CONCORD, MA  01742 *
  7. 70  REM  **********************
  8. 80  DIM ST$(99)
  9. 90  HOME 
  10. 100 N = 0
  11. 110 N = N +1
  12. 120 H$ = "":Z = 0
  13. 130  CALL  -868
  14. 140  GET B$:Z = Z +1: IF B$ < > CHR$(13)  AND Z >220  THEN  PRINT : PRINT : PRINT  CHR$(7);"WARNING: ";Z" CHARACTERS IN LINE.": PRINT "PRESS <RETURN> TO FINISH LINE": PRINT : PRINT H$ +B$
  15. 150  IF B$ < > CHR$(13)  AND Z >220  THEN  PRINT "ABOVE IS LINE, INCLUDING LAST ENTRY": PRINT 
  16. 160  IF Z >237 GOTO 270
  17. 170  IF B$ =  CHR$(13)  THEN  GOTO 270: REM  RETURN
  18. 180  IF B$ =  CHR$(8)  THEN  GOTO 210
  19. 190  PRINT B$;:H$ = H$ +B$
  20. 200  GOTO 130
  21. 210  IF  LEN(H$) < = 1  THEN  POKE 36,0: GOTO 120
  22. 220 X =  PEEK(36): IF X = 0  THEN 250
  23. 230  POKE 36, PEEK(36) -1
  24. 240 Z = Z -2:H$ =  LEFT$(H$, LEN(H$) -1): GOTO 130
  25. 250 Z = Z -2:H$ =  LEFT$(H$, LEN(H$) -1):Y =  PEEK(37): IF Y >0  THEN  VTAB (Y): POKE 36,39
  26. 260  GOTO 130
  27. 270 ST$(N) = H$: PRINT : IF  LEN(H$) = 0  THEN 290
  28. 280  GOTO 110
  29. 290  ONERR  GOTO 430
  30. 300  PRINT  CHR$(4);"MON C,I,O"
  31. 310  HOME 
  32. 320  INPUT "NAME OF TEXT FILE ";N$: IF N$ = ""  OR N$ <"A"  OR N$ > =  CHR$(91)  THEN  PRINT  CHR$(7);: GOTO 310
  33. 330  PRINT  CHR$(4);"OPEN ";N$
  34. 340  PRINT  CHR$(4);"DELETE ";N$
  35. 350  PRINT  CHR$(4);"OPEN ";N$
  36. 360  PRINT  CHR$(4);"WRITE ";N$
  37. 370  FOR K = 1 TO N -1
  38. 380  PRINT ST$(K)
  39. 390  NEXT K
  40. 400  PRINT  CHR$(4);"CLOSE ";N$
  41. 410  POKE 34,0
  42. 420  PRINT  CHR$(4);"NOMON C,I,O": END 
  43. 430 ER =  PEEK(222):EL =  PEEK(218) +256 * PEEK(219)
  44. 440  HOME : VTAB 12: PRINT "ERROR "ER" IN LINE "EL".": VTAB 23: PRINT "PRESS <RETURN> TO CONTINUE": GET Z$: PRINT : GOTO 310