home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib28a.dsk / MAY.1986 / READ.DIR.FILES.bas < prev   
BASIC Source File  |  2023-02-26  |  1KB  |  44 lines
  1. 10  REM  **********************
  2. 20  REM  *   READ.DIR.FILES   *
  3. 30  REM  * BY  SANDY MOSSBERG *
  4. 40  REM  * COPYRIGHT (C) 1986 *
  5. 50  REM  * BY MICROSPARC, INC *
  6. 60  REM  * CONCORD, MA  01742 *
  7. 70  REM  **********************
  8. 80 D$ =  CHR$(4): DIM C$(500)
  9. 90  REM -----------------------
  10. 100  REM  Get Name of Directory
  11. 110  REM ----------------------
  12. 120  HOME 
  13. 130  PRINT D$"PREFIX": INPUT P$
  14. 140  PRINT "Current Prefix: "P$: PRINT 
  15. 150  INPUT "Name of directory file: ";F$
  16. 160  IF F$ = ""  THEN F$ = P$: CALL  -998: HTAB 25: PRINT F$
  17. 170  REM --------------------
  18. 180  REM  Read Directory File
  19. 190  REM --------------------
  20. 200  PRINT D$"OPEN"F$",TDIR"
  21. 210  PRINT D$"READ"F$
  22. 220 N = 0
  23. 230 N = N +1
  24. 240  INPUT C$(N)
  25. 250  IF  LEFT$(C$(N),11) < >"BLOCKS FREE"  THEN 230
  26. 260  PRINT D$"CLOSE"
  27. 270  REM -------------------
  28. 280  REM  Print Desired Data
  29. 290  REM -------------------
  30. 300  HOME : PRINT "Directory Name: ";
  31. 310  IF  LEFT$(F$,1) = "/"  THEN  PRINT F$: GOTO 330
  32. 320  PRINT P$;F$
  33. 330  PRINT : PRINT  LEFT$(C$(2),20);: HTAB 25: PRINT "START    LENGTH": PRINT 
  34. 340 FLAG = 0:F = 0
  35. 350  FOR I = 4 TO N -2
  36. 360 M$ =  MID$ (C$(I),18,3)
  37. 370  IF M$ < >"BIN"  AND M$ < >"SYS"  THEN 420
  38. 380 FLAG = 1:F = F +1
  39. 390  PRINT  LEFT$(C$(I),20);: REM  file type field
  40. 400  HTAB 25: PRINT  RIGHT$(C$(I),5);: REM  starting address field
  41. 410  HTAB 32: PRINT  MID$ (C$(I),64,8): REM  length field
  42. 420  NEXT I
  43. 430  IF   NOT FLAG  THEN  PRINT "<NO FILES>"
  44. 440  PRINT : PRINT "Total SYS and BIN files: "F