home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Nibble Magazine
/
nib25a.dsk
/
JULY.1985
/
DECISION.MAKER.bas
< prev
next >
Wrap
BASIC Source File
|
2023-02-26
|
2KB
|
46 lines
10 REM *************************
20 REM * DECISION.MAKER *
30 REM * BY BEIRNE L. KONARSKI *
40 REM * COPYRIGHT (C) 1985 *
50 REM * BY MICROSPARC, INC. *
60 REM * CONCORD, MA 01742 *
70 REM *************************
80 REM
90 REM **********************
100 REM CHOOSE PRIORITIES
110 REM **********************
120 HOME
130 VTAB 5: HTAB 14: PRINT "DECISION MAKER"
140 HTAB 19: PRINT "BY"
150 HTAB 12: PRINT "BEIRNE L. KONARSKI": PRINT : PRINT "* COPYRIGHT (C) 1985 MICROSPARC, INC. *"
160 VTAB 13: HTAB 1: CALL -958: INPUT "HOW MANY CHOICES DO YOU HAVE? ";C$:C = VAL(C$): IF C <3 THEN 160
170 DIM LIS$(C),TALLY(C)
180 FOR X = 1 TO C
190 PRINT "CHOICE #"X;: INPUT LIS$(X)
200 NEXT
210 FOR X = 1 TO C -1
220 FOR Y = X +1 TO C
230 HOME
240 PRINT "1. "LIS$(X)
250 PRINT
260 PRINT "2. "LIS$(Y)
270 PRINT
280 PRINT "WHICH IS MORE IMPORTANT TO YOU? ": GET ANSWER$
290 IF ANSWER$ = "1" THEN TALLY(X) = TALLY(X) +1: GOTO 320
300 IF ANSWER$ < >"2" THEN PRINT : PRINT "1 OR 2 PLEASE": PRINT : PRINT : PRINT "PRESS <RETURN> TO CONTINUE": GET A$: GOTO 230
310 TALLY(Y) = TALLY(Y) +1
320 NEXT
330 NEXT
340 REM *********************
350 REM DISPLAY PRIORITIES
360 REM *********************
370 HOME
380 FOR X = C -1 TO 1 STEP -1
390 FOR Y = 1 TO X
400 IF TALLY(Y) <TALLY(Y +1) THEN HOLD = TALLY(Y):TALLY(Y) = TALLY(Y +1):TALLY(Y +1) = HOLD:TEMP$ = LIS$(Y):LIS$(Y) = LIS$(Y +1):LIS$(Y +1) = TEMP$
410 NEXT : NEXT
420 PRINT "HERE IS THE ORDER OF PRIORITY"
430 FOR X = 1 TO C: PRINT LIS$(X);: HTAB 20: PRINT TALLY(X): NEXT
440 VTAB 22: PRINT "WOULD YOU LIKE TO RE-START? (Y/N)";: GET A$
450 IF A$ = "Y" THEN CLEAR : GOTO 120
460 PRINT : HOME : END