home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Go64!
/
Go64_2003-12_2003_CSW_Side_B.d64
/
hl25e.d64
/
hl25e.d64
/
cfgr
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2003-09-25
|
6KB
|
153 lines
1 clr:mm=64:iffre(0)<>fre(1)thenmm=128
2 ifmm=64thenpoke808,225:kk=198:goto10
3 poke808,124:(NULL)clr:(NULL)15:(NULL)60000:kk=208:(NULL)1,chr$(133):(NULL)3,chr$(134):(NULL)5,chr$(135):(NULL)7,chr$(136):(NULL)5:print"[147][211]witch to 40 columns!":(NULL)0
10 poke53280,6:poke53281,6:gosub1070:print"";:dv=peek(186):ifdv<8thendv=8
20 print"[158][200]yper[204]ink 2.5 [208]atch [197] [211]etup [213]tility"
40 print"[212]his program will assist you in"
50 print"configuring [200]yper[204]ink 2.5e for your"
60 print"64 or 128's hardware configuration."
70 print"([195])1994-2003 [195]ameron [203]aiser. [193]ll"
80 print"rights reserved.":gosub1000
90 print"[158][215][193][210][206][201][206][199]!"
100 print"[193]nswering the following questions"
110 print"incorrectly can cause [200]yper[204]ink 2.5e"
120 print"to crash or behave adversely."
130 print"[201]f you are not sure how to answer a"
140 print"setup question, please contact"
150 print"[195]omputer [215]orkshops technical support"
160 print"before you continue with setup.":gosub1000
170 print"[158][201]nput [196]evices"
180 print"[211]elect the input device you will be"
190 print"using with[160][200]yper[204]ink 2.5e."
191 print"[201]f you are using a joystick or a"
192 print"1350 mouse, plug it into port 2 and"
193 print"press [198]1."
194 print"[201]f you are using a 1351 or other"
195 print"true proportional mouse, plug it"
196 print"into port 1 and press [198]3."
200 o1$="[202]oystick/1350 mouse":o2$="1351 mouse/compatible":gosub1020
210 ifop=0goto20
211 mu=op:mu$=rs$
220 print"[158][195]ache [205]emory"
230 print"[200]yper[204]ink 2.5e can use certain kinds"
240 print"of [210][193][205] expansion as disk or network"
250 print"cache to speed operation."
260 print"[200]yper[204]ink 2.5e supports any 100% [210][197][213]"
270 print"or geo[210][193][205]-compatible [210][193][205] expansion,"
280 print"or the [214][196][195] memory in all 128s."
290 print"[195]ache is optional. [196]o not enable it"
300 print"if you have an unsupported device"
310 print"or no [210][193][205] expansion of any kind.":o2$="[213]se cache"
320 o1$="[196]on't use cache":gosub1020:ifop=0goto170
330 ca=op:c1$="n/a":c2$="n/a":cp=255:ca$=rs$:ifop=1goto600
340 print"[158][195]ache [212]ype"
350 print"[201]f you are using a geo[210][193][205], [210][197][213], or a"
360 print"100% compatible expander plugged in"
362 print"the cartridge port, press [198]1."
370 print"[207]therwise, if you are using a [195]128,"
380 print"press [198]3 to use the [195]128's built-in"
382 print"[214][196][195] memory."
390 o1$="geo[210][193][205]/[210][197][213]/clones":o2$="128 [214][196][195] memory":gosub1020:ifop=0goto220
392 c1$=rs$:c1=op:ifop=2goto490
400 remc2=2:goto600:rem future is now!
401 print"[158][195]ache [212]ype ([195]artridge [208]ort)"
410 print"[201]f you are using an [210][197][213] or a"
420 print"compatible device, press [198]1."
430 print"[201]f you are using geo[210][193][205](tm) or a"
440 print"compatible device, press [198]3."
450 print"[217]our expander must have at least"
460 print"128[203] available memory to operate.":o1$="[210][197][213]/compatible"
470 o2$="geo[210][193][205]/compatible":gosub1020:ifop=0goto340
480 c2=op:c2$=rs$:goto600
490 print"[158][195]ache [211]ize ([214][196][195])"
500 print"[200]yper[204]ink 2.5e supports two [214][196][195]"
510 print"memory configurations: 16[203] and 64[203]."
511 print"[214][196][195] memory is not supported in other"
512 print"configurations by [200]yper[204]ink."
520 print"[208]ress [198]1 if you have 16[203] [214][196][195] memory"
530 print"(most flat 128s, [197]uropean 128[196]s)."
540 print"[208]ress [198]3 if you have 64[203] [214][196][195] memory"
550 print"(expanded flat 128s, 128[195][210], [206]orth"
560 print"[193]merican 128[196]s, all 128[196][195][210]s).":o1$="16[203] [214][196][195]":o2$="64[203] [214][196][195]"
590 gosub1020:ifop=0goto340
592 c2=op:c2$=rs$
600 print"[158][205]odem [195]onfiguration"
601 print"[158][212]he undocumented 1200bps mode in the"
602 print"original [200][204]2.5 is no longer enabled."
610 print"[201]f you are using [200]yper[204]ink 2.5e in"
620 print"offline mode only, press [198]1."
630 print"[201]f you are using a [211]wift[204]ink,"
640 print"[212]urbo232 or other 6551 [193][195][201][193] device,"
650 print"press [198]3.":o1$="[207]ffline only"
680 print"[207]therwise, press [198]1."
690 o2$="[211][204]/[212]232/other [193][195][201][193]":gosub1020:ifop=0goto220
692 bs=0:m2=56832:bp=0:mo=op:mo$=rs$:m1$="n/a":m2$="n/a":ifop=1goto900
700 print"[158][205]odem [195]onfiguration ([208]ort [211]peed)"
710 print"[211]elect the port speed to communicate"
720 print"with your modem. [213]sually the fastest"
730 print"port speed for your hardware is best"
740 print"and should be set at or above your"
750 print"modem's maximum connection speed."
751 print"(57600bps valid only for [212]urbo232.)"
755 bp=1200:forx=1to7:printtab(15)"[158]<"mid$(str$(x),2,1)"> "bp:bp=bp*2
756 ifbp>57600thenbp=57600
757 next:print""tab(8)"[158]<[198]7> [208]revious section":poke198,.:poke53265,27
760 geta$:ifa$<>"[136]"and(a$<"1"ora$>"7")goto760
770 gosub1070:ifa$="[136]"goto600
780 bs=val(a$)+4:bp=300*(2^(bs-3)):ifbp>57600thenbp=57600
790 print"[158][205]odem [195]onfiguration ([201]/[207])"
800 print"[217]our [211][204], [212]232 or [193][195][201][193] device can be"
810 print"driven from two memory areas."
820 print"[208]ress [198]1 if your [193][195][201][193] device appears"
830 print"at $[196][197]00 in memory (the standard"
840 print"location for most [193][195][201][193] cartridges)."
850 print"[208]ress [198]3 if your [193][195][201][193] has been"
860 print"altered or reconfigured to appear at"
870 print"$[196][198]00 in memory instead.":o1$="$[196][197]00":o2$="$[196][198]00":gosub1020
880 m2$=rs$:m2=op*256+56576:ifop=0goto700
900 print"[158][211]etup is ready to configure your"
910 print"copy of [200]yper[204]ink 2.5e. [208]lease check"
920 print"the information below."
922 print"(n/a indicates settings not required"
923 print"for the options you selected.)"
930 print"[158][201]nput: "mu$
940 print"[158][195]ache: "ca$
950 print"[146][146] "c1$
952 print"[146][146] "c2$
960 print"[158][205]odem: "mo$
970 print"[146][146] "m2$","bp"bps"
980 o1$="[195]orrect, continue setup":o2$="[201]ncorrect, restart setup":gosub1020
990 ifop=0goto600
991 ifop=2goto20
999 goto2000
1000 print"[208]ress any key to continue.":pokekk,.
1010 poke53265,27:waitkk,1:geta$:poke53265,11:print"[147]";:return
1020 print""tab(8)"[158]<[198]1> "o1$
1030 printtab(8)"[158]<[198]3> "o2$:print""tab(8)"[158]<[198]7> [208]revious section":poke198,.
1040 poke53265,27
1050 geta$:ifa$<>"[133]"anda$<>"[134]"anda$<>"[136]"goto1050
1060 op=asc(a$)-132:ifop>2thenop=0
1062 rs$=o1$:ifop>1thenrs$=o2$
1070 poke53265,11:print"[147]";:return
2000 poke53265,27:print"[158][147][195]onfiguring ..."
2010 open15,dv,15,"s0:config.cache":close15:open1,dv,2,"config.cache,u,w"
2020 print#1," ":cf$="input.joy":mw=0:ifmu=2thencf$="input.mouse":mw=1
2021 print#1,cf$
2030 cf$="cache.none":pg=255:ifca=1goto2060
2040 ifc1=1goto2070
2050 cf$="cache.vdc16":pg=0:ifc2=2thencf$="cache.vdc64":pg=3
2060 print#1,cf$:goto2090
2070 cf$="cache.reu":pg=7:ifc2=2thencf$="cache.georam"
2080 goto2060
2090 cf$="modem.turbo232":ifmo=1thencf$="modem.kernal"
2100 print#1,cf$:print#1,"-eol-":print#1,mw:print#1,pg
2110 print#1,m2
2120 print#1,bs
2130 close1:print"[147][217]our copy of [200]yper[204]ink 2.5e is ready"
2140 print"for use. [208]ress [210][197][212][213][210][206] to begin."
2142 ifmm=64goto2150
2145 print"bank15:sys65341[145][145][145]":poke808,110:new
2150 print"load"chr$(34)"cwi"chr$(34)","dv",1[145][145][145]":poke43,1:poke808,237:new
59999 end
60000 print"[147][198]atal error, restarting":sys65341:new