home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ANG-Pokey Magazine 3
/
ANG_Pokey_Magazine_03_1993_01_ANG_Software_nl_Side_B.atr
/
arcdocs.arc
/
SPLAY.SRC
< prev
next >
Wrap
Text File
|
1988-09-01
|
2KB
|
175 lines
* EERSTE DEEL VAN HET TWEEDE DEEL!?
* PLAY SAMPLES..
ORG $8900,$B900
PICTURE EQU $9010
PIECES EQU $7E00
SEQUEN EQU $7F00
SEQEND EQU $8900
SEQNR EQU $F0 (AND $F1)
SPLBEG EQU $F2 (AND $F3)
SPLEND EQU $F4 (AND $F5)
TIME EQU $F6
AUDIO EQU $D201
IRQEN EQU $D20E
DMACTL EQU $D400
WSYNC EQU $D40A
NMIEN EQU $D40E
INIT LDA #50
STA TIMER
LDA #4
STA COLOR
LDA #NMI
STA $FFFA
LDA #NMI/256
STA $FFFB
LDA #DLI
STA $200
LDA #DLI/256
STA $201
LDA #$C0
STA $D40E
PAUWAN LDA TIMER
CMP #1
BNE PAUWAN
RUN LDA #0
STA IRQEN
STA TIME
LDA #SEQUEN:L
STA SEQNR
LDA #SEQUEN:H
STA SEQNR+1
LDY #0
LDA (SEQNR),Y
NIETNUL TAX
LDA PIECES,X
STA SPLBEG+1
LDA PIECES+$20,X
STA SPLBEG
LDA PIECES+$10,X
STA SPLEND+1
LDA PIECES+$30,X
STA SPLEND
INC SEQNR
BNE NOSEQ
INC SEQNR+1
NOSEQ LDA SEQNR+1
CMP #SEQEND:H
BNE DIZ
LDA #SEQUEN:H
STA SEQNR+1
DIZ LDA #$8D
STA COMMAND
THENOT LDA (SPLBEG),Y
AND #%00001111
JSR NOISE
LDA (SPLBEG),Y
LSR
LSR
LSR
LSR
JSR NOISE
INC TIME
INC SPLBEG
BNE NSPLEND
INC SPLBEG+1
NSPLEND LDA SPLBEG
CMP SPLEND
BNE NOWAY
LDA SPLBEG+1
CMP SPLEND+1
BNE NOWAY
LDA #$AD
STA COMMAND
NOWAY LDA TIME
CMP #$EA ;TIME END
BNE THENOT
LDA #0
STA TIME
LDA (SEQNR),Y
BNE NIETNUL
INC SEQNR
BNE THENOT
INC SEQNR+1
JMP THENOT
NOISE ORA #%00010000
STA WSYNC
STA WSYNC
COMMAND STA AUDIO
RTS
NMI PHA
BIT $D40F
BPL VBLANK
JMP ($200)
VBLANK STA $D40F
LDA #DL:L
STA $D402
LDA #DL:H
STA $D403
LDA #34
STA $D400
LDA COLOR
CLC
STA $D016
ADC #2
STA $D017
ADC #4
STA $D018
DEC TIMER
BNE NIENU
LDA #50
STA TIMER
LDA COLOR
CLC
ADC #$10
STA COLOR
NIENU PLA
DLI RTI
COLOR DFB 4
TIMER DFB 0
DL DFB 112,112
DFB 112,112,112,112
DFB 112,112,112,112
DFB $4E
DFW PICTURE
DFB 14,14,14,14,14,14,14
DFB 14,14,14,14,14,14,14,14
DFB 14,14,14,14,14,14,14,14
DFB 14,14,14,14,14,14,14,14
DFB 14,14,14,14,14,14,14,14
DFB 14,14,14,14,14,14,14,14
DFB 14,14,14,14,14,14,14,14
DFB 14,14,14,14,14,14,14,14
DFB $41
DFW DL¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯