home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib20a.dsk / JUNE.1984 / ORGAN.APPLE.bas < prev    next >
BASIC Source File  |  2023-02-26  |  3KB  |  96 lines
  1. 10  REM  ************************
  2. 20  REM  *     ORGAN.APPLE      *
  3. 30  REM  * BY JOSEPH YOUNGBLOOD *
  4. 40  REM  * COPYRIGHT  (C)  1984 *
  5. 50  REM  * BY  MICROSPARC, INC. *
  6. 60  REM  * LINCOLN, MASS  01773 *
  7. 70  REM  ************************
  8. 80  REM 
  9. 90  REM 
  10. 100  TEXT : HOME : VTAB 5
  11. 110  HTAB 10: PRINT "*********************"
  12. 120  HTAB 10: PRINT "*";: HTAB 30: PRINT "*"
  13. 130  HTAB 10: PRINT "*";: HTAB 18: PRINT "LITTLE";: HTAB 30: PRINT "*"
  14. 140  HTAB 10: PRINT "*";: HTAB 30: PRINT "*"
  15. 150  HTAB 10: PRINT "*";: HTAB 15: PRINT "ORGAN  APPLE";: HTAB 30: PRINT "*"
  16. 160  HTAB 10: PRINT "*";: HTAB 30: PRINT "*"
  17. 170  HTAB 10: PRINT "*";: HTAB 20: PRINT "BY";: HTAB 30: PRINT "*"
  18. 180  HTAB 10: PRINT "*";: HTAB 30: PRINT "*"
  19. 190  HTAB 10: PRINT "*";: HTAB 12: PRINT "JOSEPH YOUNGBLOOD";: HTAB 30: PRINT "*"
  20. 200  HTAB 10: PRINT "*";: HTAB 30: PRINT "*"
  21. 210  HTAB 10: PRINT "*";: HTAB 18: PRINT "NIBBLE   ";: HTAB 30: PRINT "*"
  22. 220  HTAB 10: PRINT "*";: HTAB 30: PRINT "*"
  23. 230  HTAB 10: PRINT "*********************": VTAB 22: PRINT "** COPYRIGHT 1984 BY MICROSPARC, INC. **"
  24. 240  REM 
  25. 250 D$ =  CHR$(4)
  26. 260  PRINT D$;"BLOAD ORGAN.TABLE"
  27. 270  PRINT D$;"BLOAD ORGAN.OBJ"
  28. 280  REM 
  29. 290  POKE 232,0: POKE 233,96: REM  * SHAPE TABLE
  30. 300  HGR : POKE  -16302,0
  31. 310  HCOLOR= 3: HPLOT 0,0: CALL 62454: REM  * CLEAR SCREEN TO WHITE
  32. 320  HCOLOR= 0
  33. 330  REM 
  34. 340  REM  * TWO ROWS OF KEYS
  35. 350  DIM Z(1):Z(0) = 0:Z(1) = 90
  36. 360  FOR I = 0 TO 1:Y = Z(I)
  37. 370  REM  * WHITE KEYS
  38. 380  FOR X = 65 TO 200  STEP 15
  39. 390  HPLOT X,Y TO X,Y +74 TO X +1,Y +75 TO X +13,Y +75 TO X +14,Y +74
  40. 400  NEXT X
  41. 410  HPLOT 215,Y TO 215,Y +74
  42. 420  REM  * BLACK KEYS
  43. 430  HCOLOR= 0
  44. 440  FOR X = 77 TO 197  STEP 15
  45. 450  IF X = 107  OR X = 167  THEN 500
  46. 460  FOR Y = Z(I) TO Z(I) +49
  47. 470  HPLOT X,Y TO X +6,Y
  48. 480  NEXT Y
  49. 490  HPLOT X +1,Z(I) +50 TO X +5,Z(I) +50
  50. 500  NEXT X
  51. 510  HPLOT 65,90 TO 215,90
  52. 520  NEXT I
  53. 530  REM  * SPACE BAR
  54. 540  HPLOT 81,174 TO 199,174
  55. 550  HPLOT 81,180 TO 199,180
  56. 560  FOR Y = 175 TO 179
  57. 570  HPLOT 80,Y TO 200,Y
  58. 580  NEXT Y
  59. 590  REM 
  60. 600  REM  * CHARACTERS ON KEYS
  61. 610  DIM X1(1),X2(1),Y1(3)
  62. 620 X1(0) = 70:X1(1) = 78
  63. 630 X2(0) = 205:X2(1) = 198
  64. 640 Y1(0) = 143:Y1(1) = 53:Y1(2) = 115:Y1(3) = 25
  65. 650  SCALE= 1: ROT= 0
  66. 660 I = 1: REM  * SHAPE NUMBER
  67. 670  FOR J = 0 TO 3
  68. 680 Y = Y1(J)
  69. 690  FOR X = X1(J/2) TO X2(J/2)  STEP 15
  70. 700  IF X = 108  OR X = 168  THEN 730: REM  * NO BLACK KEY BETWEEN E AND F OR B AND C
  71. 710 I = I +1
  72. 720  XDRAW I AT X,Y
  73. 730  NEXT X
  74. 740  NEXT J
  75. 750  FOR I = 1 TO 1000: NEXT 
  76. 760  REM 
  77. 770  TEXT : HOME : VTAB 10
  78. 780  PRINT "PITCHES ARE AS SHOWN ON THE KEYS."
  79. 790  PRINT "<SPACE> GIVES YOU SILENCE."
  80. 800  PRINT "<ESC> GETS YOU OUT."
  81. 810  PRINT 
  82. 820  PRINT "PRESS ANYTHING BUT <RESET> TO BEGIN."
  83. 830  IF  PEEK( -1101) = 6  THEN  PRINT "MAKE SURE CAPS LOCK KEY IS DOWN."
  84. 840  REM  * ACTION BEGINS HERE
  85. 850  GET C$
  86. 860  POKE  -16297,0: POKE  -16300,0: POKE  -16304,0
  87. 870  XDRAW 1 AT 140,83: REM  * ORIGINAL CURSOR POSITION
  88. 880  POKE 224,140: POKE 225,0: POKE 226,83: REM  * FOR ERASING ORIGINAL CURSOR
  89. 890  CALL 768
  90. 900  TEXT : HOME : VTAB 10
  91. 910  PRINT "IF YOU WISH TO STOP, TYPE <Y>.": PRINT 
  92. 920  PRINT "IF YOU WISH TO CONTINUE, TYPE ANYTHING  ELSE EXCEPT <RESET>."
  93. 930  GET C$
  94. 940  IF C$ = "Y"  THEN  END 
  95. 950  XDRAW 1 AT  PEEK(224), PEEK(226): REM  * ERASING LAST CURSOR POSITION
  96. 960  GOTO 860