home *** CD-ROM | disk | FTP | other *** search
/ Tiger Disk 122 / Tiger_Disk_122_20xx_Tiger-Crew-Disk_de_Side_B.d64 / sprite-demo (.txt) < prev    next >
Commodore BASIC  |  2023-02-26  |  2KB  |  88 lines
  1. 10 gosub 5000
  2. 18 rem ----------  start  ----------
  3. 19 rem
  4. 20 print "dieses programm zeigt,"
  5. 30 print "wie sprites funktionieren."
  6. 40 print "und es zeigt dabei auch jeweils"
  7. 50 print "die aufgerufenen programmzeilen."
  8. 60 print:print
  9. 70 print "fertig?"
  10. 80 get a$:if a$="" then 80
  11. 90 print c$d$d$d$d$d$
  12. 95 rem
  13. 96 rem ------ lesen/ausfuehren -----
  14. 97 rem
  15. 100 for n=1 to 17
  16. 110 read x$,y$
  17. 120 printb$x$
  18. 130 printy$
  19. 140 print:print g$" cont"
  20. 145 printb$l$:print"tippe return-";
  21. 150 print"taste zur fortsetzung."
  22. 160 printl$g$u$u$u$u$u$u$u$u$u$u$
  23. 166 rem
  24. 167 rem naechste zeile holt eine return-
  25. 168 rem taste in den eingabepuffer
  26. 169 rem
  27. 170 poke 198,1 : poke 631,13
  28. 180 stop
  29. 190 printd$d$d$d$ : next n
  30. 195 printb$"ende des beispiels." : end
  31. 197 rem
  32. 198 rem ------- daten/befehle --------
  33. 199 rem
  34. 200 data"poke vc+21,1"
  35. 210 data"<sprite 0 einschalten>"
  36. 220 data"poke vc,24 : poke vc+1,50"
  37. 230 data"<bewegen nach x=24 und y=50>"
  38. 240 data"poke vc+39,7"
  39. 250 data"<spritefarbe gelb waehlen>"
  40. 260 data"poke 2040,255"
  41. 270 data"<sprite-zeiger setzen>"
  42. 280 data"poke vc+29,1"
  43. 290 data"<horizontal erweitern>"
  44. 300 data"poke vc+23,1"
  45. 310 data"<vertikal erweitern>"
  46. 320 data"for c=24 to 255:poke vc,c:next"
  47. 330 data"<sprite bewegen>"
  48. 340 data"poke vc+16,1 : poke vc,40"
  49. 350 data"<bewegen jenseits x=255>"
  50. 360 data"for c=50to208:pokevc+1,c:next"
  51. 370 data"<sprite vertikal bewegen>"
  52. 380 data"poke vc+16,0 : poke vc,150"
  53. 390 data"<zurueck , links von x=255>"
  54. 400 data"poke vc+27,1"
  55. 410 data"<hinter den video-text>"
  56. 420 data"poke vc+37,2"
  57. 430 data"rot waehlen als zusatzfarbe #1>"
  58. 440 data"poke vc+38,6"
  59. 450 data"<blau waehlen als zusatzfarbe #2>"
  60. 460 data"poke vc+28,1"
  61. 470 data"<schalten auf mehrfarbig>"
  62. 480 data"poke vc+29,0"
  63. 490 data"<schrumpfen horizontal>"
  64. 500 data"poke vc+23,0"
  65. 510 data"<schrumpfen vertikal>"
  66. 520 data"poke vc+21,0"
  67. 530 data"<sprite ausschalten>"
  68. 4997 rem
  69. 4998 rem -----  sprite aufstellen -----
  70. 4999 rem
  71. 5000 va=1024
  72. 5010 vc=53248
  73. 5040 l$="==================================="
  74. 5050 c$=chr$(147)
  75. 5060 b$=chr$(5)
  76. 5070 g$=chr$(155)
  77. 5080 u$=chr$(145)
  78. 5090 d$=chr$(17)
  79. 5100 poke 53280,12: poke 53281,15
  80. 5110 print b$c$;
  81. 5150 for n=16320 to 16331
  82. 5160 poke n,255 : poke n+111,255
  83. 5170 next n
  84. 5180 for n=16332 to 16368 step3
  85. 5190 poke n,245:poke n+1,66:poke n+2,175
  86. 5195 next n
  87. 5200 return
  88.