home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware 1 2 the Maxx
/
sw_1.zip
/
sw_1
/
UTILS
/
TBSCAN33.ZIP
/
TBS.BAT
< prev
next >
Wrap
DOS Batch File
|
1992-03-10
|
3KB
|
94 lines
@echo off
rem This is an example TbScan invokation batch file.
rem You may edit this file to suit your needs.
rem There are three default scan mnemonics defined:
rem 'quick', 'daily' and 'monthly'.
rem You can invoke a daily scan session with:
rem TBS daily
rem You can optionally specify additional options like:
rem TBS daily -quick
rem The same applies to 'monthly' and 'quick'.
rem If the user does not specify any option a help file will be
rem displayed.
rem If the user specifies a non recognised option, TbScan will be
rem invoked with that option. If TbScan does not recognise the option
rem too, it will abort with an errorlevel, and the help info will
rem be displayed anyway.
rem If TbScan detects a virus, an informative text will be displayed.
if '%1'=='quick' goto quick
if '%1'=='QUICK' goto quick
if '%1'=='daily' goto daily
if '%1'=='DAILY' goto daily
if '%1'=='monthly' goto monthly
if '%1'=='MONTHLY' goto monthly
if '%1'=='' goto help
TbScan %1 %2 %3 %4 %5 %6 %7 %8 %9
if errorlevel 2 goto virus
if errorlevel 1 goto help
goto end
:quick
rem Scan only the DOS directories and make no log file.
rem If TbScan detects a virus a daily scan session will be performed
rem automatically.
TbScan c:\bin c:\dos c:\system -quick %2 %3 %4 %5 %6 %7 %9
if errorlevel 2 goto daily
if errorlevel 1 goto help
goto end
:daily
rem Scan drive C completely and add information to the log file.
TbScan c:\ -log %2 %3 %4 %5 %6 %7 %8 %9
if errorlevel 2 goto virus
if errorlevel 1 goto help
goto end
:monthly
rem Scan drive C completely using -analyze and make a new log file.
TbScan c:\ -session -analyze %2 %3 %4 %5 %6 %7 %8 %9
if errorlevel 2 goto virus
if errorlevel 1 goto help
goto end
:virus
rem TbScan detected a virus. Lock the system and urge the user to
rem contact the help desk.
rem Of course you can also type a file or even start a specific
rem program here.
cls
echo -
echo WARNING!!!
echo TbScan detected one or more viruses!
echo -
echo Do NOT use this machine anymore,
echo and contact the security officer immediately!
echo -
echo You can also phone ESaSS for technical support: +31-80-787881
echo -
:loop
goto loop
:help
rem The user entered an illegal option. Give him/her some support.
echo -
echo Command line error detected or no options/scan path specified!
echo -
echo The following batch file options are available:
echo TBS quick Performs a quick scan on the system directories
echo TBS daily Invoke the daily scan session and add info to the log file
echo TBS monthly Invoke the monthly analyze session and clear the log file
echo -
echo Additional options may be specified. Consult the TbScan manual or:
pause
TbScan -help
:end