home *** CD-ROM | disk | FTP | other *** search
/ Tiger Disk 26 / Tiger_Disk_026_19xx_Tiger-Crew-Disk_de_Side_B.d64 / scratch-schutz (.txt) < prev    next >
Commodore BASIC  |  2023-02-26  |  1KB  |  52 lines
  1. 100 poke53280,3:poke53281,1:poke646,6
  2. 110 printchr$(147)+chr$(8)+chr$(142)
  3. 120 print" scratchschutz"
  4. 130 print:print" (c)  1985"
  5. 140 print:print" by henrysoft"
  6. 145 print:print" greetings to ksv"
  7. 150 print:print"  disk einlegen & space "
  8. 160 wait197,60:poke198,0
  9. 170 close15:open15,8,15,"i0":gosub560:ifer<>0then150
  10. 180 close8:open8,8,8,"#"
  11. 190 print#15,"u1:";8;0;18;1:print#15,"u2:";8;0;18;1:gosub560
  12. 200 ifer=26thenprint:print"  schreibschutz enfernen [146]":goto150
  13. 210 print:print:t=18:s=1
  14. 220 print#15,"u1:";8;0;t;s:gosub560
  15. 230 print#15,"b-p:";8;0
  16. 240 get#8,nt$,ns$
  17. 250 nt=0:ifnt$<>""thennt=asc(nt$)
  18. 260 ns=0:ifns$<>""thenns=asc(ns$)
  19. 270 forz=2to226step32
  20. 280 print#15,"b-p:";8;z+3
  21. 290 get#8,n$:ifn$=""then530
  22. 300 print#15,"b-p:";8;z
  23. 310 get#8,n$:ifn$=""then500
  24. 320 ifasc(n$)and128=0thengoto500
  25. 330 print#15,"b-p:";8;z+3
  26. 340 forzz=1to16:get#8,n$:printn$;:next:printtab(18);
  27. 350 print#15,"b-p:";8;z
  28. 360 get#8,n$:pt=asc(n$):ps=pt and64
  29. 370 ifps=0thenprint"   frei   [146]";
  30. 380 ifps=64thenprint"geschuetzt";
  31. 390 printtab(29);"schutz j/n"
  32. 400 poke198,0:wait198,1:getn$
  33. 410 ifn$="j"thenprinttab(29)"[145]   j a    [146]":goto460
  34. 420 ifn$="e"thenprint:goto530
  35. 430 ifn$="n"thenprinttab(29)"[145]   nein   [146]":goto470
  36. 440 ifn$=" "thenprinttab(29)"[145]unveraend.":goto500
  37. 450 goto400
  38. 460 pt=pt or64:goto480
  39. 470 pt=pt and(255-64)
  40. 480 print#15,"b-p:";8;z
  41. 490 print#8,chr$(pt);
  42. 500 nextz
  43. 510 print#15,"u2:";8;0;t;s:gosub560
  44. 520 ifnt<>0thent=nt:s=ns:goto220
  45. 530 print#15,"u2:";8;0;t;s:gosub560
  46. 540 close8:close15
  47. 550 print"ende.":end
  48. 560 input#15,er,er$,et,es
  49. 570 ifer=0orer=26thenreturn
  50. 580 print:print" disk-error";er;": ";er$;" ,";et;" ,";es
  51. 590 return
  52.