home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib20a.dsk / JULY.1984 / BRIDGE.BIDDER.bas < prev    next >
BASIC Source File  |  2023-02-26  |  26KB  |  795 lines
  1. 1  REM   *************************
  2. 2  REM   * BRIDGE.BIDDER  8.6.84 *
  3. 3  REM   *    BY  DALE SEDIVEC   *
  4. 4  REM   *  COPYRIGHT (C)  1984  *
  5. 5  REM   *  BY MICROSPARC, INC.  *
  6. 6  REM   *  LINCOLN,  MA  01773  *
  7. 7  REM   *************************
  8. 10  REM  MAIN LOGIC SECTION 
  9. 20  LOMEM: 25400
  10. 30 D$ =  CHR$(4)
  11. 40  PRINT D$;"BLOAD CARDS"
  12. 50  PRINT D$;"BLOAD SUITS"
  13. 60  GOSUB 550
  14. 70  GOSUB 680
  15. 80  GOSUB 2350
  16. 90  GOSUB 7670: GOSUB 1600: GOSUB 1780
  17. 100  IF (NB +SB) <1  OR RS > = (NB +SB)  THEN  GOSUB 7090: GOTO 120
  18. 110  GOSUB 3620
  19. 120  GOSUB 7150
  20. 130  GOTO 70: REM MAIN LOGIC SECTION ENDS HERE
  21. 140  GOSUB 4420
  22. 150  IF QE <QN  THEN W = 2:HC = O
  23. 160  RETURN 
  24. 170  GOSUB 4190
  25. 180  IF QW <QS  THEN W = 4:HC = O
  26. 190  RETURN 
  27. 200  HCOLOR= 1: GET AX$
  28. 210 X = 90:Y = 81:O = 1: GOSUB 1920
  29. 220 X = 130:Y = 59:O = 1: GOSUB 1920
  30. 230 X = 170:Y = 81:O = 1: GOSUB 1920
  31. 240 X = 130:Y = 105:O = 1: GOSUB 1920
  32. 250  RETURN 
  33. 260  HCOLOR= 3: GOSUB 1920
  34. 270  HCOLOR= 6: DRAW 15 AT X +2,Y +4
  35. 280  HCOLOR= O: HPLOT X -1,Y TO X +16,Y TO X +16,Y +24 TO X -1,Y +24 TO X -1,Y
  36. 290  RETURN 
  37. 300  FOR X7 = 13 TO 1  STEP  -1
  38. 310  IF (TP = 1  AND S(X7,PT) >0)  OR (TP = 0  AND N(X7,PT) >0)  THEN Y7 = 1: RETURN 
  39. 320  NEXT 
  40. 330  RETURN 
  41. 340 Q = QW:R = RW:X = 90:Y = 81: GOSUB 1830: RETURN 
  42. 350 Q = QE:R = RE:X = 170:Y = 81: GOSUB 1830: RETURN 
  43. 360 X = 12
  44. 370  IF RN = 1  OR RN = 3  THEN Y = 25
  45. 380  IF RN = 2  OR RN = 4  THEN Y = 12
  46. 390  FOR Y7 = 4 TO 1  STEP  -1
  47. 400  FOR X7 = 13 TO 1  STEP  -1
  48. 410  IF X7 = Q  AND Y7 = R  THEN  HCOLOR= 1:O = 1: GOSUB 1920: RETURN 
  49. 420  IF N(X7,Y7) >O  OR N(X7,Y7) =  -1  THEN X = X +20
  50. 430  NEXT 
  51. 440  NEXT 
  52. 450 CW = O:CS = O:CN = O:CE = O:HC = O: RETURN 
  53. 460 X = 12
  54. 470  IF RS = 1  OR RS = 3  THEN Y = 153
  55. 480  IF RS = 2  OR RS = 4  THEN Y = 140
  56. 490  FOR Y7 = 4 TO 1  STEP  -1
  57. 500  FOR X7 = 13 TO 1  STEP  -1
  58. 510  IF X7 = Q  AND Y7 = R  THEN  HCOLOR= 1:O = 1: GOSUB 1920: RETURN 
  59. 520  IF S(X7,Y7) >O  OR S(X7,Y7) =  -1  THEN X = X +20
  60. 530  NEXT 
  61. 540  NEXT 
  62. 550 O = 0: REM   INITIALIZE DIM'S
  63. 560  SCALE= 1: ROT= 0
  64. 570  DIM N(13,4): DIM S(13,4): DIM E(13,4): DIM W(13,4)
  65. 580 UB = O:OB = O: DIM G(1,2)
  66. 590 MS = 0:DN = 1
  67. 600  GOSUB 620
  68. 610  RETURN 
  69. 620  FOR X = 0 TO 1
  70. 630  FOR Y = 0 TO 2
  71. 640 G(X,Y) = O
  72. 650  NEXT 
  73. 660  NEXT 
  74. 670  RETURN 
  75. 680  FOR Q = 1 TO 13: REM   INITIALIZE VARIABLES AND DEAL
  76. 690  FOR R = 0 TO 4
  77. 700 N(Q,R) = O:S(Q,R) = O:E(Q,R) = O:W(Q,R) = O
  78. 710  NEXT 
  79. 720  NEXT 
  80. 730 S8 = 1:QE = 100:QW = 100
  81. 740  IF MS = 1  THEN 840
  82. 750  TEXT : HOME : VTAB 22: PRINT "** COPYRIGHT 1984 BY MICROSPARC, INC. **": VTAB 1
  83. 760  PRINT "ENTER MONTH,DAY,YEAR AND WAIT FOR DEAL:"
  84. 770  INPUT "MO ? ";M8
  85. 780  INPUT "DA ? ";D8
  86. 790  INPUT "YR ? ";T8
  87. 800  IF T8 <(M8 +D8)  THEN 760
  88. 810  HGR2 : GOSUB 1060
  89. 820 T8 = T8 -D8 -M8
  90. 830  IF T8 <1  THEN 760
  91. 840  FOR M8 = 1 TO T8
  92. 850 D8 =  RND(1)
  93. 860  NEXT 
  94. 870  POKE  -16304,0: POKE  -16297,0: POKE  -16299,0: GOSUB 3560
  95. 880  FOR T8 = 1 TO 52
  96. 890 R =  INT(4 * RND(1) +1)
  97. 900 Q =  INT(13 * RND(1) +1)
  98. 910  IF (N(Q,R) +S(Q,R) +E(Q,R) +W(Q,R)) >0  THEN 890
  99. 920  IF S8 = 1  THEN W(Q,R) = Q:S8 = 2:X =  INT(74 * RND(1) +1):Y =  INT(37 * RND(1) +60): GOSUB 260: GOTO 960
  100. 930  IF S8 = 2  THEN N(Q,R) = Q:S8 = 3:X =  INT(74 * RND(1) +90):Y =  INT(37 * RND(1)): GOSUB 260: GOTO 960
  101. 940  IF S8 = 3  THEN E(Q,R) = Q:S8 = 4:X =  INT(74 * RND(1) +180):Y =  INT(37 * RND(1) +60): GOSUB 260: GOTO 960
  102. 950 S(Q,R) = Q:S8 = 1:X =  INT(74 * RND(1) +90):Y =  INT(37 * RND(1) +120): GOSUB 260
  103. 960  NEXT 
  104. 970 MS = 1
  105. 980 ZZ = O:ST$ = "O":NB =  -1:SB =  -1:NT = O:TN = O:NP = O:SP = O
  106. 990 DN = DN +1:BC = 1
  107. 1000  IF DN = 3  THEN DN = 1
  108. 1010 T2 = O
  109. 1020 X8 = 221:Y8 = 51
  110. 1030 BN = 1:PT = O
  111. 1040  GOSUB 450
  112. 1050  RETURN 
  113. 1060  HCOLOR= 1: REM BACKGROUND COLOR 
  114. 1070  FOR Y = 0 TO 191
  115. 1080  HPLOT 0,Y TO 279,Y
  116. 1090  NEXT 
  117. 1100  RETURN 
  118. 1110  HCOLOR= 3
  119. 1120  HPLOT X +2,Y TO X +15,Y
  120. 1130  HPLOT X +2,Y +23 TO X +15,Y +23
  121. 1140  RETURN 
  122. 1150 X = X8:Y = Y8
  123. 1160  IF X8 = 221  AND Y8 = 51  THEN  GOSUB 260:X8 = X8 +8:Y8 = Y8 +12: RETURN 
  124. 1170  IF T2 = 7  THEN X8 = 191:Y8 = 55
  125. 1180 X = X8:Y = Y8: GOSUB 260
  126. 1190 X8 = X8 +8:Y8 = Y8 +12
  127. 1200  RETURN 
  128. 1210  GOSUB 1430
  129. 1220  FOR QW = 1 TO 13
  130. 1230  IF W(QW,RW) >S(QS,RS)  AND QW >QN  THEN CW = 1:W = 1: RETURN 
  131. 1240  NEXT 
  132. 1250  GOSUB 5350
  133. 1260  IF CW = 1  THEN W = 1: RETURN 
  134. 1270  GOSUB 4190
  135. 1280  IF CW = 1  THEN  RETURN 
  136. 1290 RW = T: GOSUB 4190
  137. 1300  IF CW = 1  THEN W = 1: RETURN 
  138. 1310  GOSUB 4130: RETURN 
  139. 1320  GOSUB 1470
  140. 1330  FOR QE = 1 TO 13
  141. 1340  IF E(QE,RE) >N(QN,RN)  AND QE >QS  THEN CE = 1:W = 3: RETURN 
  142. 1350  NEXT 
  143. 1360  GOSUB 4830
  144. 1370  IF CE = 1  THEN W = 3: RETURN 
  145. 1380  GOSUB 4420
  146. 1390  IF CE = 1  THEN  RETURN 
  147. 1400 RE = T: GOSUB 4420
  148. 1410  IF CE = 1  THEN W = 3: RETURN 
  149. 1420  GOSUB 4460: RETURN 
  150. 1430  FOR QN = 13 TO 1  STEP  -1
  151. 1440  IF N(QN,RN) >0  THEN  RETURN 
  152. 1450  NEXT 
  153. 1460 QN = 0: RETURN 
  154. 1470  FOR QS = 13 TO 1  STEP  -1
  155. 1480  IF S(QS,RS) >0  THEN  RETURN 
  156. 1490  NEXT 
  157. 1500 QS = 0: RETURN 
  158. 1510 X = 12
  159. 1520  FOR R = 4 TO 1  STEP  -1
  160. 1530  IF R = 4  OR R = 2  THEN Y = 140
  161. 1540  IF R = 3  OR R = 1  THEN Y = 153
  162. 1550  FOR Q = 13 TO 1  STEP  -1
  163. 1560  IF S(Q,R) >O  THEN O = 1: GOSUB 1830
  164. 1570  NEXT 
  165. 1580  NEXT 
  166. 1590  RETURN 
  167. 1600 X = 12
  168. 1610  FOR R = 4 TO 1  STEP  -1
  169. 1620  IF R = 4  OR R = 2  THEN Y = 12
  170. 1630  IF R = 3  OR R = 1  THEN Y = 25
  171. 1640  FOR Q = 13 TO 1  STEP  -1
  172. 1650  IF N(Q,R) >O  THEN O = 1: GOSUB 1830
  173. 1660  NEXT 
  174. 1670  NEXT 
  175. 1680  RETURN 
  176. 1690  PRINT 
  177. 1700 Q = Q -1
  178. 1710  IF Q = O  THEN Q = 14
  179. 1720  GOSUB 1830
  180. 1730  RETURN 
  181. 1740 BC = BC +1
  182. 1750 BN = BN +1
  183. 1760  IF BC >2  THEN BC = 1
  184. 1770  RETURN 
  185. 1780  HCOLOR= 1:CH = 0
  186. 1790  FOR Y = 59 TO 131
  187. 1800  HPLOT 80,Y TO 279,Y
  188. 1810  NEXT 
  189. 1820  HCOLOR= 3:CH = 3: RETURN 
  190. 1830  REM  DRAW CARDS
  191. 1840  HCOLOR= 3: GOSUB 1920
  192. 1850  HCOLOR= 0
  193. 1860  ON Q GOSUB 1960,1980,2000,2020,2040,2060,2080,2100,2120,2140,2160,2180,2200,2220
  194. 1870  POKE 232,0: POKE 233,98
  195. 1880  ON R GOSUB 2230,2260,2290,2320
  196. 1890  HCOLOR= 1: HPLOT X -2,Y +10 TO X -2,Y +20
  197. 1900 X = X +20
  198. 1910  RETURN 
  199. 1920  POKE 232,0: POKE 233,96: DRAW 1 AT X,Y
  200. 1930  IF O = 1  THEN O = 0: RETURN 
  201. 1940 AX =  PEEK( -16336):AX =  PEEK( -16336):AX =  PEEK( -16336): REM  SOUND OF CARD WHEN PLAYED
  202. 1950  RETURN 
  203. 1960  DRAW 2 AT X +6,Y +3
  204. 1970  RETURN 
  205. 1980  DRAW 3 AT X +6,Y +3
  206. 1990  RETURN 
  207. 2000  DRAW 4 AT X +6,Y +3
  208. 2010  RETURN 
  209. 2020  DRAW 5 AT X +10,Y +3
  210. 2030  RETURN 
  211. 2040  DRAW 6 AT X +6,Y +3
  212. 2050  RETURN 
  213. 2060  DRAW 7 AT X +6,Y +3
  214. 2070  RETURN 
  215. 2080  DRAW 8 AT X +6,Y +5
  216. 2090  RETURN 
  217. 2100  DRAW 9 AT X +9,Y +6
  218. 2110  RETURN 
  219. 2120  DRAW 10 AT X +6,Y +3
  220. 2130  RETURN 
  221. 2140  DRAW 11 AT X +10,Y +3
  222. 2150  RETURN 
  223. 2160  DRAW 12 AT X +8,Y +9
  224. 2170  RETURN 
  225. 2180  DRAW 13 AT X +6,Y +3
  226. 2190  RETURN 
  227. 2200  DRAW 14 AT X +6,Y +9
  228. 2210  RETURN 
  229. 2220  HPLOT X +8,Y +3 TO X +8,Y +9: RETURN 
  230. 2230  HCOLOR= O
  231. 2240  DRAW 7 AT X +4,Y +19
  232. 2250  RETURN 
  233. 2260  HCOLOR= 5
  234. 2270  DRAW 4 AT X +2,Y +17
  235. 2280  RETURN 
  236. 2290  HCOLOR= 5
  237. 2300  DRAW 5 AT X +2,Y +13
  238. 2310  RETURN 
  239. 2320  HCOLOR= O
  240. 2330  DRAW 6 AT X +3,Y +17
  241. 2340  RETURN 
  242. 2350  GOSUB 1060: GOSUB 1510: GOSUB 3430: REM    BIDDING SECTION
  243. 2360  GOSUB 2470
  244. 2370  IF DN = 2  THEN 2420
  245. 2380  IF NB = O  AND SB >O  THEN W = 4: RETURN 
  246. 2390  IF SB = O  AND NB = O  THEN  RETURN 
  247. 2400  GOSUB 3200
  248. 2410  GOSUB 1740
  249. 2420  IF SB = O  AND NB >O  THEN W = 2: RETURN 
  250. 2430  IF SB = O  AND NB = O  THEN  RETURN 
  251. 2440  GOSUB 2670
  252. 2450  GOSUB 1740
  253. 2460  GOTO 2380
  254. 2470  FOR Y = 1 TO 4: REM  DETERMINE PTS OF NO AND SO
  255. 2480 D8 = O:T8 = O:NT = O
  256. 2490  FOR X = 1 TO 13
  257. 2500  IF N(X,Y) >O  THEN NT = NT +N(X,Y):D8 = D8 +1
  258. 2510  IF S(X,Y) >O  THEN T8 = T8 +1
  259. 2520  NEXT 
  260. 2530  IF D8 <3  THEN NP = NP +3 -D8
  261. 2540  IF T8 <3  THEN SP = SP +3 -T8
  262. 2550  IF NT >TN  AND D8 >3  THEN TN = NT:TP = Y:PT = Y: GOSUB 6830
  263. 2560  NEXT 
  264. 2570  FOR Y = 1 TO 4
  265. 2580  FOR X = 10 TO 13
  266. 2590  IF N(X,Y) >O  THEN NP = NP +X -9
  267. 2600  IF S(X,Y) >O  THEN SP = SP +X -9
  268. 2610  NEXT 
  269. 2620  NEXT 
  270. 2630  FOR Q = 1 TO 7
  271. 2640  IF (NP +SP) >(16 +3 *Q)  THEN ZZ = Q
  272. 2650  NEXT 
  273. 2660  RETURN 
  274. 2670 X = QE:Y = 59:TP = PT:QE = QE +20: IF SB >O  THEN  GOSUB 3130: REM  NO'S BID
  275. 2680  IF NB =  -1  AND SB < = O  AND NP >19  AND XX < = 4  THEN Q = 1:TP = 0: GOTO 2920
  276. 2690 R5 = O: IF T < >M8  AND T < >(PT)  AND SB >O  THEN  GOSUB 6900
  277. 2700  IF R5 = 1  THEN R5 = O: GOTO 2880
  278. 2710  IF XX = 7  AND (NP +SP) <20  AND SB <2  AND NB =  -1  THEN Q = 3: GOTO 2920
  279. 2720  IF XX >6  AND  INT(SB) = 1  AND NB =  -1  THEN Q = 3: GOTO 2920
  280. 2730  IF XX >6  AND SB <7  THEN 2880
  281. 2740  IF  INT(NB) = 1  AND (ST$ = "N"  OR  INT(SB) = 3)  THEN  GOSUB 2940: GOTO 2880
  282. 2750  IF (ST$ = "N"  AND NB <1)  OR ( INT(SB) = 2  AND NB <1  AND NP >5)  THEN 2880
  283. 2760  IF (SB < = O  AND NP <13)  OR (SB >O  AND NP <6)  THEN 2870
  284. 2770  IF SB < = O  AND NP >19  AND NB =  -1  THEN Q = 2: GOTO 2920
  285. 2780  IF NB >O  AND BN >2  AND BN <5  THEN  GOSUB 2940
  286. 2790  IF D8 = 1  THEN D8 = O: GOTO 2820
  287. 2800  IF NB >O  AND BN >2  AND BN <7  THEN  GOSUB 3080
  288. 2810  IF D8 = 1  THEN D8 = O: GOTO 2820
  289. 2820  FOR Q = 1 TO 7
  290. 2830  IF TP = O  THEN TP = 5
  291. 2840  IF (Q +TP/10) >SB  AND Q < = ZZ  THEN 2920
  292. 2850  NEXT 
  293. 2860  IF TP = 5  THEN TP = O
  294. 2870  HCOLOR= 3: GOSUB 1920:NB = O: RETURN 
  295. 2880  FOR Q = 1 TO 7
  296. 2890  IF TP = O  THEN TP = 5
  297. 2900  IF (Q +TP/10) >SB  THEN 2920
  298. 2910  NEXT 
  299. 2920 NB = Q +TP/10: IF TP = 5  THEN TP = O
  300. 2930 T = TP:R = TP: GOSUB 1690: RETURN 
  301. 2940 D8 = O
  302. 2950  FOR R = 1 TO 4
  303. 2960  FOR Q = 13 TO 12  STEP  -1
  304. 2970  IF (N(Q,R) >O  AND N(Q -1,R) >O)  OR (N(Q,R) >O  AND N(Q -2,R) >O)  AND R < >PT  THEN  GOSUB 6980
  305. 2980  IF D8 = 1  THEN  RETURN 
  306. 2990  NEXT 
  307. 3000  NEXT 
  308. 3010  FOR R = 1 TO 4
  309. 3020  FOR Q = 13 TO 12  STEP  -1
  310. 3030  IF N(Q,R) >O  AND R < >PT  THEN  GOSUB 6980
  311. 3040  IF D8 = 1  THEN  RETURN 
  312. 3050  NEXT 
  313. 3060  NEXT 
  314. 3070  RETURN 
  315. 3080 D8 = O
  316. 3090  IF SB < = O  OR T = O  OR M8 = O  THEN  RETURN 
  317. 3100  IF T8 >Z  THEN D8 = 1:TP = M8
  318. 3110  IF DE >T8  AND DE >Z  THEN D8 = 1:TP = T
  319. 3120  RETURN 
  320. 3130  IF M8 = O  OR SB < = O  OR T = O  THEN  RETURN 
  321. 3140 T8 = O:DE = O
  322. 3150  FOR Q = 1 TO 13
  323. 3160 T8 = T8 +S(Q,M8) +N(Q,M8)
  324. 3170 DE = DE +S(Q,T) +N(Q,T)
  325. 3180  NEXT 
  326. 3190  RETURN 
  327. 3200  REM  SO'S BID
  328. 3210 X = QW:Y = 105:QW = QW +20
  329. 3220  HCOLOR= O:O = 1: GOSUB 1920: GOSUB 3490
  330. 3230  GET Q$
  331. 3240  IF Q$ =  CHR$(27)  THEN  GOSUB 3410:Y = 105: GOTO 3230
  332. 3250  IF Q$ = "P"  THEN SB = O: HCOLOR= 3: GOSUB 1920: RETURN 
  333. 3260  GET ST$
  334. 3270 Q =  VAL(Q$)
  335. 3280  IF Q <1  THEN  CALL  -198: GOTO 3230
  336. 3290  IF Q >7  OR (ST$ < >"S"  AND ST$ < >"H"  AND ST$ < >"D"  AND ST$ < >"C"  AND ST$ < >"N")  THEN  CALL  -198: GOTO 3230
  337. 3300  IF ST$ = "C"  THEN R = 1:T = 1
  338. 3310  IF ST$ = "D"  THEN R = 2:T = 2
  339. 3320  IF ST$ = "H"  THEN R = 3:T = 3
  340. 3330  IF ST$ = "S"  THEN R = 4:T = 4
  341. 3340  IF ST$ = "N"  THEN R = O:T = O
  342. 3350  IF SB <1  THEN M8 = T
  343. 3360  IF T = O  THEN T = 5
  344. 3370 SB = Q +T/10: IF T = 5  THEN T = O
  345. 3380  IF SB < = NB  THEN  CALL  -198: GOTO 3230
  346. 3390  GOSUB 1690
  347. 3400  RETURN 
  348. 3410  TEXT : HOME : GOSUB 7670: GOSUB 7480: PRINT : INVERSE : PRINT "PROJECTED BID OF EAST/WEST: " INT(RS);" ";EW$: NORMAL : PRINT : GET AX$
  349. 3420  POKE  -16304,0: POKE  -16297,0: POKE  -16299,0: RETURN 
  350. 3430  REM  DRAW NO & SO
  351. 3440  HCOLOR= O:O = 1:X = 80:Y = 59: GOSUB 1920
  352. 3450  HCOLOR= 3: HPLOT X +2,Y +15 TO X +2,Y +9 TO X +6,Y +15 TO X +6,Y +9: GOSUB 3550
  353. 3460  HCOLOR= O:O = 1:Y = 105: GOSUB 1920
  354. 3470  HCOLOR= 3: DRAW 5 AT X +6,Y +9: GOSUB 3550
  355. 3480  RETURN 
  356. 3490  REM  DRAW BID
  357. 3500  HCOLOR= 3: POKE 232,0: POKE 233,98
  358. 3510  DRAW 1 AT X +10,Y +3
  359. 3520  DRAW 2 AT X +7,Y +9
  360. 3530  DRAW 3 AT X +6,Y +17
  361. 3540  RETURN 
  362. 3550  HPLOT X +10,Y +9 TO X +14,Y +9 TO X +14,Y +15 TO X +10,Y +15 TO X +10,Y +9: RETURN 
  363. 3560  HCOLOR= 1:X = 130:Y = 59: GOSUB 1920:Y = 105: GOSUB 1920
  364. 3570 X = 12:Y = 81: GOSUB 1920:X = 32: GOSUB 1920
  365. 3580  FOR Y = 145 TO 50  STEP  -1
  366. 3590  HPLOT 279,Y TO 190,Y
  367. 3600  NEXT 
  368. 3610  RETURN 
  369. 3620  GOSUB 6790: REM   TRICK SECTION
  370. 3630  IF PT < >M8  AND W = 2  AND T = M8  THEN W = 4
  371. 3640  IF PT < >M8  AND W = 4  AND T = PT  THEN W = 2
  372. 3650  ON W GOSUB 5120,5560,6280,3810
  373. 3660  GOSUB 4930
  374. 3670  GOSUB 200
  375. 3680  IF W = 2  OR W = 4  THEN T2 = T2 +1: GOSUB 1150
  376. 3690  GOSUB 450
  377. 3700  ON W GOSUB 3810,5120,5560,6280
  378. 3710  GOSUB 4930
  379. 3720  FOR Q = 1 TO 13
  380. 3730  FOR R = 1 TO 4
  381. 3740  IF S(Q,R) >0  THEN 3670
  382. 3750  NEXT 
  383. 3760  NEXT 
  384. 3770  IF AX$ = "A"  THEN  RETURN 
  385. 3780  GOSUB 200
  386. 3790  IF W = 2  OR W = 4  THEN T2 = T2 +1: GOSUB 1150
  387. 3800  RETURN 
  388. 3810 W = 1:FL = O: REM  WEST LEADS
  389. 3820  GOSUB 4020
  390. 3830  IF CW = 1  THEN  GOSUB 340: GOTO 3910
  391. 3840  GOSUB 5770
  392. 3850  IF CE = 1  THEN CE = 0:HC = 0:RW = RE: GOSUB 4190
  393. 3860  IF CW = 1  THEN  GOSUB 340: GOTO 3910
  394. 3870  IF FL = O  THEN FL = 1: GOSUB 5880: GOTO 3850
  395. 3880  GOSUB 4130
  396. 3890  IF CW = 1  THEN  GOSUB 340: GOTO 3910
  397. 3900 RW = T: GOSUB 4190: GOSUB 340
  398. 3910 PT = RW:TP = 0: GOSUB 4870: GOSUB 1830: GOSUB 360
  399. 3920  GOSUB 5030
  400. 3930  IF HC = 1  AND W = 1  THEN  GOSUB 4520: GOSUB 350: GOTO 3970
  401. 3940  IF W = 1  THEN  GOSUB 4580: GOSUB 350: GOTO 3970
  402. 3950  IF RN = RW  THEN RE = RN:RS = RE: GOSUB 1320: GOSUB 350: GOTO 3970
  403. 3960  GOSUB 4760: GOSUB 350
  404. 3970 TP = 1: GOSUB 4900: GOSUB 1830: GOSUB 460
  405. 3980  IF HC = 1  AND RS < >T  THEN  RETURN 
  406. 3990  IF W = 1  THEN  GOSUB 4940: RETURN 
  407. 4000  IF W = 3  THEN  GOSUB 4970: RETURN 
  408. 4010  GOSUB 5000: RETURN 
  409. 4020  FOR QW = 13 TO 1  STEP  -1
  410. 4030  FOR RW = 1 TO 4
  411. 4040  IF W(QW,RW) >O  THEN  GOSUB 4090
  412. 4050  IF CW = 1  THEN  RETURN 
  413. 4060  NEXT 
  414. 4070  NEXT 
  415. 4080  RETURN 
  416. 4090  FOR QN = QW TO 13
  417. 4100  IF N(QN,RW) >O  OR S(QN,RW) >O  THEN  RETURN 
  418. 4110  NEXT 
  419. 4120 CW = 1:HC = 1: RETURN 
  420. 4130  FOR QW = 1 TO 13
  421. 4140  FOR RW = 1 TO 4
  422. 4150  IF W(QW,RW) >O  AND RW < >T  THEN CW = 1: RETURN 
  423. 4160  NEXT 
  424. 4170  NEXT 
  425. 4180  RETURN 
  426. 4190  FOR QW = 1 TO 13
  427. 4200  IF W(QW,RW) >O  THEN CW = 1: RETURN 
  428. 4210  NEXT 
  429. 4220  RETURN 
  430. 4230  GET Q$: GET R$
  431. 4240 Q =  VAL(Q$)
  432. 4250  IF Q < >0  THEN Q = Q -1
  433. 4260  IF Q = O  THEN  GOSUB 4290
  434. 4270  GOSUB 4350: IF Y7 = 1  THEN  CALL  -198: GOTO 4230
  435. 4280  RETURN 
  436. 4290  IF Q$ = "A"  THEN Q = 13
  437. 4300  IF Q$ = "K"  THEN Q = 12
  438. 4310  IF Q$ = "Q"  THEN Q = 11
  439. 4320  IF Q$ = "J"  THEN Q = 10
  440. 4330  IF Q$ = "T"  THEN Q = 9
  441. 4340  RETURN 
  442. 4350 R = O:Y7 = O
  443. 4360  IF R$ = "C"  THEN R = 1
  444. 4370  IF R$ = "D"  THEN R = 2
  445. 4380  IF R$ = "H"  THEN R = 3
  446. 4390  IF R$ = "S"  THEN R = 4
  447. 4400  IF R < >(PT)  AND X7 < >0  THEN  GOSUB 300
  448. 4410  RETURN 
  449. 4420  FOR QE = 1 TO 13
  450. 4430  IF E(QE,RE) >O  THEN CE = 1: RETURN 
  451. 4440  NEXT 
  452. 4450  RETURN 
  453. 4460  FOR QE = 1 TO 13
  454. 4470  FOR RE = 4 TO 1  STEP  -1
  455. 4480  IF E(QE,RE) >O  AND RE < >T  THEN CE = 1: RETURN 
  456. 4490  NEXT 
  457. 4500  NEXT 
  458. 4510  RETURN 
  459. 4520 RE = RW: GOSUB 4420
  460. 4530  IF CE = 1  AND QE >QW  THEN W = 3
  461. 4540  IF CE = 1  THEN  RETURN 
  462. 4550  GOSUB 4460
  463. 4560  IF CE = 1  THEN  RETURN 
  464. 4570 W = 3:RE = T: GOSUB 4420: RETURN 
  465. 4580 RE = RW: GOSUB 4610
  466. 4590  IF CE = 1  AND QE >QW  THEN W = 3
  467. 4600  GOSUB 4720: RETURN 
  468. 4610  FOR QE = 13 TO 1  STEP  -1
  469. 4620  IF E(QE,RE) >O  THEN CE = 1: RETURN 
  470. 4630  NEXT 
  471. 4640  RETURN 
  472. 4650  FOR QE = 13 TO 1  STEP  -1
  473. 4660  IF E(QE,RE) >N(QN,RN)  THEN CE = 1: RETURN 
  474. 4670  NEXT 
  475. 4680  RETURN 
  476. 4690  GOSUB 4650
  477. 4700  IF CE = 1  THEN W = 3: RETURN 
  478. 4710  GOSUB 4420: GOSUB 4720: RETURN 
  479. 4720  IF CE = 1  THEN  RETURN 
  480. 4730 RE = T: GOSUB 4420
  481. 4740  IF CE = 1  THEN W = 3: RETURN 
  482. 4750  GOSUB 4460: RETURN 
  483. 4760 RE = RW: GOSUB 4420
  484. 4770  IF CE = 1  THEN  RETURN 
  485. 4780 RE = T: GOSUB 4830
  486. 4790  IF CE = 1  THEN W = 3: RETURN 
  487. 4800  GOSUB 4460
  488. 4810  IF CE = 1  THEN  RETURN 
  489. 4820 RE = T: GOSUB 4420: RETURN 
  490. 4830  FOR QE = 1 TO 13
  491. 4840  IF E(QE,RE) >N(QN,RN)  THEN CE = 1: RETURN 
  492. 4850  NEXT 
  493. 4860  RETURN 
  494. 4870  GOSUB 4230:QN = Q:RN = R:X = 130:Y = 59
  495. 4880  IF QN <1  OR QN >13  OR RN <1  OR RN >4  OR N(QN,RN) < = O  THEN  CALL  -198: GOTO 4870
  496. 4890  RETURN 
  497. 4900  GOSUB 4230:QS = Q:RS = R:X = 130:Y = 105
  498. 4910  IF QS <1  OR QS >13  OR RS <1  OR RS >4  OR S(QS,RS) < = O  THEN  CALL  -198: GOTO 4900
  499. 4920  RETURN 
  500. 4930 S(QS,RS) =  -1:N(QN,RN) =  -1:E(QE,RE) =  -1:W(QW,RW) =  -1: RETURN 
  501. 4940  IF QS >QW  AND RS = RW  THEN W = 4:HC = O
  502. 4950  IF RS < >RW  AND RS = T  THEN W = 4:HC = O
  503. 4960  RETURN 
  504. 4970  IF QS >QE  AND RS = RE  THEN W = 4:HC = O
  505. 4980  IF RS < >RE  AND RS = T  THEN W = 4:HC = O
  506. 4990  RETURN 
  507. 5000  IF QS >QN  AND RS = RN  THEN W = 4:HC = O
  508. 5010  IF RS < >RN  AND RS = T  THEN W = 4:HC = O
  509. 5020  RETURN 
  510. 5030  IF QN >QW  AND RN = RW  THEN W = 2:HC = O
  511. 5040  IF RN < >RW  AND RN = T  THEN W = 2:HC = O
  512. 5050  RETURN 
  513. 5060  IF QN >QS  AND RN = RS  THEN W = 2:HC = O
  514. 5070  IF RN < >RS  AND RN = T  THEN W = 2:HC = O
  515. 5080  RETURN 
  516. 5090  IF QN >QE  AND RN = RE  THEN W = 2:HC = O
  517. 5100  IF RN < >RE  AND RN = T  THEN W = 2:HC = O
  518. 5110  RETURN 
  519. 5120 X = 130:Y = 59: GOSUB 1110: REM  NO LEADS
  520. 5130  IF AX$ = "A"  THEN  GOSUB 7040: RETURN 
  521. 5140 W = 2:TP = 0:X7 = 0: GOSUB 4870: GOSUB 1830: GOSUB 360:PT = RN
  522. 5150 RE = RN: GOSUB 1320
  523. 5160  IF RE = RN  AND QE = 12  AND S(13,RN) >O  AND  RND(1) <.5  THEN  GOSUB 140
  524. 5170  GOSUB 350
  525. 5180 TP = 1: GOSUB 4900: GOSUB 1830: GOSUB 460
  526. 5190  IF W = 2  THEN  GOSUB 5000: GOTO 5210
  527. 5200  GOSUB 4970
  528. 5210  IF W = 2  THEN  GOSUB 5270: GOSUB 340: RETURN 
  529. 5220  IF W = 4  AND RS < >T  THEN  GOSUB 5330: GOSUB 340: RETURN 
  530. 5230  IF W = 4  AND RS = RN  AND RS = T  THEN  GOSUB 5330: GOSUB 340: RETURN 
  531. 5240  IF W = 4  THEN  GOSUB 6570: GOSUB 340: RETURN 
  532. 5250  IF RE = RN  THEN  GOSUB 6040: GOSUB 340: RETURN 
  533. 5260  GOSUB 6640: GOSUB 340: RETURN 
  534. 5270 RW = RN: GOSUB 5290
  535. 5280  GOSUB 5390: RETURN 
  536. 5290  FOR QW = 1 TO 13
  537. 5300  IF W(QW,RW) >N(QN,RN)  THEN CW = 1: RETURN 
  538. 5310  NEXT 
  539. 5320  RETURN 
  540. 5330 RW = RS: GOSUB 5350
  541. 5340  GOSUB 5390: RETURN 
  542. 5350  FOR QW = 1 TO 13
  543. 5360  IF W(QW,RW) >S(QS,RS)  THEN CW = 1: RETURN 
  544. 5370  NEXT 
  545. 5380  RETURN 
  546. 5390  IF CW = 1  THEN W = 1: RETURN 
  547. 5400  GOSUB 4190: GOSUB 5410: RETURN 
  548. 5410  IF CW = 1  THEN  RETURN 
  549. 5420 RW = T: GOSUB 4190
  550. 5430  IF CW = 1  THEN W = 1: RETURN 
  551. 5440  GOSUB 4130: RETURN 
  552. 5450 RW = RE: GOSUB 4190
  553. 5460  IF CW = 1  AND QW <QE  THEN  RETURN 
  554. 5470  IF CW = 1  THEN W = 1: RETURN 
  555. 5480  GOSUB 4130
  556. 5490  IF CW = 1  THEN  RETURN 
  557. 5500 RW = T:W = 1: GOSUB 4190: RETURN 
  558. 5510  LET RE = T: GOSUB 4830
  559. 5520  IF CE = 1  THEN W = 3: RETURN 
  560. 5530  GOSUB 4420
  561. 5540  IF CE = 1  THEN  RETURN 
  562. 5550  GOSUB 4460: RETURN 
  563. 5560 FL = O: REM  EAST LEADS
  564. 5570 W = 3: GOSUB 5770
  565. 5580  IF CE = 1  THEN  GOSUB 350: GOTO 5660
  566. 5590  GOSUB 4020
  567. 5600  IF CW = 1  THEN CW = 0:HC = 0:RE = RW: GOSUB 4420
  568. 5610  IF CE = 1  THEN  GOSUB 350: GOTO 5660
  569. 5620  IF FL = O  THEN FL = 1: GOSUB 5960: GOTO 5600
  570. 5630  GOSUB 4460
  571. 5640  IF CE = 1  THEN  GOSUB 350: GOTO 5660
  572. 5650 RE = T: GOSUB 4420: GOSUB 350
  573. 5660 PT = RE:TP = 1: GOSUB 4900: GOSUB 1830: GOSUB 460
  574. 5670  GOSUB 4970
  575. 5680  IF HC = 1  AND W = 3  THEN  GOSUB 6040: GOSUB 340: GOTO 5720
  576. 5690  IF W = 3  THEN  GOSUB 6100: GOSUB 340: GOTO 5720
  577. 5700  IF RS = RE  THEN RW = RS:RN = RW: GOSUB 1210: GOSUB 340: GOTO 5720
  578. 5710  GOSUB 6210: GOSUB 340
  579. 5720 TP = 0: GOSUB 4870: GOSUB 1830: GOSUB 360
  580. 5730  IF HC = 1  AND RN < >T  THEN  RETURN 
  581. 5740  IF W = 1  THEN  GOSUB 5030: RETURN 
  582. 5750  IF W = 3  THEN  GOSUB 5090: RETURN 
  583. 5760  GOSUB 5060: RETURN 
  584. 5770  FOR QE = 13 TO 1  STEP  -1
  585. 5780  FOR RE = 4 TO 1  STEP  -1
  586. 5790  IF E(QE,RE) >O  THEN  GOSUB 5840
  587. 5800  IF CE = 1  THEN  RETURN 
  588. 5810  NEXT 
  589. 5820  NEXT 
  590. 5830  RETURN 
  591. 5840  FOR QN = QE TO 13
  592. 5850  IF N(QN,RE) >O  OR S(QN,RE) >O  THEN  RETURN 
  593. 5860  NEXT 
  594. 5870 CE = 1:HC = 1: RETURN 
  595. 5880  FOR RE = 1 TO 4
  596. 5890  FOR QE = 1 TO 13
  597. 5900 CE = CE +E(QE,RE)
  598. 5910  NEXT 
  599. 5920  IF CE = O  AND RE < >T  THEN CE = 1:HC = 1: RETURN 
  600. 5930 CE = O
  601. 5940  NEXT 
  602. 5950  RETURN 
  603. 5960  FOR RW = 1 TO 4
  604. 5970  FOR QW = 1 TO 13
  605. 5980 CW = CW +W(QW,RW)
  606. 5990  NEXT 
  607. 6000  IF CW = O  AND RW < >T  THEN CW = 1:HC = 1: RETURN 
  608. 6010 CW = O
  609. 6020  NEXT 
  610. 6030  RETURN 
  611. 6040 RW = RE: GOSUB 4190
  612. 6050  IF CW = 1  AND QW >QE  THEN W = 1: RETURN 
  613. 6060  IF CW = 1  THEN  RETURN 
  614. 6070  GOSUB 4130
  615. 6080  IF CW = 1  THEN  RETURN 
  616. 6090 W = 1:RW = T: GOSUB 4190: RETURN 
  617. 6100 RW = RE: GOSUB 6130
  618. 6110  IF CW = 1  AND QW >QE  THEN W = 1
  619. 6120  GOSUB 5410: RETURN 
  620. 6130  FOR QW = 13 TO 1  STEP  -1
  621. 6140  IF W(QW,RW) >O  THEN CW = 1: RETURN 
  622. 6150  NEXT 
  623. 6160  RETURN 
  624. 6170  FOR QW = 13 TO 1  STEP  -1
  625. 6180  IF W(QW,RW) >S(QS,RS)  THEN CW = 1: RETURN 
  626. 6190  NEXT 
  627. 6200  RETURN 
  628. 6210 RW = RE: GOSUB 4190
  629. 6220  IF CW = 1  THEN  RETURN 
  630. 6230 RW = T: GOSUB 5350
  631. 6240  IF CW = 1  THEN W = 1: RETURN 
  632. 6250  GOSUB 4130
  633. 6260  IF CW = 1  THEN  RETURN 
  634. 6270 RW = T: GOSUB 4190: RETURN 
  635. 6280 X = 130:Y = 105: GOSUB 1110: REM  SO LEADS
  636. 6290  IF AX$ = "A"  THEN  GOSUB 7040: RETURN 
  637. 6300 W = 4:TP = 1:X7 = 0: GOSUB 4900: GOSUB 1830: GOSUB 460:PT = RS
  638. 6310 RW = RS: GOSUB 1210
  639. 6320  IF RW = RS  AND QW = 12  AND N(13,RS) >O  AND  RND(1) <.5  THEN  GOSUB 170
  640. 6330  GOSUB 340
  641. 6340 TP = 0: GOSUB 4870: GOSUB 1830: GOSUB 360
  642. 6350  IF W = 4  THEN  GOSUB 5060: GOTO 6370
  643. 6360  GOSUB 5030
  644. 6370  IF W = 4  THEN RE = RS: GOSUB 6710: GOSUB 350: RETURN 
  645. 6380  IF W = 2  AND RN < >T  THEN RE = RN: GOSUB 4690: GOSUB 350: RETURN 
  646. 6390  IF W = 2  AND RS = RN  AND RS = T  THEN  GOSUB 5510: GOSUB 350: RETURN 
  647. 6400  IF W = 2  THEN  GOSUB 6430: GOSUB 350: RETURN 
  648. 6410  IF RW = RS  THEN  GOSUB 4520: GOSUB 350: RETURN 
  649. 6420  GOSUB 6500: GOSUB 350: RETURN 
  650. 6430 RE = RS: GOSUB 4420
  651. 6440  IF CE = 1  THEN  RETURN 
  652. 6450 RE = T: GOSUB 4830
  653. 6460  IF CE = 1  THEN W = 3: RETURN 
  654. 6470  GOSUB 4460
  655. 6480  IF CE = 1  THEN  RETURN 
  656. 6490 RE = T: GOSUB 4420: RETURN 
  657. 6500 RE = RS: GOSUB 4420
  658. 6510  IF CE = 1  THEN  RETURN 
  659. 6520  GOSUB 4460
  660. 6530  IF CE = 1  THEN  RETURN 
  661. 6540 RE = T: GOSUB 4420
  662. 6550  IF QE >QW  THEN W = 3
  663. 6560  RETURN 
  664. 6570 RW = RN: GOSUB 4190
  665. 6580  IF CW = 1  THEN  RETURN 
  666. 6590 RW = T: GOSUB 5350
  667. 6600  IF CW = 1  THEN W = 1: RETURN 
  668. 6610  GOSUB 4130
  669. 6620  IF CW = 1  THEN  RETURN 
  670. 6630 RW = T: GOSUB 4190: RETURN 
  671. 6640 RW = RN
  672. 6650  IF CW = 1  THEN  RETURN 
  673. 6660  GOSUB 4130
  674. 6670  IF CW = 1  THEN  RETURN 
  675. 6680 RW = T: GOSUB 4190
  676. 6690  IF QW >QE  THEN W = 1
  677. 6700  RETURN 
  678. 6710  FOR QE = 1 TO 13
  679. 6720  IF E(QE,RE) >S(QS,RS)  THEN CE = 1:W = 3: RETURN 
  680. 6730  NEXT 
  681. 6740  GOSUB 4420
  682. 6750  IF CE = 1  THEN  RETURN 
  683. 6760 RE = T: GOSUB 4420
  684. 6770  IF CE = 1  THEN W = 3: RETURN 
  685. 6780  GOSUB 4460: RETURN 
  686. 6790 Q =  INT(SB +NB) -1
  687. 6800  IF Q = 0  THEN Q = 14
  688. 6810 R = T:X = 12:Y = 81: GOSUB 1830
  689. 6820  HCOLOR= O:O = 1: GOSUB 1920: GOSUB 3490: RETURN 
  690. 6830 XX = O:Z = O
  691. 6840  FOR X = 1 TO 13
  692. 6850  IF N(X,Y) >O  THEN XX = XX +1
  693. 6860 Z = Z +S(X,Y)
  694. 6870  NEXT 
  695. 6880 Z = Z +TN
  696. 6890  RETURN 
  697. 6900 R = O
  698. 6910  IF T = O  THEN 6950
  699. 6920  FOR Q = 1 TO 13
  700. 6930 R = R +N(Q,T) +S(Q,T)
  701. 6940  NEXT 
  702. 6950  IF (R <T8  OR R <Z)  AND  INT(SB) > = ZZ  THEN ZZ =  INT(SB) +1: IF NP <6  THEN NP = 6
  703. 6960  IF R >T8  AND R >Z  THEN R5 = 1:TP = T
  704. 6970  RETURN 
  705. 6980 Z5 = O
  706. 6990  FOR D8 = 1 TO 13
  707. 7000  IF N(D8,R) >O  THEN Z5 = Z5 +1
  708. 7010  NEXT 
  709. 7020  IF Z5 <4  THEN D8 = O: RETURN 
  710. 7030 D8 = 1:TP = R: RETURN 
  711. 7040  FOR R = 1 TO 4
  712. 7050  FOR Q = 1 TO 13
  713. 7060  IF S(Q,R) >O  THEN S(Q,R) = O:T2 = T2 +1: GOSUB 1150
  714. 7070  NEXT 
  715. 7080  NEXT 
  716. 7090  HCOLOR= 1
  717. 7100  FOR DE = 12 TO 50
  718. 7110  HPLOT 0,DE TO 279,DE
  719. 7120  HPLOT 0,DE +127 TO 279,DE +127
  720. 7130  NEXT 
  721. 7140  HCOLOR= 3: RETURN 
  722. 7150  GET AX$: TEXT : HOME : REM              SCORE SHEET SECTION
  723. 7160  GOSUB 7670
  724. 7170 QS = 30:QE = O:QW = O:QN =  INT(SB +NB)
  725. 7180  IF T = 1  OR T = 2  THEN QS = 20
  726. 7190  FLASH 
  727. 7200  IF (P$ = "P"  OR QN <1)  AND RS <1  THEN R = O:Q = O:RE = O: PRINT "NO BID - HIT ANY KEY FOR NEW DEAL": GOTO 7250
  728. 7210  IF RS > = (QN +T/10)  THEN RS =  INT(RS): PRINT "EAST/WEST WINS HAND WITH ";RS;" ";EW$:Q = 0:R = 1:RE = 0: GOTO 7250
  729. 7220  IF QN < = (T2 -6)  THEN Q = 1:R = O:RE = O: PRINT "YOU MADE THE CONTRACT !!!": GOTO 7250
  730. 7230 Q = O:R = O:RE = 1: PRINT "YOUR BID WAS UNSUCCESSFUL"
  731. 7240  IF QN >ZZ  THEN RE = 2: PRINT "EAST/WEST DOUBLED THE BID"
  732. 7250  NORMAL : PRINT 
  733. 7260  FOR Y = 0 TO 2
  734. 7270  IF G(0,Y) <100  AND G(1,Y) <100  THEN 7290
  735. 7280  NEXT 
  736. 7290 G(0,Y) = G(0,Y) +QN *QS *Q
  737. 7300  IF T = O  AND QN >RS  AND QN < = (T2 -6)  THEN G(0,Y) = G(0,Y) +10
  738. 7310 G(1,Y) = G(1,Y) +RS *30 *R *(EW >2) +RS *20 *R *(EW <3)
  739. 7320 UB = UB +Q *(T2 -6 -QN) *QS
  740. 7330  IF G(0,0) > = 100  OR G(0,1) > = 100  THEN OB = OB +100 *RE *(QN +6 -T2)
  741. 7340  IF G(0,0) <100  AND G(0,1) <100  THEN OB = OB +50 *RE *(QN +6 -T2)
  742. 7350  FOR Y = 0 TO 2
  743. 7360 QE = QE +G(0,Y)
  744. 7370 QW = QW +G(1,Y)
  745. 7380  NEXT 
  746. 7390  IF Q = 1  AND QN >5  THEN UB = UB +500
  747. 7400  IF R = 1  AND RS >5  THEN OB = OB +500
  748. 7410  IF G(0,0) > = 100  AND G(0,1) > = 100  THEN UB = UB +750:ZZ =  -1: GOTO 7450
  749. 7420  IF G(1,0) > = 100  AND G(1,1) > = 100  THEN OB = OB +750:ZZ =  -1: GOTO 7450
  750. 7430  IF G(0,2) > = 100  THEN UB = UB +500:ZZ =  -1: GOTO 7450
  751. 7440  IF G(1,2) > = 100  THEN OB = OB +500:ZZ =  -1
  752. 7450 QE = QE +UB
  753. 7460 QW = QW +OB
  754. 7470  GOSUB 7480: GOTO 7590
  755. 7480  INVERSE 
  756. 7490  PRINT " NORTH/SOUTH"; TAB( 20);"EAST/WEST ": NORMAL 
  757. 7500  PRINT : PRINT  TAB( 6);UB; TAB( 23);OB
  758. 7510  PRINT "-----------------------------"
  759. 7520  FOR Y = 0 TO 2
  760. 7530  PRINT  TAB( 6);G(0,Y); TAB( 12);"<GAME";(Y +1);">"; TAB( 23);G(1,Y)
  761. 7540  PRINT : INVERSE 
  762. 7550  PRINT "                             "
  763. 7560  NORMAL : PRINT 
  764. 7570  NEXT 
  765. 7580  RETURN 
  766. 7590  PRINT  TAB( 6);QE; TAB( 12);
  767. 7600  PRINT "<TOTAL>"; TAB( 23);QW: PRINT 
  768. 7610  INVERSE : PRINT "                             ": NORMAL 
  769. 7620  PRINT 
  770. 7630  IF ZZ =  -1  THEN  CALL  -198: FLASH : PRINT "GAME OVER";: NORMAL : GOSUB 620:UB = O:OB = O
  771. 7640  PRINT "  PLAY AGAIN ? (Y/N) ";
  772. 7650  GET AX$: IF AX$ = "N"  THEN  END 
  773. 7660  RETURN 
  774. 7670 RS = 0
  775. 7680  FOR XZ = 1 TO 7
  776. 7690  IF (43 -NP -SP) >(16 +3 *XZ)  THEN RS = XZ
  777. 7700  NEXT 
  778. 7710 ET = 0:WT = 0
  779. 7720  FOR J8 = 1 TO 4
  780. 7730 TE = 0:TW = 0
  781. 7740  FOR K8 = 1 TO 13
  782. 7750 TE = TE +E(K8,J8):TW = TW +W(K8,J8)
  783. 7760  NEXT 
  784. 7770  IF TE > = ET  THEN ES = J8:ET = TE
  785. 7780  IF TW > = WT  THEN WS = J8:WT = TW
  786. 7790  NEXT 
  787. 7800  IF WT >ET  THEN EW = WS
  788. 7810  IF ET > = WT  THEN EW = ES
  789. 7820 RS = RS +EW/10
  790. 7830  IF EW = 1  THEN EW$ = "CLUBS"
  791. 7840  IF EW = 2  THEN EW$ = "DIAMONDS"
  792. 7850  IF EW = 3  THEN EW$ = "HEARTS"
  793. 7860  IF EW = 4  THEN EW$ = "SPADES"
  794. 7870  IF RS <1  THEN EW$ = " "
  795. 7880  RETURN