home *** CD-ROM | disk | FTP | other *** search
/ Transactor / Transactor_22_1988_Transactor_Publishing.d64 / clock-cal.bud < prev    next >
Text File  |  2023-02-26  |  15KB  |  705 lines
  1. ;put"@0:clock-cal.bud
  2. ; ** rewritten in Buddy 128 Format
  3. ; 
  4. *=$1300 ; 4864
  5. .obj "@0:clk4864"
  6. ;
  7. ;* * * * * * * * * * * * * * * * *
  8. ;*                               *
  9. ;* clock & calendar display...   *
  10. ;* with audible alarm function   *
  11. ;*                               *
  12. ;* c-128 mode, 40 or 80 columns  *
  13. ;*                               *
  14. ;* written 11-16-85  w.j. brier  *
  15. ;*                               *
  16. ;* revised  6-05-87              *
  17. ;*                               *
  18. ;* copyright 1986                *
  19. ;*                               *
  20. ;* this program is not to be...  *
  21. ;* sold.  it is permissible...   *
  22. ;* to copy it but credit must... *
  23. ;* be given in the documentation *
  24. ;*                               *
  25. ;* see the documentation for...  *
  26. ;* instructions on using this... *
  27. ;* program with your software... *
  28. ;* as well as distribution...    *
  29. ;* limitations.                  *
  30. ;*                               *
  31. ;* * * * * * * * * * * * * * * * *
  32.               ;
  33.               ;
  34. ;* * * * * * * * * * * * * * * * *
  35. ;*                               *
  36. ;*  <<< program assignments >>>  *
  37. ;*                               *
  38. ;* * * * * * * * * * * * * * * * *
  39.               ;
  40.               ;
  41. ;system vectors & pointers...
  42.               ;
  43. dflto  =$9a   ;output device
  44.               ;
  45. mode   =$d7   ;display mode flag
  46.               ;
  47. cinv   =$0314 ;normal irq vector
  48. ibsout =$0326 ;normal chrout vector
  49.               ;
  50. system =$0a00 ;basic reset vector
  51.               ;
  52. rptflg =$0a22 ;keyb'd repeat flag
  53.               ;
  54. basrst =$4003 ;basic warm reset
  55.               ;
  56. tod2   =$dd08 ;time of day clock #2
  57.               ;
  58.               ;
  59. ;screen editor functions...
  60.               ;
  61. wvdcm  =$cdca ;write to 8563 ram
  62. wvdcr  =$cdcc ;write to 8563 register
  63.               ;
  64.               ;
  65. ;kernal functions...
  66.               ;
  67. chrout =$ef79 ;output a byte
  68. irq    =$fa65 ;normal irq
  69. crti   =$ff33 ;irq handler exit
  70.               ;
  71.               ;
  72. ;40 col vic screen ram...
  73.               ;
  74. vcram  =$0400 ;start of display ram
  75. vlram  =$d800 ;start of color ram
  76.               ;
  77.               ;
  78. ;sid chip registers (voice 3)...
  79.               ;
  80. frelo3 =$d40e ;frequency ctrl (lo)
  81. frehi3 =$d40f ;frequency ctrl (hi)
  82.               ;
  83. vcreg3 =$d412 ;control register
  84.               ;
  85. surel3 =$d414 ;sustain/release
  86.               ;
  87. sigvol =$d418 ;sid volume
  88.               ;
  89.               ;
  90. ;80 col 8563 vdc assignments...
  91.               ;
  92. scram1 =72    ;screen ram (time)
  93. scram2 =152   ;screen ram (date)
  94.               ;
  95. atram1 =2120  ;attribute ram (time)
  96. atram2 =2200  ;attribute ram (date)
  97.               ;
  98. upreg  =18    ;update register
  99.               ;
  100.               ;
  101. ;=================================
  102.        ;
  103.        ;
  104. ;user-accessible memory...
  105.        ;
  106. tdta   .asc "  -  -  "
  107.        .byte 0 ; ascii date
  108. toda   .asc "  :  :  "              
  109.        .byte 0 ; ascii time
  110. tdtc   .byte 255, 255, 255  ;bcd date
  111. ;
  112. dflg   .byte 0 ;1 = no display
  113. cflg   .byte 7 ;display color
  114. rflg   .byte 0 ;1 = reverse video
  115.        ;
  116. key    .byte 0, 0, 0, 0
  117.        ;
  118.        ;
  119. ;exit vector...
  120.        ;
  121. irqa   .word irq
  122.        ;
  123.        ;
  124. ;alarm registers...
  125.        ;
  126. altc   .byte 255, 255 ;time (h:m)
  127.        ;
  128. aflg   .byte 255     ;enable flag
  129.        ;
  130. ;---------------------------------
  131.        ;
  132. ;entry point to start display
  133.        ;
  134. clkon  jmp start ;start display
  135.        ;
  136. ;---------------------------------
  137.        ;
  138. ;entry point to stop display
  139.        ;
  140. clkof  jmp stop ;stop display
  141.        ;
  142. ;---------------------------------
  143.        ;
  144. ;bcd time storage
  145.        ;
  146. todc   .byte 0, 0, 0 ;hrs min sec
  147.        ;
  148. ;=================================
  149.        ;
  150. ;stop clock-calendar display
  151.        ;
  152. stop   ldx cinv ;irq vector
  153.        ldy cinv+1
  154.        cpx #<dcc ;display vector
  155.        bne clkof2 ;not running
  156.        ;
  157.        cpy #>dcc
  158.        bne clkof2 ;not running
  159.        ;
  160.        sei ;interrupts off
  161.        ;
  162.        ldx irqa ;original irq vector
  163.        ldy irqa+1
  164.        stx cinv
  165.        sty cinv+1
  166.        ;
  167.        ldx bsouta
  168.        ldy bsouta+1
  169.        stx ibsout ;restore chrout vector
  170.        sty ibsout+1
  171.        ;
  172.        ldx alrst1
  173.        ldy alrst1+1
  174.        stx system ;restore system vector
  175.        sty system+1
  176.        ;
  177.        cli ;interrupts on
  178.        ;
  179.        ldy #3 ;offset
  180.        lda #0
  181.        ;
  182. clkof1 sta key,y ;wipe out id key
  183.        dey
  184.        bpl clkof1 ;loop
  185.        ;
  186. clkof2 rts
  187.        ;
  188. ;---------------------------------
  189.        ;
  190. ;start clock-calendar display
  191.        ;
  192. start  ldx cinv ;irq vector
  193.        ldy cinv+1
  194.        cpx #<dcc
  195.        bne start1 ;change vector
  196.        ;
  197.        cpy #>dcc
  198.        beq start3 ;display is runnning
  199.        ;
  200. start1 stx irqa ;save existing...
  201.        sty irqa+1 ;irq vector
  202.        ;
  203.        sei
  204.        ;
  205.        ldx #<dcc ;change...
  206.        ldy #>dcc ;irq vector so that...
  207.        stx cinv ;clock-calendar runs
  208.        sty cinv+1
  209.        ;
  210.        ldx ibsout ;save current...
  211.        ldy ibsout+1 ;chrout vector
  212.        stx bsouta
  213.        sty bsouta+1
  214.        ;
  215.        ldx #<crdy ;change...
  216.        ldy #>crdy ;chrout vector so...
  217.        stx ibsout ;delay routine...
  218.        sty ibsout+1 ;intercepts it
  219.        ;
  220.        ldx system ;basic reset
  221.        ldy system+1
  222.        stx alrst1 ;store
  223.        sty alrst1+1
  224.        ;
  225.        ldx #<alrst ;alternate reset
  226.        ldy #>alrst
  227.        stx system ;new reset vector
  228.        sty system+1
  229.        ;
  230.        lda tod2 ;give clock a kick...
  231.        sta tod2 ;to get it started
  232.        ;
  233.        cli
  234.        ;
  235.        ldy #3 ;offset
  236.        ;
  237. start2 lda keystr,y ;key
  238.        sta key,y ;enable key
  239.        dey
  240.        bpl start2 ;loop
  241.        ;
  242.        iny
  243.        sty dflg ;clear display flag
  244.        sty lflg ;clear lockout flag
  245.        ;
  246. start3 rts
  247.        ;
  248. ;=================================
  249.        ;
  250. ;update & display time & date
  251.        ;
  252. dcc    cld ;binary mode
  253.        ;
  254.        lda tod2 ;tenths of seconds
  255.        beq dcc02 ;tenths are zero
  256.        ;
  257.        lda #0
  258.        sta lflg ;clear lockout flag
  259.        ;
  260. dcc01  jmp (irqa) ;normal irq
  261.        ;
  262. dcc02  bit lflg
  263.        bmi dcc01 ;update locked out
  264.        ;
  265.        dec lflg ;set lockout flag
  266.        ;
  267.        ;
  268. ;read clock registers...
  269.        ;
  270.        ldx #3 ;tod2 offset
  271.        ldy #0 ;storage offset
  272.        ;
  273. dcc03  lda tod2,x ;fetch time value
  274.        dex
  275.        bmi dcc04 ;finished
  276.        ;
  277.        sta todc,y ;save in buffer
  278.        ;
  279.        iny
  280.        bne dcc03 ;loop
  281.        ;
  282.        ;
  283. ;test am/pm flag & adjust hours
  284.        ;
  285. dcc04  lda todc ;bcd hours
  286.        bmi dcc05 ;it's pm
  287.        ;
  288.        cmp #$12
  289.        bne dcc06 ;not midnite
  290.        ;
  291.        lda #0
  292.        beq dcc06 ;set hours to midnite
  293.        ;
  294. dcc05  and #%01111111 ;mask am/pm bit
  295.        cmp #$12
  296.        bcs dcc06 ;it's noon straight up
  297.        ;
  298.        sed ;decimal mode
  299.        adc #$12 ;change to 24 hours
  300.        cld ;binary mode
  301.        ;
  302. dcc06  sta todc ;converted hours
  303.        ;
  304.        ;
  305. ;test for alarm time...
  306.        ;
  307.        bit aflg ;check flag
  308.        bmi dcc09 ;alarm not enabled
  309.        ;
  310.        ldy #1 ;offset
  311.        ;
  312. dcc07  lda altc,y ;alarm time
  313.        cmp todc,y ;check against tod
  314.        bne dcc09 ;not time
  315.        ;
  316.        dey
  317.        bpl dcc07 ;loop
  318.        ;
  319.        ;
  320. ;sound alarm...
  321.        ;
  322.        lda #15
  323.        sta sigvol ;max volume
  324.        sta frelo3 ;set frequency
  325.        sta frehi3
  326.        ;
  327.        ldx #250 ;duration
  328.        ldy #33 ;sawtooth waveform
  329.        stx surel3 ;sustain/release
  330.        sty vcreg3 ;attack/decay
  331.        ;
  332.        dey
  333.        sty vcreg3 ;gate voice
  334.        ;
  335.        ;
  336. ;test for stroke of midnite...
  337.        ;
  338. dcc09  ldy #2 ;todc offset
  339.        ;
  340. dcc10  lda todc,y ;fetch time value
  341.        bne dcc16 ;not midnite
  342.        ;
  343.        dey
  344.        bpl dcc10 ;loop
  345.        ;
  346.        ;
  347. ;test for leap year...
  348.        ;
  349.        lda tdtc+2 ;current year
  350.        jsr bcdof ;change to binary
  351.        ;
  352.        ldx #$28
  353.        ;
  354.        lsr ;divide by 2
  355.        bcs dcc11 ;odd year
  356.        ;
  357.        lsr ;divide again
  358.        bcs dcc11 ;non-leap year
  359.        ;
  360.        inx ;leap year
  361.        ;
  362. dcc11  stx clut+1 ;last day in feb.
  363.        ;
  364.        ;
  365. ;adjust date for end of month...
  366.        ;
  367.        lda tdtc ;fetch month
  368.        jsr bcdof ;change to binary
  369.        ;
  370.        tax
  371.        dex ;calendar lookup offset
  372.        ;
  373.        lda tdtc+1 ;current day
  374.        cmp clut,x ;last day of month
  375.        bne dcc14 ;not end of month
  376.        ;
  377.        cpx #11
  378.        bne dcc12 ;not december
  379.        ;
  380.        lda tdtc+2 ;current year
  381.        jsr idv ;bump year
  382.        sta tdtc+2 ;save new year
  383.        ;
  384.        lda #1
  385.        bne dcc13 ;set month to january
  386.        ;
  387. dcc12  lda tdtc ;current month
  388.        jsr idv ;bump
  389.        ;
  390. dcc13  sta tdtc ;new month
  391.        ;
  392.        lda #1
  393.        bne dcc15 ;set day to 1st of month
  394.        ;
  395. dcc14  jsr idv ;bump day
  396.        ;
  397. dcc15  sta tdtc+1 ;new day
  398.        ;
  399.        ;
  400. ;decode date for display...
  401.        ;
  402. dcc16  lda tdtc ;current month
  403.        jsr bcdasc ;decode to ascii
  404.        cmp #"0"
  405.        bne dcc17
  406.        ;
  407.        lda #32 ;blank leading zero
  408.        ;
  409. dcc17  sta tdta ;save tens
  410.        stx tdta+1 ;save units
  411.        ;
  412.        lda tdtc+1 ;current day
  413.        jsr bcdasc
  414.        sta tdta+3
  415.        stx tdta+4
  416.        ;
  417.        lda tdtc+2 ;current year
  418.        jsr bcdasc
  419.        sta tdta+6
  420.        stx tdta+7
  421.        ;
  422.        ;
  423. ;decode time for display...
  424.        ;
  425.        lda todc ;hours
  426.        jsr bcdasc
  427.        sta toda
  428.        stx toda+1
  429.        ;
  430.        lda todc+1 ;minutes
  431.        jsr bcdasc
  432.        sta toda+3
  433.        stx toda+4
  434.        ;
  435.        lda todc+2 ;seconds
  436.        jsr bcdasc
  437.        sta toda+6
  438.        stx toda+7
  439.        ;
  440.        ;
  441. ;display time & date...
  442.        ;
  443.        lda dflg
  444.        bne dcc23 ;display inhibited
  445.        ;
  446.        ;
  447. ;display on 40 column screen...
  448.        ;
  449. dcc18  lda cflg ;display color
  450.        ldy #7 ;offset
  451.        ;
  452. dcc19  sta vlram+32,y ;color
  453.        sta vlram+72,y
  454.        dey
  455.        bpl dcc19 ;loop
  456.        ;
  457.        ldx rflg ;normal/reverse flag
  458.        ldy #7 ;offset
  459.        ;
  460. dcc20  lda toda,y ;fetch time
  461.        ;
  462.        cpx #0 ;test reverse flag
  463.        beq dcc21 ;not reversed
  464.        ;
  465.        ora #128 ;reverse
  466.        ;
  467. dcc21  sta vcram+32,y
  468.        ;
  469.        lda tdta,y ;fetch date
  470.        cpx #0
  471.        beq dcc22
  472.        ;
  473.        ora #128
  474.        ;
  475. dcc22  sta vcram+72,y
  476.        ;
  477.        dey
  478.        bpl dcc20
  479.        ;
  480.        ;
  481. ;display on 80 column screen...
  482.        ;
  483.        lda #>scram1 ;address for...
  484.        ldy #<scram1 ;time display
  485.        jsr setram ;set up vdc ram
  486.        ;
  487.        ldx #<toda ;petascii time
  488.        ldy #>toda
  489.        jsr dtod ;display
  490.        ;
  491.        lda #>scram2 ;address for...
  492.        ldy #<scram2 ;date display
  493.        jsr setram
  494.        ;
  495.        ldx #<tdta ;petascii date
  496.        ldy #>tdta
  497.        jsr dtod ;display
  498.        ;
  499.        ;
  500. ;set 80 column attributes...
  501.        ;
  502.        lda #>atram1 ;address for...
  503.        ldy #<atram1 ;time attribute
  504.        jsr setram
  505.        ;
  506.        jsr atrst ;set up attributes
  507.        ;
  508.        lda #>atram2 ;address for...
  509.        ldy #<atram2 ;date attribute
  510.        jsr setram
  511.        ;
  512.        jsr atrst ;set up attributes
  513.        ;
  514.        bit mode
  515.        bpl dcc23 ;40 column mode
  516.        ;
  517.        jmp crti ;bypass rest of irq
  518.        ;
  519. dcc23  jmp (irqa) ;continue irq
  520.        ;
  521. ;=================================
  522.        ;
  523. ;display time or date
  524.        ;
  525. dtod   stx dtod02 ;source address
  526.        sty dtod02+1
  527.        ;
  528.        ldy #0 ;offset
  529.        ;
  530. dtod01 .byte $b9 ;lda llhh,y op-code
  531.        ;
  532. dtod02 *=*+2 ;source address
  533.        ;
  534.        beq atrst3 ;end of string
  535.        ;
  536.        jsr wvdcm ;output to 8563
  537.        iny
  538.        bne dtod01 ;loop
  539.        ;
  540. ;---------------------------------
  541.        ;
  542. ;set up display attributes
  543.        ;
  544. atrst  ldy #8 ;counter
  545.        ;
  546. atrst1 lda cflg ;get color
  547.        ldx rflg
  548.        beq atrst2 ;no reverse display
  549.        ;
  550.        ora #%01000000 ;reverse
  551.        ;
  552. atrst2 jsr wvdcm ;output to 8563
  553.        dey
  554.        bne atrst1 ;loop
  555.        ;
  556. atrst3 rts
  557.        ;
  558. ;---------------------------------
  559.        ;
  560. ;set up vdc ram address
  561.        ;
  562. setram ldx #upreg ;update register
  563.        jsr wvdcr ;write
  564.        inx
  565.        tya ;swap hi byte
  566.        jmp wvdcr
  567.        ;
  568. ;---------------------------------
  569.        ;
  570. ;chrout intercept & trap
  571.        ;
  572. crdy   pha ;save printing char.
  573.        ;
  574.        bit mode
  575.        bpl crdy01 ;in 40 columns
  576.        ;
  577.        lda dflto ;output device
  578.        cmp #3
  579.        bne crdy01 ;not screen
  580.        ;
  581.        lda dflg ;test display flag
  582.        bne crdy01 ;display inhibited
  583.        ;
  584.        dec dflg ;block display
  585.        ;
  586. crdy01 pla ;recover character
  587.        ;
  588.        .byte 32 ;jsr op-code
  589.        ;
  590. bsouta .word chrout ;normal chrout
  591.        ;
  592.        bit dflg
  593.        bpl crdy02 ;no reset needed
  594.        ;
  595.        inc dflg ;clear for display
  596.        ;
  597. crdy02 rts
  598.        ;
  599. ;---------------------------------
  600.        ;
  601. ;convert bcd to petascii
  602.        ;
  603. bcdasc jsr bcdbin ;bcd to binary
  604.        ;
  605.        pha ;save tens value
  606.        ;
  607.        txa ;units value
  608.        ora #48 ;change to petascii
  609.        tax ;hold
  610.        ;
  611.        pla ;fetch tens
  612.        ora #48
  613.        ;
  614.        rts
  615.        ;
  616. ;---------------------------------
  617.        ;
  618. ;bcd digit to 2 binary digits
  619.        ;
  620. bcdbin pha ;save bcd value
  621.        ;
  622.        and #15 ;mask tens nybble
  623.        tax ;units in .x register
  624.        ;
  625.        pla ;fetch bcd value
  626.        ;
  627.        lsr ;shift tens nybble
  628.        lsr  
  629.        lsr  
  630.        lsr  
  631.        ;
  632.        rts
  633.        ;
  634. ;---------------------------------
  635.        ;
  636. ;bcd digit to 1 binary digit
  637.        ;
  638. bcdof  jsr bcdbin ;bcd to binary
  639.        ;
  640.        tay ;tens value
  641.        txa ;units
  642.        ;
  643.        clc
  644.        ;
  645. bcdof1 dey ;counter
  646.        bmi idv01 ;finished
  647.        ;
  648.        adc #10
  649.        bne bcdof1
  650.        ;
  651. ;---------------------------------
  652.        ;
  653. ;increment date value
  654.        ;
  655. idv    sed ;decimal mode
  656.        ;
  657.        clc
  658.        adc #1
  659.        ;
  660.        cld ;binary mode
  661.        ;
  662. idv01  rts
  663.        ;
  664. ;---------------------------------
  665.        ;
  666. ;alternate basic reset
  667.        ;
  668. alrst  jsr start ;restart clock
  669.        ;
  670.        lda #0
  671.        sta rptflg ;repeat off
  672.        ;
  673.        .byte $4c ;jmp llhh op-code
  674.        ;
  675. alrst1 *=*+2 ;reset jump
  676.        ;
  677. ;---------------------------------
  678.        ;
  679. ;calendar lookup table
  680.        ;
  681. clut   .byte $31 ;jan
  682.        .byte $28 ;feb
  683.        .byte $31 ;mar
  684.        .byte $30 ;apr
  685.        .byte $31 ;may
  686.        .byte $30 ;jun
  687.        .byte $31 ;jul
  688.        .byte $31 ;aug
  689.        .byte $30 ;sep
  690.        .byte $31 ;oct
  691.        .byte $30 ;nov
  692.        .byte $31 ;dec
  693.        ;
  694. ;---------------------------------
  695.        ;
  696. ;program storage
  697.        ;
  698. keystr .asc "clk"  
  699.        .byte 0
  700.        ;
  701. lflg   *=*+1  ;display lockout
  702.        ;
  703. ;=================================
  704. .end
  705.