home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib24a.dsk / MAY.1985 / MOUNTAIN.PRODOS.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  50 lines
  1. 10  REM  **********************
  2. 20  REM  *  MOUNTAIN.PRODOS   *
  3. 30  REM  *  BY FRED TIBBITTS  *
  4. 40  REM  * COPYRIGHT (C) 1985 *
  5. 50  REM  * BY MICROSPARC, INC *
  6. 60  REM  * CONCORD, MA  01742 *
  7. 70  REM  **********************
  8. 80  REM  ######## INITIALIZE #########
  9. 90 YEAR$ = "85":SLOT = 4
  10. 100 D$ =  CHR$(4)
  11. 110  REM  ######## READ DATA FROM CLOCK CARD ########
  12. 120  PRINT D$;"IN#";SLOT
  13. 130  PRINT D$;"PR#";SLOT
  14. 140  INPUT " ";T$
  15. 150  PRINT D$;"IN#0"
  16. 160  PRINT D$;"PR#0"
  17. 170  REM  ####### PRINT TITLE TO SCREEN #########
  18. 180  TEXT : HOME 
  19. 190  VTAB 5: HTAB 12: PRINT "MOUNTAIN.PRODOS"
  20. 200  VTAB 7: PRINT "** COPYRIGHT 1985 BY MICROSPARC, INC. **"
  21. 210  REM  ####### SET DATA TO BE POKED INTO MEMORY WHERE PRODOS WILL RECOGNIZE IT #######
  22. 220  REM  DAY
  23. 230 DD =  VAL( MID$ (T$,4,1))
  24. 240 DD = DD *10 + VAL( MID$ (T$,5,1))
  25. 250  REM  MONTH
  26. 260 MM =  VAL( LEFT$(T$,2))
  27. 270  REM  YEAR
  28. 280 YY =  VAL( LEFT$(YEAR$,1)) *10 + VAL( RIGHT$(YEAR$,1))
  29. 290  REM  HOUR
  30. 300 HH = 10 * VAL( MID$ (T$,7,1)) + VAL( MID$ (T$,8,1))
  31. 310 HOUR$ =  MID$ (T$,7,2)
  32. 320 HOUR =  VAL(HOUR$)
  33. 330 HR = HOUR: IF HR = 0  THEN HR = 12
  34. 340  IF HR >12  THEN HOUR = HR -12
  35. 350 P$ = "A": IF HR >11  THEN P$ = "P"
  36. 360 HH = HOUR
  37. 370  REM  MINUTE
  38. 380 MI = 10 * VAL( MID$ (T$,10,1)) + VAL( MID$ (T$,11,1))
  39. 390  REM  ######### NOW PRINT OUT THE RESULTS ##########
  40. 400  PRINT : PRINT : PRINT "        CURRENT DATE IS: ";MM;"-";DD;"-";YY
  41. 410  PRINT : PRINT "        CURRENT TIME IS: ";HH;":";MI;"   ";P$;"M"
  42. 420  REM  ######## NOW POKE THE DATA INTO MEMORY FOR PRODOS #########
  43. 430  POKE 49041,YY *2 +(MM >7)
  44. 440  IF MM >7  THEN  POKE 49040,(MM -8) *32 +DD
  45. 450  IF MM <8  THEN  POKE 49040,MM *32 +DD
  46. 460  IF HH = 12  THEN HH = 0
  47. 470  IF P$ = "P"  THEN HH = HH +12
  48. 480  POKE 49043,HH: POKE 49042,MI
  49. 490  REM  ######## NOW HAVE THE PROGRAM CATALOG THE DISK OR RUN ONE OF YOUR OWN PROGRAMS ########
  50. 500  END