home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib25b.dsk / BLACKJACK.bas < prev    next >
BASIC Source File  |  2023-02-26  |  14KB  |  232 lines

  1. 10  REM ******07/17/85********
  2. 20  REM *     BLACKJACK      *
  3. 30  REM *   BY JIM FEEHAN    *
  4. 40  REM * COPYRIGHT (C) 1985 *
  5. 50  REM * BY MICROSPARC, INC *
  6. 60  REM * CONCORD, MA  01742 *
  7. 70  REM **********************
  8. 80  IF  PEEK(104) < >64  THEN  POKE 16384,0: POKE 104,64: POKE 103,1: PRINT  CHR$(4)"RUN BLACKJACK"
  9. 90  REM  - RANDOMIZE
  10. 100 J =  PEEK(78):J = J +1: IF J >255  THEN J = 255
  11. 110  FOR I = 1 TO J:NUM =  RND(1): NEXT I: POKE 202,J
  12. 120  PRINT  CHR$(4)"BLOAD BLACKJACK.SHAPE,A$900"
  13. 130  REM  - POKE SHAPE TABLE ADDR
  14. 140  TEXT : HOME : POKE 232,0: POKE 233,9: DIM DECK(52),T(2):LOOT = 0
  15. 150  VTAB 2: HTAB 15: PRINT "WELCOME TO": FOR I = 1 TO 1000: NEXT : GOTO 1780
  16. 160  REM  - PRINT SUBROUTINES
  17. 170  IF F = 2  THEN 230
  18. 180  GOTO 270
  19. 190  IF F = 2  THEN 210
  20. 200  GOTO 250
  21. 210  IF W = 1  THEN  PRINT "YOUR 1ST HAND LOSES 1 COIN.": RETURN 
  22. 220  PRINT "YOUR 1ST HAND LOSES ";W;" COINS.": RETURN 
  23. 230  IF W = 1  THEN  PRINT "YOUR 1ST HAND WINS 1 COIN.": RETURN 
  24. 240  PRINT "YOUR 1ST HAND WINS ";W;" COINS.";: RETURN 
  25. 250  IF W = 1  THEN  PRINT "YOU LOSE 1 COIN.": RETURN 
  26. 260  PRINT "YOU LOSE ";W;" COINS.": RETURN 
  27. 270  IF W = 1  THEN  PRINT "YOU WIN 1 COIN.": RETURN 
  28. 280  PRINT "YOU WIN ";W;" COINS.": RETURN 
  29. 290  IF W = 1  THEN  PRINT "YOUR 2ND HAND LOSES 1 COIN.": RETURN 
  30. 300  PRINT "YOUR 2ND HAND LOSES ";W;" COINS.": RETURN 
  31. 310  IF W = 1  THEN  PRINT "YOUR 2ND HAND WINS 1 COIN.": RETURN 
  32. 320  PRINT "YOUR SECOND HAND WINS ";W;" COINS.": RETURN 
  33. 330  VTAB 23: HTAB 1: PRINT "YOUR NET GAIN = ";LOOT;" COINS.": RETURN 
  34. 340  VTAB 24: HTAB 1: PRINT "HIT ANY KEY TO CONTINUE (ESC=QUIT) ";: GET W$: IF  ASC(W$) = 27  THEN  POP : GOTO 1980
  35. 350  RETURN 
  36. 360  REM  - FIND SUIT FOR DRAW ROUTINE
  37. 370 SUIT = 4: IF DECK(A) <40  THEN SUIT = 3: IF DECK(A) <27  THEN SUIT = 2: IF DECK(A) <14  THEN SUIT = 1
  38. 380  RETURN 
  39. 390  REM  - CLEAR HI-RES SCREEN
  40. 400  POKE 230,32: HCOLOR= 0: HPLOT 0,0: CALL 62454
  41. 410  REM  - SHUFFLE DECK
  42. 420  FOR I = 1 TO 52:DECK(I) = I: NEXT 
  43. 430  FOR J = 1 TO 52:I =  INT( RND(1) *52 +1)
  44. 440 K = DECK(J):DECK(J) = DECK(I):DECK(I) = K: NEXT 
  45. 450  REM  - DRAW 1ST 4 CARDS
  46. 460  HOME : HGR : ROT= 0: SCALE= 1: HCOLOR= 7: HPLOT 0,0: CALL 62454: HCOLOR= 0
  47. 470 DECK(51) = DECK(1):DECK(52) = DECK(2):DECK(50) = DECK(3)
  48. 480 A = 1:C = 1: GOSUB 370: GOSUB 2010:A = 2
  49. 490  FOR I = 1 TO 250: NEXT 
  50. 500  GOSUB 370:C = 2: GOSUB 2010:A = 3
  51. 510  FOR I = 1 TO 250: NEXT 
  52. 520  GOSUB 370: IF SUIT = 2  THEN DECK(3) = DECK(3) -13
  53. 530  IF SUIT = 3  THEN DECK(3) = DECK(3) -26
  54. 540  IF SUIT = 4  THEN DECK(3) = DECK(3) -39
  55. 550  HPLOT 1,0 TO 51,0 TO 51,71 TO 1,71 TO 1,0
  56. 560  FOR I = 2 TO 50  STEP 5: HPLOT I,0 TO I,71: NEXT 
  57. 570  FOR I = 1 TO 70  STEP 5: HPLOT 1,I TO 51,I: NEXT 
  58. 580  HCOLOR= 5: FOR I = 5 TO 50  STEP 5: HPLOT I,0 TO I,71: NEXT 
  59. 590  FOR I = 5 TO 70  STEP 5: HPLOT 1,I TO 51,I: NEXT : HCOLOR= 0
  60. 600  FOR I = 1 TO 250: NEXT 
  61. 610 A = 4: GOSUB 370:C = 2: GOSUB 2100:A = 5
  62. 620  REM  - CHECK FOR DEALER BLACKJACK
  63. 630  FOR I = 21 TO 26:DECK(I) = 0: NEXT 
  64. 640  IF DECK(3) >10  THEN DECK(3) = 10
  65. 650  IF DECK(4) >10  THEN DECK(4) = 10
  66. 660  IF DECK(3) +DECK(4) = 11  AND DECK(3) = 1  THEN 2230
  67. 670  IF DECK(3) +DECK(4) = 11  AND DECK(4) = 1  THEN 2230
  68. 680  REM  - CHECK FOR POSSIBLE SPLIT
  69. 690  IF DECK(1) < >DECK(2)  THEN DECK(21) = DECK(1):DECK(22) = DECK(2):F$ = "N": GOTO 780
  70. 700  IF DECK(1) = DECK(2)  THEN  VTAB 23: PRINT "DO YOU WANT TO SPLIT THESE CARDS (Y/N)? ";: GET F$: IF F$ = "N"  THEN DECK(21) = DECK(1):DECK(22) = DECK(2): GOTO 950
  71. 710  IF F$ < >"Y"  THEN 700
  72. 720  REM  - ERASE 2ND CARD
  73. 730  HCOLOR= 7: FOR I = 57 TO 107: HPLOT I,80 TO I,151: NEXT 
  74. 740  FOR I = 1 TO 250: NEXT 
  75. 750  REM  - DRAW NEW 2ND CARD
  76. 760 C = 2:A = 5: HCOLOR= 0: GOSUB 370: GOSUB 2010:DECK(21) = DECK(1):DECK(22) = DECK(5)
  77. 770  REM  - SET FACE CARDS TO 10
  78. 780  IF DECK(21) >10  THEN DECK(21) = 10
  79. 790  IF DECK(22) >10  THEN DECK(22) = 10
  80. 800  IF DECK(23) >10  THEN DECK(23) = 10
  81. 810  IF DECK(24) >10  THEN DECK(24) = 10
  82. 820  IF DECK(25) >10  THEN DECK(25) = 10
  83. 830  IF DECK(26) >10  THEN DECK(26) = 10
  84. 840  IF DECK(52) = 99  THEN 2310
  85. 850  REM  - CHECK FOR PLAYER'S BLACKJACK
  86. 860  IF DECK(21) +DECK(22) < >11  OR DECK(23) >0  THEN 950
  87. 870  IF DECK(21) = 1  OR DECK(22) = 1  THEN  HOME : VTAB 21: INVERSE : HTAB 13: PRINT "BLACKJACK !!!": NORMAL : GOTO 930
  88. 880  REM  - 1ST 2 CARDS TOTAL 11
  89. 890  IF F = 1  AND F$ = "N"  THEN  VTAB 22: HTAB 1: PRINT "DO YOU WANT TO DOUBLE DOWN (Y/N)? ";: GET W$: IF W$ < >"Y"  AND W$ < >"N"  THEN 890
  90. 900  IF W$ = "Y"  THEN 2300
  91. 910  GOTO 950
  92. 920  REM  - PAYOFF BLACKJACK
  93. 930  PRINT "YOU WIN ";W *4;" COINS.":LOOT = LOOT +(W *4): GOSUB 330: GOSUB 340:T(F) =  -1:T(0) = 0: HOME : GOTO 1080
  94. 940  REM  - BEGIN MAIN ROUTINE - TOTAL CARDS DEALT SO FAR
  95. 950 T(F) = DECK(21) +DECK(22) +DECK(23) +DECK(24) +DECK(25) +DECK(26): IF T(F) >21  THEN 1030
  96. 960  REM  - CHECK FOR ACES
  97. 970 T(0) = 0: FOR I = 21 TO 26: IF DECK(I) = 1  THEN T(0) = T(0) +1
  98. 980  NEXT I
  99. 990  IF T(F) <22  THEN  HOME : VTAB 21: PRINT "YOUR TOTAL IS ";T(F);
  100. 1000  IF T(0) >0  AND T(F) +10 <22  THEN T(F) = T(F) +10: PRINT " OR ";T(F)
  101. 1010  GOSUB 330
  102. 1020  IF T(F) <22  THEN 1250
  103. 1030 LOOT = LOOT -W
  104. 1040  HOME : VTAB 21: INVERSE : PRINT "BUSTED !!!";: NORMAL : HTAB 14: PRINT T(F);: INVERSE : HTAB 20: PRINT "BUSTED !!!": NORMAL 
  105. 1050  GOSUB 190: GOSUB 330
  106. 1060 T(F) =  -1: GOSUB 340: HOME 
  107. 1070  REM  - CHECK FOR SPLIT
  108. 1080  IF F = 1  AND F$ = "N"  THEN 1900
  109. 1090  IF T(1) =  -1  AND T(2) =  -1  THEN  HOME : GOTO 1900
  110. 1100  IF F = 2  AND T(1) >0  THEN 1440
  111. 1110  REM  - ERASE 1ST HAND OF SPLIT
  112. 1120  HCOLOR= 7: FOR I = 80 TO 151: HPLOT 0,I TO 275,I: NEXT : HCOLOR= 0
  113. 1130  REM  - DRAW 2ND HAND
  114. 1140 C = 1:DECK(29) = A:A = 52:F = 2:F$ = "N": GOSUB 370: GOSUB 2010:A = DECK(29) +1
  115. 1150  GOSUB 370: IF SUIT = 2  THEN DECK(3) = DECK(3) -13
  116. 1160  IF SUIT = 3  THEN DECK(3) = DECK(3) -26
  117. 1170  IF SUIT = 4  THEN DECK(3) = DECK(3) -39
  118. 1180  FOR I = 1 TO 250: NEXT :C = 2: GOSUB 2010
  119. 1190  REM  - CLEAR 1ST HAND'S TOTAL
  120. 1200 DECK(21) = DECK(52):DECK(22) = DECK(A):DECK(23) = 0:DECK(24) = 0:DECK(25) = 0:DECK(26) = 0
  121. 1210  REM  - TOTAL FOR 2ND HAND
  122. 1220 T(F) = DECK(21) +DECK(22) +DECK(23) +DECK(24) +DECK(25) +DECK(26)
  123. 1230  GOTO 780
  124. 1240  REM  - COME HERE AFTER EACH CARD IS DRAWN
  125. 1250 W$ = "S": IF C < >6  THEN  VTAB 24: HTAB 1: INVERSE : PRINT "DO YOU WANT TO HIT OR STAND (H/S)? ";: GET W$: NORMAL 
  126. 1260  IF W$ = "S"  THEN 1310
  127. 1270  IF W$ < >"H"  THEN 1250
  128. 1280  REM  - DRAW HIT CARD
  129. 1290 C = C +1:A = A +1: GOSUB 370: GOSUB 2010:DECK(20 +C) = DECK(A): GOTO 780
  130. 1300  REM  - CHECK FOR 5 OR 6 CARDS UNDER 21
  131. 1310  IF C < >6  AND C < >5  THEN 1400
  132. 1320  HOME : IF C = 6  THEN LOOT = LOOT +(W *10)
  133. 1330  IF C = 5  THEN LOOT = LOOT +(W *5)
  134. 1340  VTAB 21: INVERSE : PRINT "YOU HAVE ";C;" CARDS AND ONLY ";T(F);" POINTS."
  135. 1350  IF C = 5  THEN  PRINT "YOU HAVE WON ";W *5;" COINS !!": NORMAL 
  136. 1360  IF C = 6  THEN  PRINT "YOU HAVE WON ";W *10;" COINS!!": NORMAL 
  137. 1370  GOSUB 330
  138. 1380 T(F) = 0:T(0) = 0: GOSUB 340: HOME : GOTO 1080
  139. 1390  REM  - ADD 10 IF THERE IS AN ACE
  140. 1400  IF T(0) >1  AND T(F) +10 <22  THEN T(F) = T(F) +10
  141. 1410  IF F$ = "N"  THEN 1440
  142. 1420  GOTO 1120
  143. 1430  REM  - DEALER PLAYS - DRAW DOWN CARD
  144. 1440 C = 1: HCOLOR= 7: FOR I = 0 TO 51: HPLOT I,0 TO I,71: NEXT : HCOLOR= 0:DECK(3) = DECK(50)
  145. 1450 DECK(29) = A:A = 3: GOSUB 370: GOSUB 2100:A = DECK(29):C = 2
  146. 1460 DECK(21) = DECK(3):DECK(22) = DECK(4):DECK(23) = 0:DECK(24) = 0:DECK(25) = 0:DECK(26) = 0
  147. 1470  FOR I = 21 TO 26: IF DECK(I) >10  THEN DECK(I) = 10
  148. 1480  NEXT I
  149. 1490  FOR I = 21 TO 26: IF DECK(I) = 1  THEN DECK(0) = DECK(0) +1
  150. 1500  NEXT 
  151. 1510  REM  - GET DEALER'S TOTAL
  152. 1520 T(0) = DECK(21) +DECK(22) +DECK(23) +DECK(24) +DECK(25) +DECK(26): IF T(0) >21  THEN 1660
  153. 1530  IF C = 5  AND T(0) <22  THEN  HOME : VTAB 21: PRINT "DEALER HAS FIVE CARDS UNDER 22.": GOSUB 190:LOOT = LOOT -W: GOSUB 330: GOSUB 340: IF F = 1  THEN  HOME : GOTO 1900
  154. 1540  IF C = 5  AND T(0) <22  AND F = 2  THEN  HOME : VTAB 22: HTAB 1: GOSUB 290:LOOT = LOOT -W: GOSUB 330: GOSUB 340: HOME : GOTO 1900
  155. 1550  IF T(0) <22  THEN  HOME : VTAB 21: PRINT "DEALER'S TOTAL IS ";T(0);
  156. 1560  IF DECK(0) >0  AND T(0) +10 <22  THEN T(0) = T(0) +10: PRINT " OR ";T(0)
  157. 1570  IF F = 2  AND T(2) =  -1  THEN  VTAB 22: HTAB 1: PRINT "YOUR 1ST HAND'S TOTAL WAS ";T(1): GOSUB 330: GOSUB 340: GOTO 1600
  158. 1580  VTAB 22: HTAB 1: PRINT "YOUR TOTAL IS ";T(F): GOSUB 330: GOSUB 340
  159. 1590  REM  - HIT DEALER
  160. 1600  IF T(0) <16  THEN C = C +1:A = A +1: GOSUB 370: GOSUB 2100:DECK(20 +C) = DECK(A): GOTO 1470
  161. 1610  IF T(0) <T(1)  AND T(0) <T(2)  THEN T(0) = 15: GOTO 1600
  162. 1620  IF T(0) >T(1)  AND T(0) >T(2)  THEN 1680
  163. 1630  IF (T(0) > = T(1)  AND T(1) < > -1)  OR (T(0) > = T(2)  AND T(2) >0)  THEN 1680
  164. 1640  IF T(0) <T(1)  THEN T(0) = 15: GOTO 1600
  165. 1650  IF T(0) <T(2)  THEN T(0) = 15: GOTO 1600
  166. 1660  HOME : VTAB 21: PRINT "DEALER HAS ";T(0);".  HE IS BUSTED !!!"
  167. 1670  REM  - PAYOFF ROUTINES
  168. 1680  IF T(0) >21  AND T(1) >0  AND T(1) <22  THEN LOOT = LOOT +W: VTAB 22: GOSUB 170: GOSUB 330: GOSUB 340: HOME : IF T(2) = 0  THEN  TEXT : GOTO 1900
  169. 1690  IF T(0) >21  AND T(2) >0  AND T(2) <22  THEN LOOT = LOOT +W: VTAB 22: HTAB 1: GOSUB 310: GOSUB 330
  170. 1700  IF T(0) >21  THEN 1760
  171. 1710  IF T(0) > = T(1)  AND T(1) >0  THEN LOOT = LOOT -W: HOME : VTAB 21: PRINT "DEALER WINS.": GOSUB 190: GOSUB 330: IF T(2) >0  THEN  GOSUB 340
  172. 1720  IF T(0) <T(1)  AND T(1) >0  THEN LOOT = LOOT +W: VTAB 22: PRINT "YOUR 1ST HAND BEATS THE DEALER.": GOSUB 170: GOSUB 330
  173. 1730  IF T(0) > = T(2)  AND T(2) >0  THEN LOOT = LOOT -W: HOME : VTAB 21: PRINT "DEALER BEATS YOUR 2ND HAND.": GOSUB 250: GOSUB 330
  174. 1740  IF T(1) >0  AND T(1) >T(0)  THEN LOOT = LOOT +W: HOME : VTAB 22: PRINT "YOUR TOTAL BEATS THE DEALER.": GOSUB 170: GOSUB 330: IF T(2) >0  THEN  GOSUB 340
  175. 1750  IF T(2) >0  AND T(2) >T(0)  THEN LOOT = LOOT +W: HOME : VTAB 22: PRINT "YOUR 2ND HAND BEATS THE DEALER.": GOSUB 270: GOSUB 330
  176. 1760  GOSUB 340: TEXT : HOME : GOTO 1900
  177. 1770  REM  - INITIAL PRINT ROUTINE
  178. 1780  HOME : VTAB 4: HTAB 12: INVERSE : PRINT "NIBBLE BLACKJACK": NORMAL : VTAB 1: PRINT "* COPYRIGHT 1985 BY MICROSPARC, INC. *"
  179. 1790  VTAB 7: PRINT "YOU MAY WAGER 1-5 COINS ON EACH HAND.   IF YOU SPLIT, YOUR WAGER IS DOUBLED     AUTOMATICALLY."
  180. 1800  PRINT "DEALER WINS ALL PUSHES (TIES)"
  181. 1810  VTAB 12: PRINT "========================================"
  182. 1820  VTAB 13: PRINT "= SPECIALS:                            ="
  183. 1830  VTAB 14: PRINT "=";: HTAB 40: PRINT "="
  184. 1840  VTAB 15: PRINT "= FIVE CARDS TOTALING LESS THAN 22 PAY == 5 TO 1. SIX CARDS TOTALING LESS THAN == 22 PAY 10 TO 1.                      ="
  185. 1850  VTAB 18: PRINT "=";: HTAB 40: PRINT "="
  186. 1860  VTAB 19: PRINT "=";: HTAB 40: PRINT "="
  187. 1870  VTAB 20: PRINT "= BLACKJACK PAYS 4 TO 1.               ="
  188. 1880  VTAB 21: PRINT "========================================"
  189. 1890  REM  - EACH HAND STARTS HERE
  190. 1900  VTAB 23: HTAB 1: PRINT "HOW MANY COINS WILL YOU BET (1-5)?": HTAB 24: PRINT "(ESC=QUIT) ";: VTAB 23: HTAB 36: GET W$
  191. 1910  IF  ASC(W$) = 27  THEN 1980
  192. 1920  REM  - RESET ALL COUNTERS
  193. 1930 A = 0:C = 0:F$ = "":SUIT = 0:T(0) = 0:T(1) = 0:T(2) = 0:W = 0:DECK(0) = 0
  194. 1940  REM  - CHECK FOR BET 1 TO 5
  195. 1950 W =  ASC(W$): IF W <49  OR W >53  THEN 1900
  196. 1960  HOME :F = 1:W = W -48: VTAB 12: HTAB 15: PRINT "SHUFFLING": GOTO 400
  197. 1970  IF C = 5  AND T(0) <22  THEN  HOME : VTAB 22: PRINT "DEALER HAS FIVE CARDS UNDER 22.": GOSUB 24:LOOT = LOOT -W: HTAB 20: PRINT "YOUR NET GAIN = ";LOOT: GOSUB 340: GOTO 1900
  198. 1980  TEXT : HOME : VTAB 4: PRINT "ARE YOU SURE YOU WANT TO QUIT?";: GET Z$: PRINT : HOME : IF Z$ < >"Y" GOTO 1900
  199. 1990  END 
  200. 2000  REM  - DRAW ROUTINES FOR PLAYER'S CARDS
  201. 2010  HCOLOR= 0
  202. 2020  IF C = 1  THEN  HPLOT 1,80 TO 51,80 TO 51,151 TO 1,151 TO 1,80:X = 26:Y = 105
  203. 2030  IF C = 2  THEN  HPLOT 57,80 TO 107,80 TO 107,151 TO 57,151 TO 57,80:X = 83:Y = 105
  204. 2040  IF C = 3  THEN  HPLOT 113,80 TO 163,80 TO 163,151 TO 113,151 TO 113,80:X = 138:Y = 105
  205. 2050  IF C = 4  THEN  HPLOT 169,80 TO 219,80 TO 219,151 TO 169,151 TO 169,80:X = 194:Y = 105
  206. 2060  IF C = 5  THEN  HPLOT 225,80 TO 275,80 TO 275,151 TO 225,151 TO 225,80:X = 250:Y = 105
  207. 2070  IF C = 6  THEN  HPLOT 225,0 TO 275,0 TO 275,71 TO 225,71 TO 225,0:X = 250:Y = 25
  208. 2080  GOTO 2170
  209. 2090  REM  - DRAW ROUTINES FOR DEALER'S CARDS
  210. 2100  IF C = 2  THEN  HPLOT 57,0 TO 107,0 TO 107,71 TO 57,71 TO 57,0:X = 82:Y = 25
  211. 2110  IF C = 3  THEN  HPLOT 113,0 TO 163,0 TO 163,71 TO 113,71 TO 113,0:X = 138:Y = 25
  212. 2120  IF C = 4  THEN  HPLOT 169,0 TO 219,0 TO 219,71 TO 169,71 TO 169,0:X = 194:Y = 25
  213. 2130  IF C = 1  THEN  HPLOT 1,0 TO 51,0 TO 51,71 TO 1,71 TO 1,0:X = 26:Y = 25
  214. 2140  IF C = 5  THEN  HPLOT 225,0 TO 275,0 TO 275,71 TO 225,71 TO 225,0:X = 250:Y = 25
  215. 2150  IF C = 6  THEN  HPLOT 225,80 TO 275,80 TO 275,151 TO 225,151 TO 225,80:X = 250:Y = 105
  216. 2160  REM  - DRAW SUIT AND VALUE - X,Y DETERMINE CENTER OF CARD
  217. 2170  ON SUIT GOTO 2180,2190,2200,2210
  218. 2180  ROT= 32: HCOLOR= 5: DRAW 14 AT X,Y +20: DRAW DECK(A) AT X +21,Y +44: ROT= 0: DRAW DECK(A) AT X -21,Y -23: HCOLOR= 0: RETURN 
  219. 2190  DRAW 15 AT X,Y:DECK(A) = DECK(A) -13: ROT= 32: DRAW DECK(A) AT X +21,Y +44: ROT= 0: DRAW DECK(A) AT X -21,Y -23: RETURN 
  220. 2200  HCOLOR= 5: DRAW 16 AT X,Y:DECK(A) = DECK(A) -26: ROT= 32: DRAW DECK(A) AT X +21,Y +44: ROT= 0: DRAW DECK(A) AT X -21,Y -23: HCOLOR= 0: RETURN 
  221. 2210  DRAW 17 AT X,Y:DECK(A) = DECK(A) -39: ROT= 32: DRAW DECK(A) AT X +21,Y +44: ROT= 0: DRAW DECK(A) AT X -21,Y -23: RETURN 
  222. 2220  REM  - DEALER'S BLACKJACK ROUTINE
  223. 2230  HCOLOR= 7: FOR I = 0 TO 51: HPLOT I,0 TO I,71: NEXT 
  224. 2240  HCOLOR= 0:C = 1:A = 50
  225. 2250  GOSUB 370: GOSUB 2100
  226. 2260  VTAB 21: INVERSE : PRINT "DEALER HAS BLACKJACK !!": NORMAL :LOOT = LOOT -W
  227. 2270  GOSUB 190: GOSUB 330
  228. 2280  GOSUB 340: TEXT : HOME : GOTO 1900
  229. 2290  REM  - PLAYER'S DOUBLE DOWN ROUTINE
  230. 2300 C = 3:A = 5: GOSUB 370: GOSUB 2010:DECK(23) = DECK(5):DECK(52) = 99: GOTO 780
  231. 2310 T(1) = DECK(21) +DECK(22) +DECK(23):W = W *2
  232. 2320  HOME : VTAB 21: PRINT "YOU HAVE DOUBLED DOWN AND MUST STAND ON THESE THREE CARDS - YOUR TOTAL IS ";T(1): GOSUB 330: GOSUB 340: HOME : GOTO 1440