home *** CD-ROM | disk | FTP | other *** search
/ PC World Komputer 1998 May / Pcwk5b98.iso / Borland / Cplus45 / BC45 / START16.PAK / C0D.ASM < prev    next >
Assembly Source File  |  1995-08-29  |  15KB  |  427 lines
  1. ;[]------------------------------------------------------------[]
  2. ;|      C0D.ASM -- Start Up Code For Windows DLLs               |
  3. ;[]------------------------------------------------------------[]
  4.  
  5. ;
  6. ;       C/C++ Run Time Library - Version 6.5
  7. ; 
  8. ;       Copyright (c) 1991, 1994 by Borland International
  9. ;       All Rights Reserved.
  10. ; 
  11.  
  12.                 locals
  13.  
  14.                 __C0__ = 1
  15. include         RULES.ASI
  16.  
  17.                 ASSUME CS:_TEXT, DS:DGROUP
  18.  
  19.                 public  __acrtused              ;satisfy MS for now
  20. __acrtused      equ     0
  21.  
  22.  
  23.                 extrn LIBMAIN:far       ;the C routine to be called
  24.                 extrn LOCALINIT:far     ;Windows heap init routine
  25.                 extrn LOCKSEGMENT:far
  26.                 extrn UNLOCKSEGMENT:far
  27.                 extrn GETWINFLAGS:far
  28.                 extrn __WEP:far
  29.                 extrn __cexit:DIST
  30. ifdef    __LARGE__
  31. ifndef    _BUILDRTLDLL
  32.                 extrn FREELIBRARY:far
  33.                 extrn __LockDLL:DIST
  34. endif
  35. endif
  36.                 extrn __setupio:near    ;required!
  37.  
  38.                 public LibEntry         ;Entry point for the DLL
  39.                 publicdll WEP
  40.  
  41. NULL            segment
  42.                 db      16 dup (0)              ;Windows
  43.                 db       4 dup (0)              ;destructor count
  44.                 db       2 dup (0)              ;exception list
  45.                 db       4 dup (0)              ;exception vptr
  46.                 db       6 dup (0)              ;reserved
  47.                 db       2 dup (0)              ;VBX control jump vector
  48.                                                 ;MUST be at SS:20h
  49.                 db       2 dup (0)              ;reserved
  50.                 ends
  51.  
  52. _CVTSEG         segment
  53.                 public __RealCvtVector
  54. __RealCvtVector label word
  55.                 ends
  56.  
  57. _SCNSEG         segment
  58.                 public __ScanTodVector
  59. __ScanTodVector label word
  60.                 ends
  61.  
  62. _FPSEG          segment
  63.                 public __FPVector
  64. __FPVector      dd      0
  65.                 ends
  66.  
  67. _DATA           segment
  68.                 public _errno
  69. _errno          dw      0
  70.                 public __protected
  71. __protected     dw      0
  72.                 public __8086
  73. __8086          dw      0
  74.                 public __8087
  75. __8087          dw      0
  76.                 public __version
  77. __version       label word
  78.                 public __osversion
  79. __osversion     label word
  80.                 public __osmajor
  81. __osmajor       db      0
  82.                 public __osminor
  83. __osminor       db      0
  84.                 public __osmode         ;Used for OS/2 protected mode by MS,
  85. __osmode        db      0               ;currently set to 0 under Windows
  86.                 public __hInstance
  87. __hInstance     dw      0
  88.                 public __WinAllocFlag   ;Used by malloc for additional flags
  89. __WinAllocFlag  dw      2000h           ;to pass to GlobalAlloc (used in DLLs)
  90.                                         ;default value is GMEM_SHARE
  91.                 public __LockWIN87EM    ;Used do lock down WIN87EM to avoid
  92. __LockWIN87EM   dw      1               ;DLL unload ordering problem
  93.  
  94. ifdef    __LARGE__
  95. ifndef    _BUILDRTLDLL
  96.                 public __LockRTLHandle
  97. __LockRTLHandle dw      0               ;Handle of RTLDLL (locked)
  98. endif
  99. endif
  100.  
  101.             public  __abend
  102. __abend        label   word
  103. _abend          dw      1               ;If LibEntry is called gets set to
  104.                                         ;normal state (0).  If it is 1 then
  105.                                         ;exit routines are not performed
  106.                                         ;Gets set to 1 if DLL is terminated
  107.                                         ;by a call to abort() or _exit().
  108.  
  109. CopyRight       db      'Borland C++ - Copyright 1994 Borland Intl.',0
  110.                 ends
  111.  
  112. _TEXT           segment
  113.  
  114. LibEntry        proc far
  115.                 mov     __hInstance, di ;save SI and DI
  116.                 push    si
  117.  
  118.                 push    di              ;handle of the module instance
  119.                 push    ds              ;library data segment
  120.                 push    cx              ;heap size
  121.                 push    es              ;command line segment
  122.                 push    si              ;command line offset
  123.  
  124.                 ;if we have some heap then initialize it
  125.                 jcxz    @@Init          ;jump if no heap specified
  126.  
  127.                 ;call the Windows function LocalInit() to set up the heap
  128.                 ;LocalInit((LPSTR)start, WORD cbHeap);
  129.  
  130.                 push    ds              ;Heap segment
  131.                 xor     ax,ax
  132.                 push    ax              ;Heap start offset in segment
  133.                 push    cx              ;Heap end offset in segment
  134.                 call    LOCALINIT
  135.                 xchg    ax,cx
  136.                 jcxz    @@JmpExit       ;quit if it failed
  137.                 jmp     short @@Init
  138. @@JmpExit:      jmp     @@Exit
  139.  
  140. @@Init:
  141.  
  142. IF LDATA EQ false
  143.                 mov     ax,-1
  144.                 push    ax
  145.                 call    LOCKSEGMENT
  146. ENDIF
  147.  
  148.                 ;Clear _BSS, uninitialized data area
  149.  
  150.                 xor     ax, ax
  151.                 push    ds
  152.                 pop     es
  153.                 mov     di,offset DGROUP:BeginBSS
  154.                 mov     cx,offset DGROUP:EndBSS
  155.                 sub     cx,di
  156.                 cld
  157.                 rep
  158.                 stosb
  159.  
  160. ;Determine DOS version
  161.  
  162.                 mov     ah, 30h
  163.                 int     21h
  164.                 mov     __version, ax   ; save minor and major revision
  165.  
  166. ;Determine whether we are in protected mode
  167.  
  168.                 call    GETWINFLAGS
  169.                 test    ax,1            ; WF_PMODE = 1
  170.                 jz      @@realmode      ; Note:  GETWINFLAGS returns a long,
  171.                                         ; so if WF_PMODE changed it could be
  172.                                         ; in the high word.
  173.                 mov     __protected, 8  ; Eight is for convenience.
  174. @@realmode:
  175.  
  176. ;Test for 8087 presence
  177.  
  178.                 test    ax,0400h        ; WF_8087 = 0x0400
  179.                 jz      @@no8087
  180.                 mov     __8087, 1
  181. @@no8087:
  182.                 and     ax,08h+04h+02h  ; WF_CPU486|WF_CPU386|WF_CPU286 
  183.                 shr     ax,1            ; Convert to 4 or 2 or 1 or 0
  184.                 test    ax,0004h        ; Have 4, 486 done
  185.                 jnz     @@NoAdjust
  186.                 or      ax,ax           ; Have 0, 8086 done
  187.                 jz      @@NoAdjust      
  188.                 inc     ax              ; Have 2 or 1, need 3 or 2
  189. @@NoAdjust:
  190.                 mov     __8086,ax       ; Set CPU Type
  191.  
  192. ;Call our initialization functions, including C++ static constructors.
  193.  
  194.                 mov     ax,ds
  195.                 mov     es,ax
  196.                 mov     si,offset DGROUP:InitStart      ;si = start of table
  197.                 mov     di,offset DGROUP:InitEnd        ;di = end of table
  198.  
  199.                 call    Initialize
  200.                 mov     _abend, 0                       ; Set LibEntry called
  201.  
  202.                 ;invoke the C routine to do any special initialization
  203. @@Main:         call    LIBMAIN         ;invoke the 'C' routine (result in AX)
  204.                 or  ax, ax
  205.  
  206. ifdef    __LARGE__
  207. ifndef    _BUILDRTLDLL
  208.                 jz  @@LibMainRet
  209.  
  210.                 push    ax
  211.                 call    __LockDLL
  212.                 mov __LockRTLHandle, ax
  213.                 pop ax
  214. @@LibMainRet:
  215. endif
  216. endif
  217.                 mov     di, __hInstance ;restore SI and DI
  218.                 pop     si
  219.                 ret
  220.  
  221. @@Exit:         mov ax, 0               ;set return code
  222.                 pop si                  ;remove arguments to LIBMAIN
  223.                 pop es                  ;  since we didn't call it.
  224.                 pop cx
  225.                 pop ds
  226.                 pop di
  227.                 pop si                  ;restore saved SI.  DI is restored
  228.                 ret                     ;  by removing arguments to LIBMAIN
  229.                 endp
  230.  
  231. ;---------------------------------------------------------------------------
  232. ;       _cleanup()      call all #pragma exit cleanup routines.
  233. ;       _checknull()    check for null pointer zapping copyright message
  234. ;       _terminate(exitcode, quick)     exit program with error code
  235. ;       _restorezero()  restore interrupt vectors
  236. ;
  237. ;       These functions are called by exit(), _exit(), _cexit(),
  238. ;       and _c_exit().
  239. ;---------------------------------------------------------------------------
  240.  
  241. ;       Call cleanup routines
  242.  
  243. __cleanup       PROC    DIST
  244.                 PUBLIC  __cleanup
  245.  
  246.                 mov     ax,ds
  247.                 mov     es,ax
  248.                 push    si
  249.                 push    di
  250.                 mov     si,offset DGROUP:ExitStart
  251.                 mov     di,offset DGROUP:ExitEnd
  252.                 call    Cleanup
  253.                 pop     di
  254.                 pop     si
  255.                 ret
  256. __cleanup       ENDP
  257.  
  258. ;       Check for null pointers before exit.  NO-OP on Windows.
  259.  
  260. __checknull     PROC    DIST
  261.                 PUBLIC  __checknull
  262.                 ret
  263. __checknull     ENDP
  264.  
  265. ;       Restore grabbed interrupt vectors.  NO-OP on Windows.
  266.  
  267. __restorezero     PROC    DIST
  268.                 PUBLIC  __restorezero
  269.                 ret
  270. __restorezero     ENDP
  271.  
  272. ;       Exit to DOS
  273. ;
  274. ; Usage:        void _terminate(int exitcode, int quick);
  275.  
  276. __terminate     PROC    DIST
  277.                 PUBLIC  __terminate
  278.  
  279.                 mov     bp,sp
  280.                 mov     al,[bp+cPtrSize]        ; get exitcode
  281.                 mov     ah,4ch
  282.                 int     21h
  283.                 ret
  284.                 endp
  285.  
  286. WEP             proc    windows pascal far nParam:WORD
  287.                 push    si
  288.                 push    di
  289.  
  290.                 cmp     _abend, 0
  291.                 jne     @@error
  292.                 push    nParam
  293.                 call    __WEP
  294.                 push    ax
  295.                 call    __cexit         ; perform cleanup without exiting
  296.  
  297. @@unlock:
  298.  
  299. ifdef    __LARGE__
  300. ifndef    _BUILDRTLDLL
  301.         mov    ax, __LockRTLHandle
  302.         or    ax, ax
  303.         jz    @@RTLNotLocked
  304.         push    ax
  305.         call    FreeLibrary
  306. @@RTLNotLocked:
  307. endif
  308. endif
  309.  
  310. IF LDATA EQ false
  311.                 mov     ax,-1
  312.                 push    ax
  313.                 call    UNLOCKSEGMENT
  314. ENDIF
  315.  
  316.                 pop     ax
  317.                 pop     di
  318.                 pop     si
  319.                 ret
  320.  
  321. @@error:
  322.                 push    1
  323.                 jmp     @@unlock
  324.  
  325.                 endp
  326.  
  327. ;       Return default data segment in AX
  328.  
  329. __GetDGROUP     PROC    FAR
  330.                 PUBLIC  __GetDGROUP
  331.                 mov     ax, DGROUP
  332.                 ret
  333.                 endp
  334.  
  335. ;------------------------------------------------------------------
  336. ;  Loop through a startup/exit (SE) table,
  337. ;  calling functions in order of priority.
  338. ;  ES:SI is assumed to point to the beginning of the SE table
  339. ;  ES:DI is assumed to point to the end of the SE table
  340. ;  First 64 priorities are reserved by Borland
  341. ;------------------------------------------------------------------
  342. PNEAR           EQU     0
  343. PFAR            EQU     1
  344. NOTUSED         EQU     0ffh
  345.  
  346. SE              STRUC
  347. calltype        db      ?                       ; 0=near,1=far,ff=not used
  348. priority        db      ?                       ; 0=highest,ff=lowest
  349. addrlow         dw      ?
  350. addrhigh        dw      ?
  351. SE              ENDS
  352.  
  353. Initialize      proc near
  354. @@Start:        mov     ax,100h                 ;start with lowest priority
  355.                 mov     dx,di                   ;set sentinel to end of table
  356.                 mov     bx,si                   ;bx = start of table
  357.  
  358. @@TopOfTable:   cmp     bx,di                   ;and the end of the table?
  359.                 je      @@EndOfTable            ;yes, exit the loop
  360.                 cmp     es:[bx.calltype],NOTUSED;check the call type
  361.                 je      @@Next
  362.                 mov     cl, es:[bx.priority]    ;move priority to CX
  363.                 xor     ch, ch
  364.                 cmp     cx,ax                   ;check the priority
  365.                 jae     @@Next                  ;too high?  skip
  366.                 mov     ax,cx                   ;keep priority
  367.                 mov     dx,bx                   ;keep index in dx
  368. @@Next:         add     bx,SIZE SE              ;bx = next item in table
  369.                 jmp     @@TopOfTable
  370.  
  371. @@EndOfTable:   cmp     dx,di                   ;did we exhaust the table?
  372.                 je      @@Done                  ;yes, quit
  373.                 mov     bx,dx                   ;bx = highest priority item
  374.                 cmp     es:[bx.calltype],PNEAR  ;is it near or far?
  375.                 mov     es:[bx.calltype],NOTUSED;wipe the call type
  376.                 push    es                      ;save es
  377.                 je      @@NearCall
  378.  
  379. @@FarCall:      call    DWORD PTR es:[bx.addrlow]
  380.                 pop     es                      ;restore es
  381.                 jmp     short @@Start
  382.  
  383. @@NearCall:     call    WORD PTR es:[bx.addrlow]
  384.                 pop     es                      ;restore es
  385.                 jmp     short @@Start
  386.  
  387. @@Done:         ret
  388.                 endp
  389.  
  390. Cleanup         proc near
  391. @@Start:        mov     ah,0                    ;start with highest priority
  392.                 mov     dx,di                   ;set sentinel to end of table
  393.                 mov     bx,si                   ;bx = start of table
  394.  
  395. @@TopOfTable:   cmp     bx,di                   ;and the end of the table?
  396.                 je      @@EndOfTable            ;yes, exit the loop
  397.                 cmp     es:[bx.calltype],NOTUSED;check the call type
  398.                 je      @@Next
  399.                 cmp     es:[bx.priority],ah     ;check the priority
  400.                 jb      @@Next                  ;too low?  skip
  401.                 mov     ah,es:[bx.priority]     ;keep priority
  402.                 mov     dx,bx                   ;keep index in dx
  403. @@Next:         add     bx,SIZE SE              ;bx = next item in table
  404.                 jmp     @@TopOfTable
  405.  
  406. @@EndOfTable:   cmp     dx,di                   ;did we exhaust the table?
  407.                 je      @@Done                  ;yes, quit
  408.                 mov     bx,dx                   ;bx = highest priority item
  409.                 cmp     es:[bx.calltype],PNEAR  ;is it near or far?
  410.                 mov     es:[bx.calltype],NOTUSED;wipe the call type
  411.                 push    es                      ;save es
  412.                 je      @@NearCall
  413.  
  414. @@FarCall:      call    DWORD PTR es:[bx.addrlow]
  415.                 pop     es                      ;restore es
  416.                 jmp     short @@Start
  417.  
  418. @@NearCall:     call    WORD PTR es:[bx.addrlow]
  419.                 pop     es                      ;restore es
  420.                 jmp     short @@Start
  421.  
  422. @@Done:         ret
  423.                 endp
  424.  
  425.                 ends
  426.                 end LibEntry
  427.