home *** CD-ROM | disk | FTP | other *** search
/ Mail Madness! 5 / Mail_Madness_05_19xx_-_Side_B.d64 / logadress (.txt) < prev    next >
Commodore BASIC  |  2023-02-26  |  11KB  |  299 lines
  1. 5 poke788,52
  2. 10 poke53280,0:poke53281,0:print"":open15,8,15:print#15,"i0":gosub10000
  3. 20 pu=2:fp=1:dk=0:l1=40:l2=30:l3=15:t=0
  4. 30 bz$(1)="satznummer..:":bz$(2)="name/vorname:":bz$(3)="strasse.....:"
  5. 40 bz$(4)="plz/ort.....:":bz$(5)="rufnummer...:":bz$(6)="codierung...:"
  6. 50 bl$="............[157][157][157][157][157][157][157][157][157][157][157][157][157][157]"
  7. 100 dim a$(501),a(501)
  8. 190 goto11000
  9. 200 print"[164][157]";
  10. 205 gett$:ift$=""then205
  11. 210 tt=asc(t$):iftt=20andtt$=""thent$="":goto205
  12. 215 iftt>13andtt<20ortt>20andtt<32ortt>96thent$="":goto205
  13. 220 iftt=95ortt=13thenprintchr$(32):return
  14. 225 iftt=34thent$="'"
  15. 230 iftt<>20thenprintt$;:tt$=tt$+t$:goto240
  16. 235 iftt=20thenprintt$;:tt$=left$(tt$,len(tt$)-1)
  17. 240 iflen(tt$)<llthen200
  18. 245 printchr$(32):return
  19. 1000 x$="":x=0:print"[147] 1-[146] diskette anlegen";spc(61);"2-[146] datei anlegen";spc(64);
  20. 1010 print"3-[146] menue"
  21. 1020 getx$:x=val(x$):ifx<1orx>3then1020
  22. 1030 ifx=1then1100
  23. 1040 ifx=2then1300
  24. 1050 ifx=3thenreturn
  25. 1060 goto1020
  26. 1100 print"[147]diskette anlegen:":input"diskette eingelegt  n[157][157][157]";x$
  27. 1110 ifx$<>"j"then1100
  28. 1120 input"diskettenname";d$:ifd$=""thenprint"[145][145][145]":goto1120
  29. 1130 input"diskettennummer";dn$:dn=val(dn$):ifdn<1ord>9thenprint"[145][145][145]":goto1130
  30. 1140 input"angaben richtig  n[157][157][157]";x$:ifx$<>"j"thenprint"[145][145][145][145][145][145][145]":goto1120
  31. 1150 print#15,"n0:"+d$+","+dn$
  32. 1160 goto1000
  33. 1300 print"[147]datei anlegen:":input"diskette fuer seq. datei eingelegt  n[157][157][157]";x$
  34. 1310 ifx$<>"j"then1300
  35. 1320 print"":forx=1to6:printbz$(x):next
  36. 1330 forx=7to10
  37. 1340 printbl$;:inputbz$(x)
  38. 1350 iflen(bz$(x))>12thenprint"[145][145]":fory=1tolen(bz$(x)):print" ";:next:
  39. 1360 iflen(bz$(x))>12thenprint"[145]":bz$(x)="":goto1340
  40. 1370 ifleft$(bz$(x),1)="."thenprint"[145][145]":goto1340
  41. 1380 bz$(x)=bz$(x)+":":print"[145]";bz$(x):next
  42. 1390 print"[147]";:forx=1to10:printbz$(x):next:input"angaben korrekt  j[157][157][157]";x$:ifx$="j"then1500
  43. 1400 input"welche bezeichnung 7-10";x$:x=val(x$)
  44. 1410 ifx<7orx>10thenprint"[145][145][145]":goto1400
  45. 1420 printbz$(x)
  46. 1430 printbl$;:inputbz$(x)
  47. 1440 iflen(bz$(x))>12thenprint"[145][145]":fory=1tolen(bz$(x)):print" ";:next:
  48. 1450 iflen(bz$(x))>12thenprint"[145]":bz$(x)="":goto1430
  49. 1460 ifleft$(bz$(x),1)="."thenprint"[145][145]":goto1430
  50. 1470 bz$(x)=bz$(x)+":":print"[145]";bz$(x):goto1390
  51. 1500 print"[147]geben sie nun den dateinamen ein:":d$=""
  52. 1510 input"dateinamen:";d$:dd$="@:"+d$+"s,w":print#15,"i0":open3,8,3,dd$:gosub10000
  53. 1520 forx=1to500
  54. 1540 a$(x)="^":a(x)=x:nextx:t=0:print#3,t
  55. 1550 forx=7to10:print#3,chr$(34);bz$(x):next
  56. 1560 forx=1to500:print#3,a$(x):print#3,a(x):print"";x:next
  57. 1570 gosub10000:close3:return
  58. 2000 print"[147]datei einlesen:[146]";spc(65);"_[146] =menue";spc(72)
  59. 2010 input"diskette mit indexdatei eingelegt  n[157][157][157]";x$:print""
  60. 2020 ifx$="_"thenreturn
  61. 2030 ifx$<>"j"then2000
  62. 2040 input"dateiname";d$:dd$=d$+"s,r":open3,8,3,dd$:gosub10000:input#3,t
  63. 2045 ify=62thenclose3:print"[145][145][145][145][145]":goto2040
  64. 2050 forx=7to10:input#3,bz$(x):next:print"";t;"":forx=1to10:printbz$(x):next
  65. 2055 print"datei ";d$;"[146] wird eingelesen.[145][145][145]"
  66. 2060 forx=1to500:input#3,a$(x):input#3,a(x):next
  67. 2070 gosub10000:close3:return
  68. 3000 print"[147]indexdatei speichern:[146]";spc(59);"_[146] =menue/end"
  69. 3010 input"indexdiskette eingelegt  n[157][157][157]";x$:ifx$="_"thenreturn
  70. 3020 ifx$<>"j"then3000
  71. 3030 input"dateinamen:";d$:input"dateinamen korrekt  j[157][157][157]";x$
  72. 3040 ifx$="n"thenprint"[145][145][145][145][145]":goto3030
  73. 3050 dd$=d$+"s,w":open3,8,3,dd$:gosub10000:ify<>0thengoto3100
  74. 3060 print#3,t:forx=7to10:print#3,chr$(34);bz$(x):next
  75. 3070 forx=1to500:print#3,chr$(34);a$(x):print#3,a(x):next:close3:gosub10000:return
  76. 3100 close3:input"datei ueberschreiben  j[157][157][157]";x$
  77. 3110 ifx$="n"then3000
  78. 3120 dd$="@:"+d$+"s,w":open3,8,3,dd$:goto3060
  79. 4000 print"[147]daten eingeben:[146]";spc(65);"_[146] = menue"
  80. 4010 input"datendiskette eingelegt  n[157][157][157]";x$:ifx$="_"thenreturn
  81. 4015 ifx$<>"j"then4000
  82. 4020 ifa$(1)=""thenreturn
  83. 4030 forx=1to500:ifa$(x)="^"then4100
  84. 4035 next
  85. 4040 print"kein datensatz mehr frei":forx=1to1000:next:return
  86. 4100 print"[147][213][192][192][192][192][192][192][192][192][178][192][192][192][192][192][192][192][192][192][178][192][192][192][192][192][192][192][192][192][178][192][192][192][192][192][192][192][192][192][201]";
  87. 4101 print "[221]        10        20        30        [194]";
  88. 4102 print"[202][192][192][192][192][192][192][192][192][177][192][192][192][192][192][192][192][192][192][177][192][192][192][192][192][192][192][192][192][177][192][192][192][192][192][192][192][192][192][203]"
  89. 4105 r=a(x):print"";bz$(1);r;"[146]"
  90. 4110 printbz$(2),l1:ll=l1:gosub200:ad$(1)=tt$:tt$=""
  91. 4115 ifad$(1)=""thenad$(1)="---"
  92. 4120 print"[145][145]":printbz$(3);l2:ll=l2:gosub200:ad$(2)=tt$:tt$=""
  93. 4125 ifad$(2)=""thenad$(2)="---"
  94. 4130 print"[145][145]":printbz$(4),l2:ll=l2:gosub200:ad$(3)=tt$:tt$=""
  95. 4135 ifad$(3)=""thenad$(3)="---"
  96. 4140 print"[145][145]":printbz$(5),l3:ll=l3:gosub200:ad$(4)=tt$:tt$=""
  97. 4145 ifad$(4)=""thenad$(4)="---"
  98. 4150 print"[145][145]":printbz$(6),l3:ll=l3:gosub200:ad$(5)=tt$:tt$=""
  99. 4155 ifad$(5)=""thenad$(5)="---"
  100. 4160 print"[145][145]":printbz$(7),l2:ll=l2:gosub200:ad$(6)=tt$:tt$=""
  101. 4165 ifad$(6)=""thenad$(6)="---"
  102. 4170 print"[145][145]":printbz$(8),l2:ll=l2:gosub200:ad$(7)=tt$:tt$=""
  103. 4175 ifad$(7)=""thenad$(7)="---"
  104. 4180 print"[145][145]":printbz$(9),l2:ll=l2:gosub200:ad$(8)=tt$:tt$=""
  105. 4185 ifad$(8)=""thenad$(8)="---"
  106. 4190 print"[145][145]":printbz$(10),l2:ll=l2:gosub200:ad$(9)=tt$:tt$=""
  107. 4195 ifad$(9)=""thenad$(9)="---"
  108. 4200 input"eingabe korrekt  j[157][157][157]";x$:ifx$="j"then4210
  109. 4205 ifx$="n"thengosub10700:q=1:gosub5200
  110. 4210 t=t+1:a$(x)=ad$(1):open2,8,2,"#":gosub10200:close2
  111. 4220 input"neue eingabe (j/n)[146]  j[157][157][157]";x$:ifx$="n"thenreturn
  112. 4230 ifx$="j"then4035
  113. 4240 print"[145]";:goto4220
  114. 5000 input"[147]datendiskette eingelegt (_[146] = menue)  n[157][157][157]";x$:ifx$="_"thenreturn
  115. 5005 ifx$<>"j"then5000
  116. 5010 print"welcher satz soll gesucht werden?       _[146]=menue":z=0
  117. 5015 input"";s$:ifs$="_"then return
  118. 5020 fory=1tot:ifleft$(a$(y),len(s$))=s$thenz=y:goto5100
  119. 5030 nexty:print"datensatz nicht mehr im speicher":forx=1to1000:next:goto5000
  120. 5100 r=a(y):open2,8,2,"#":gosub10100:gosub10700
  121. 5120 print"a[146]endern      l[146]oeschen      _[146]neuer satz         w[146]eitersuchen"
  122. 5130 getx$:ifx$=""then5130
  123. 5140 ifx$="a"thengosub5200:close2:goto5100
  124. 5150 ifx$="l"then5300
  125. 5160 ifx$="_"thenclose2:goto5000
  126. 5170 ifx$="w"thenclose2:y=z:goto5030
  127. 5180 goto5130
  128. 5200 print"welches feld soll geaendert werden?"
  129. 5205 inputz$:a=val(z$):ifa<1ora>9thenprint"[145][145]":goto5210
  130. 5210 ll=30:ifa=1thenll=l1
  131. 5215 ifa=4ora=5thenll=15
  132. 5220 printad$(a);"":gosub200:ad$(a)=tt$:tt$="":ifad$(a)=""thenad$(a)="---"
  133. 5230 input"weitere aenderungen  n[157][157][157]";z$
  134. 5233 ifz$="n"andq=1thenreturn
  135. 5235 ifz$="n"thengosub10200:return
  136. 5240 ifz$="j"thengosub10700:goto5200
  137. 5300 close2:forgy=1to9:ad$(gy)="@@@@@@":next:open2,8,2,"#":gosub10200:close2
  138. 5310 ifz=tthena$(t)="^":t=t-1:goto5010
  139. 5320 forx=ztot-1:a(x)=a(x+1):a$(x)=a$(x+1):next:a$(t)="^":a(t)=t:t=t-1
  140. 5330 goto5010
  141. 6000 input"[147]datendiskette eingelegt  n[157][157][157]";x$:ifx$="_"thenreturn
  142. 6003 ifx$<>"j"then6000
  143. 6005 print"[147]datenausgaben:[146]";spc(67);"1-[146] uebersicht indexdatei";spc(56);
  144. 6010 print"2-[146] daten bearbeiten";spc(61);"3-[146] gesamtausdruck";spc(63);
  145. 6020 print"4-[146] gesamtausdruck nach suchbegr.";spc(48);"5-[146] adressaufkleber";
  146. 6030 printspc(62);"6-[146] adressaufkl. nach suchbegr.";spc(50);
  147. 6035 print"7-[146] ausdruck nach plz";spc(60);"8-[146] menue";spc(121);"waehle 1-8[146]"
  148. 6040 getx$:x=val(x$):ifx<1orx>8then6040
  149. 6050 ifx=8thenreturn
  150. 6060 onxgoto6100,6200,6300,6400,6500,6600,6700
  151. 6100 print"[147]uebersicht:[146]"
  152. 6110 forx=1tot:printa(x);" ";tab(7);a$(x)
  153. 6120 ifx/15=int(x/15)theninput"'return'[146]";x$:print"[147]uebersicht:[146]"
  154. 6130 next:input"'return'[146]";x$:goto6005
  155. 6140 next:goto6005
  156. 6200 z=1:r=a(z):open2,8,2,"#"
  157. 6210 gosub10100:gosub10700
  158. 6220 print"a[146]endern    d[146]rucken   +[146]vor-  -[146]zurueck-   ";
  159. 6223 print">[146] 10 vor-  <[146] 10 zurueckbl.  _[146] ende[145][145]"
  160. 6225 getx$:ifx$=""then6225
  161. 6230 ifx$="a"thengosub5200:goto6210
  162. 6240 ifx$="d"thengosub10500:goto6210
  163. 6245 ifx$="+"thenz=z+1:ifz>tthenz=t
  164. 6250 ifx$="+"thenr=a(z):goto6210
  165. 6255 ifx$="-"thenz=z-1:ifz<1thenz=1
  166. 6260 ifx$="-"thenr=a(z):goto6210
  167. 6265 ifx$=">"thenz=z+10:ifz>tthenz=t
  168. 6270 ifx$=">"thenr=a(z):goto6210
  169. 6275 ifx$="<"thenz=z-10:ifz<1thenz=1
  170. 6280 ifx$="<"thenr=a(z):goto6210
  171. 6285 ifx$="_"thenclose2:goto6005
  172. 6290 goto6225
  173. 6300 print"[147]gesamtausdruck aller daten:":open2,8,2,"#":forx=1tot:print"";x:r=a(x)
  174. 6310 gosub10100:gosub10500:ifx/6=int(x/6)thenopen1,4,1:print#1,chr$(12):close1
  175. 6320 ifx/30=int(x/30)theninput"'return'[146]";x$
  176. 6330 next:close2:goto6005
  177. 6400 print"[147]gesamtausdruck nach code:":input"geben sie code ein";cd$:gosub10700
  178. 6405 input"suchfeld";yy:ifyy<1oryy>9thenprint"[145][145][145]":goto6405
  179. 6410 ifcd$=""then6400
  180. 6420 print"[147]":xx=0:open2,8,2,"#":forx=1tot:print"";x:r=a(x):gosub10100
  181. 6430 forz=1tolen(ad$(yy))-len(cd$)+1
  182. 6440 ifmid$(ad$(yy),z,len(cd$))=cd$thengosub10700:gosub10500:xx=xx+1
  183. 6450 nextz:ifxx/6=int(xx/6)andxx>0thenopen7,4,1:print#7,chr$(12)
  184. 6460 nextx:close2:goto6005
  185. 6500 print"[147]gesamtausdruck aller adressen:":open2,8,2,"#":forx=1tot
  186. 6510 print"";x:r=a(x):gosub10100:gosub10600:next:close2:goto6005
  187. 6600 print"[147]gesamtausdruck nach code:":input"geben sie code ein";cd$:gosub10700
  188. 6605 input"suchfeld";yy:ifyy<1oryy>9thenprint"[145][145][145]":goto6605
  189. 6610 ifcd$=""then6600
  190. 6620 print"[147]":open2,8,2,"#":forx=1tot:print"";x:r=a(x):gosub10100
  191. 6630 forz=1tolen(ad$(yy))-len(cd$)+1
  192. 6640 ifmid$(ad$(yy),z,len(cd$))=cd$thengosub10700:gosub10600
  193. 6650 nextz:nextx:close2:goto6005
  194. 6700 print"[147]ausgabe eines postleitzahlenbereiches:"
  195. 6710 print"geben sie a[146] fuer adressaufkleber oder   g[146] fuer gesamtausdruck ein."
  196. 6715 getst$:ifst$="a"orst$="g"then6725
  197. 6720 goto6715
  198. 6725 input"kleinere plz:";pk$:pk=val(pk$):ifpk<10000orpk>99999thenprint"[145]";:goto6725
  199. 6727 print""
  200. 6730 input"groessere plz:";pg$:pg=val(pg$):ifpk<10000orpk>99999thenprint"[145]";:goto6730
  201. 6735 forx=1tot:r=a(x):open2,8,2,"#":gosub10100:close2
  202. 6740 ifval(left$(ad$(3),5))>=pkandval(left$(ad$(3),5))<=pgthen6750
  203. 6745 nextx:return
  204. 6750 ifst$="a"thengosub10600:goto6745
  205. 6755 ifst$="g"thengosub10500:goto6745
  206. 7000 print"[147] 1-[146] indexdatei anlegen":print" 2-[146] indexdatei sortieren"
  207. 7010 print" 3-[146] menue"
  208. 7020 getx$:x=val(x$):ifx<1orx>3then7020
  209. 7030 ifx=1then7100
  210. 7040 ifx=2thenprint" 2.[146]":goto7300
  211. 7050 ifx=3thenreturn
  212. 7060 goto7020
  213. 7100 input"[147]datendiskette eingelegt  n[157][157][157]";x$:ifx$<>"j"then7100
  214. 7110 ifx$="_"thenreturn
  215. 7120 print"":forx=2to10:printx-1;"";bz$(x):next
  216. 7130 print"   nach welchem feld soll indexdatei       angelegt werden?"
  217. 7140 getx$:x=val(x$):ifx<1orx>9then7140
  218. 7150 printx:open2,8,2,"#":forz=1tot:r=a(z):gosub10100:a$(z)=ad$(x):next
  219. 7160 close2:return
  220. 7300 m=t
  221. 7305 m=int(m/2)
  222. 7310 ifm=0then7370
  223. 7315 j=1:k=t-m
  224. 7320 i=j
  225. 7325 l=i+m
  226. 7330 ifa$(i)<a$(l)then7355
  227. 7335 gosub7500
  228. 7340 i=i-m
  229. 7345 ifi<1then7355
  230. 7350 goto7325
  231. 7355 j=j+1
  232. 7360 ifj>kthen7305
  233. 7365 goto7320
  234. 7370 i=0:j=0:k=0:l=0:m=0:return
  235. 7500 a$(0)=a$(i):a(0)=a(i):a$(i)=a$(l):a(i)=a(l):a$(l)=a$(0):a(l)=a(0):return
  236. 8000 print"[147]backup:[146] ":print"1-[146] diskette/kassette":print"2-[146] kassette/diskette"
  237. 8010 print"3-[146] menue"
  238. 8020 getx$:x=val(x$):ifx<1orx>3then8020
  239. 8030 ifx=3thenreturn
  240. 8040 onxgoto8100,8200
  241. 8050 goto8020
  242. 8100 input"[147]datendiskette eingelegt  n[157][157][157]";x$:ifx$<>"j"then8100
  243. 8105 input"kassette eingelegt  n[157][157][157]";x$:ifx$="n"thenprint"[145][145][145]":goto8105
  244. 8110 input"kassettendateiname:";kn$:open1,1,1,kn$:open2,8,2,"#"
  245. 8120 forx=1tot:r=a(x):gosub10100:print#1,r:fory=1to9:print#1,ad$(y):next:next
  246. 8130 close1:close2:return
  247. 8200 input"[147]datendiskette eingelegt  n[157][157][157]";x$:ifx$="n"then8200
  248. 8205 input"kassette eingelegt  n[157][157][157]";x$:ifx$="n"thenprint"[145][145][145]":goto8205
  249. 8210 input"kassettendateiname:";kn$:open1,1,0,kn$:open2,8,2,"#"
  250. 8220 forx=1tot:input#1,r:fory=1to9:input#1,ad$(y):next:gosub10200:next
  251. 8230 close1:close2:return
  252. 9000 print"[147]sie haben end[146] gewaehlt, ist":input"indexdatei[146] gespeichert  n[157][157][157]";x$
  253. 9010 ifx$<>"j"thengosub3000
  254. 9020 clr:print"[147]";:end
  255. 10000 input#15,y,y$,v$,w$:ify<>0thenprinty,y$,v$,w$:input"fortsetzen mit 'return'[146]";x$
  256. 10010 return
  257. 10100 gosub10300:print#15,"u1:";pu;dk;rt;rs:print#15,"b-p:";pu;fp
  258. 10105 forg=1to9:ad$(g)="":next
  259. 10110 gosub10000:forg=1to9:input#pu,ad$(g):next:return
  260. 10200 gosub10300:print#15,"b-p:";pu;fp:forgy=1to9:print#pu,chr$(34);ad$(gy);chr$(13);
  261. 10205 next
  262. 10210 print#15,"u2:";pu;dk;rt;rs:gosub10000:fory=1to9:ad$(y)="":next
  263. 10220 return
  264. 10300 ifr<358thenr1=0:r2=22:r3=1:goto10330
  265. 10310 ifr>357andr<472thenr1=357:r2=20:r3=19:goto10330
  266. 10320 ifr>471thenr1=471:r2=19:r3=25
  267. 10330 rt=int(((r-r1)-1)/(r2-1))+r3
  268. 10340 rs=r-r1-(rt-r3)*r2+(rt-r3-1)
  269. 10350 return
  270. 10500 open7,4,1:open8,4,0:print#7,chr$(27);chr$(68);chr$(15);chr$(0);
  271. 10510 fory=1to9:print#8,bz$(y+1);:print#7,chr$(9);:print#8,ad$(y):next
  272. 10520 fory=1to4:print#8,"--------------------";:next:print#8::close7:close8:return
  273. 10600 open7,4,0:ifmid$(ad$(5),2,1)="f"thenprint#7,"firma":goto10685
  274. 10610 ifmid$(ad$(5),2,1)="w"thenprint#7,"frau":goto10640
  275. 10620 ifmid$(ad$(5),2,1)="m"then print#7,"herrn":goto10640
  276. 10630 print#7,"frau/herrn"
  277. 10640 fory=1tolen(ad$(1)):ifmid$(ad$(1),y,1)="/"thenl$=left$(ad$(1),y-1)
  278. 10645 fory=1tolen(ad$(1)):ifmid$(ad$(1),y,1)="/"thenl$=left$(ad$(1),y-1)
  279. 10650 ifmid$(ad$(1),y,1)="/"thenr$=right$(ad$(1),len(ad$(1))-y)
  280. 10660 ifmid$(ad$(1),y,1)="/"thend$=ad$(1):ad$(1)=r$+" "+l$
  281. 10670 nexty:print#7,ad$(1):ifmid$(d$,y,1)="/"thenad$(1)=d$
  282. 10680 print#7,ad$(2):print#7:print#7,ad$(3):print#7:print#7:print#7:print#7:close7:return
  283. 10685 print#7,ad$(1):ifleft$(ad$(5),1)="@"thenprint#7,"z. hd.: ";ad$(6):fl=1
  284. 10690 print#7,ad$(2):iffl=0thenprint#7
  285. 10695 print#7,ad$(3):print#7:print#7:print#7:print#7:close7:fl=0:return
  286. 10700 print"[147]";bz$(1);r;""
  287. 10710 form=2to10:print"";m-1;bz$(m);"[146] ";ad$(m-1):next:return
  288. 11000 print"[147]logadress 64[146]";spc(77);"menue:";spc(34);"[183][183][183][183][183][183]";spc(66);
  289. 11010 print"1-[146] diskette formatieren/datei anlegen";spc(43);
  290. 11020 print"2-[146] datei einlesen";spc(63);"3-[146] datei speichern";spc(62);
  291. 11030 print"4-[146] daten eingeben";spc(63);"5-[146] daten suchen/aendern/loeschen";
  292. 11040 printspc(48);"6-[146] datenausgabe (bildschirm/drucker)";spc(44);
  293. 11050 print"7-[146] indexdateien anlegen/sortieren";spc(47);
  294. 11060 print"8-[146] backup auf/von kassette";spc(54);"9-[146] end";spc(84);
  295. 11070 print"waehle 1-9[146]"
  296. 11080 getx$:x=val(x$):ifx<1orx>9then11080
  297. 11090 onxgosub1000,2000,3000,4000,5000,6000,7000,8000,9000
  298. 11100 x$="":x=0:q=0:goto11000
  299.