home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib19a.dsk / APRIL.1984 / LABEL.PRINTER.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  33 lines
  1. 10  REM  **********************
  2. 20  REM  *   LABEL.PRINTER    *
  3. 30  REM  * BY ROBERT C. BROCK *
  4. 40  REM  * COPYRIGHT (C) 1984 *
  5. 50  REM  * BY MICROSPARC, INC *
  6. 60  REM  * LINCOLN, MA. 01773 *
  7. 70  REM  **********************
  8. 80  TEXT : HOME : CLEAR : POKE 34,10: DIM L$(5)
  9. 90  INVERSE : PRINT "***   L A B E L     P R I N T E R   ***": PRINT "***       BY  ROBERT C. BROCK       ***": PRINT "*  COPYRIGHT 1984 BY MICROSPARC, INC  *": NORMAL 
  10. 100  VTAB 5: INPUT "HOW MANY LABELS TO PRINT?     ";NN
  11. 110  VTAB 6: INPUT "HOW MANY LINES PER LABEL?     ";N
  12. 120  IF N < = 0  OR N >5  THEN  GOTO 110
  13. 130  VTAB 8: PRINT "TYPE STYLE:  1) STANDARD": PRINT  TAB( 14)"2) CONDENSED": PRINT  TAB( 14)"3) DOUBLE WIDTH  ";: INPUT "";TY$
  14. 140  IF TY$ = "1"  OR TY$ = "2"  OR TY$ = "3" GOTO 160
  15. 150  GOTO 130
  16. 160  IF TY$ = "1"  THEN LT = 18:SP = 25:DW = 18
  17. 170  IF TY$ = "2"  THEN LT = 15:SP = 45:DW = 18
  18. 180  IF TY$ = "3"  THEN LT = 14:SP = 21:DW = 15
  19. 190  FOR NL = 1 TO N
  20. 200  VTAB 12: PRINT : PRINT "LINE #";NL;":": PRINT : PRINT  CHR$(91);: FOR L = 1 TO SP: PRINT ".";: NEXT L: PRINT  CHR$(93)
  21. 210  VTAB 15: HTAB 2: INPUT "";L$(NL)
  22. 220  IF  LEN(L$(NL)) >SP  THEN  HOME : GOTO 200
  23. 230  NEXT NL
  24. 240  HOME : VTAB 14: PRINT "THIS IS THE WAY THE LABEL WILL LOOK:": PRINT 
  25. 250  INVERSE : FOR C = 1 TO 5: PRINT L$(C): NEXT C: NORMAL 
  26. 260  VTAB 22: PRINT "IS THIS CORRECT? (Y/N) ";: GET AN$
  27. 270  IF AN$ = "Y"  THEN  POKE 34,3: GOTO 290
  28. 280  IF AN$ = "N"  THEN  HOME : GOTO 190
  29. 290  HOME : PRINT : PRINT  CHR$(4)"PR#1"
  30. 300  FOR C = 1 TO NN: FOR I = 1 TO 5: PRINT  CHR$(DW); CHR$(LT);L$(I): NEXT I: PRINT : NEXT C
  31. 310  PRINT  CHR$(4)"PR#0": POKE 34,3: HOME : VTAB 5: PRINT "RUN MORE LABELS? (Y/N) ";: GET AN$: PRINT AN$
  32. 320  IF AN$ = "Y"  THEN  GOTO 80
  33. 330  POKE 34,0: HOME : END