Chip 1997 January/Chip_1997-01_cd.bin/dirwin/data.z/ANIMWIZ.DIR/00008_Script_Banners

Text File | 1996-03-15 | 10KB | 337 lines

-- Banners script

property ioFieldList
property iFieldFocus
property ioFieldFocus
property iCurrentMotionStyleIndex
property iCurrentVisualStyleIndex

-- The motion styles are:
property ikMotionRightToLeft  -- 1
property ikMotionLeftToRight  -- 2
property ikMotionUp                 -- 3
property ikMotionDown             --4

property iFirstTIme
property iSaveSeconds
property iSaveFPS
property iSaveBaseline
property iSaveDelayEnter
property iSaveMark
property iSaveCycles


on birth me
  global goBannersText
  global goSeconds
  global goFPS
  global goBaseLine
  global goDelayEnter
  global goCycles

  set ioFieldList = [goBannersText, goSeconds, goFPS, goBaseLine, goDelayEnter, goCycles]
  set ikMotionRightToLeft = 1
  set ikMotionLeftToRight = 2
  set ikMotionUp = 3
  set ikMotionDown = 4

  set iCurrentMotionStyleIndex = ikMotionRightToLeft
  set iCurrentVisualStyleIndex = 1
  set iFieldFocus = 1
  set iFirstTime = TRUE

  return me
end birth

on mInit me
  global goSeconds
  global goFPS
  global goBaseLine
  global goDelayEnter
  global goCycles
  global goBanners
  global goMarkFrame
  global goVisualStyles
  global goMotionStyles
  global goScoreMgr

  -- CheckMark parameter: channel
  mInit(goMarkFrame, 4)  -- channel

  if iFirstTime then  -- use intellegent defaults
    mSetValue(goSeconds, 5)
    mSetValue(goFPS, 5)
    set defaultBaseLine = integer(mGetStageHeight(goScoreMgr) / 2)
    mSetValue(goBaseLine, defaultBaseLine)
    mSetValue(goDelayEnter, 0)
    mSetValue(goCycles, 1)
    mSetValue(goMarkFrame, TRUE)
    set iFirstTime = FALSE

  else  -- use values saved from when we last left
    mSetValue(goSeconds, iSaveSeconds)
    mSetValue(goFPS, iSaveFPS)
    mSetValue(goBaseLine, iSaveBaseline)
    mSetValue(goDelayEnter, iSaveDelayEnter)
    mSetValue(goCycles, iSaveCycles)
    mSetValue(goMarkFrame, iSaveMark)
  end if

  set ioFieldFocus = GetAt(ioFieldList, iFieldFocus)

  -- RadioButtons parameters: channel, nChannels, rightAnswer, default
  set goMotionStyles = 0
  set goMotionStyles = birth(script "RadioButton",  26, 4, 0, iCurrentMotionStyleIndex)


  -- VisualStyles Params: castNum, default, nItems, channel
  if the machineType < 256 then
    mInit(goVisualStyles, the number of cast "BannersVisualStylesMac", ¼
               iCurrentVisualStyleIndex, 8, 19)
  else
    mInit(goVisualStyles, the number of cast "BannersVisualStylesPC", ¼
               iCurrentVisualStyleIndex, 8, 19)
  end if


  -- For keystroke validity checking
  set the keydownscript =  "mCheckKey(goBanners)"

end mInit

on mSetFieldFocus me, oWhom
  set where = getOne(ioFieldList, oWhom)
  if where = 0 then
    alert("Internal error - mSetFieldFocus could not find object")
    return
  end if

  set iFieldFocus = where
  set ioFieldFocus = GetAt(ioFieldList, iFieldFocus)

end mSetFieldFocus


on mCheckKey me
  if the Key = TAB then -- change focus to the next field
    set iFieldFocus = IncrMod(iFieldFocus, count(ioFieldList))
    set ioFieldFocus = GetAt(ioFieldList, iFieldFocus)
    pass  -- pass the event so the hilight goes to the next field
  else
    if iFieldFocus = 1 then -- the text entry field, allow anything
      pass
    else  -- numeric fields, only allow digits
      if (offset(the key, "0123456789") > 0) or (the key = BACKSPACE)  then
        pass
      else
        dontPassEvent -- restrict only to digits.
      end if
    end if
  end if
end mCheckKey

on mSetNewMotionStyle me, theNewStyleIndex
  set iCurrentMotionStyleIndex = theNewStyleIndex
end mSetNewMotionStyle

on mSetNewVisualStyle me, theNewStyleIndex
  set iCurrentVisualStyleIndex = theNewStyleIndex
end mSetNewVisualStyle



on mValidate me
  -- Attempt to validate the last field of focus
  set lastFieldOKFlag = mValidate(ioFIeldFocus)
  return lastFieldOKFlag
end mValidate


on mCreate me
  global goMarkFrame
  global goMotionStyles
  global goVisualStyles
  global goScoreMgr
  global goCastMgr
  global gDevelopmentFlag
  global gCastNumTextAsBitmap

  if not(mValidate(me)) then
    return
  end if
  if field("BannersText") = EMPTY then
    alert("Please enter some text for the banner.")
    return
  end if

  tell the stage
    set theStageFrame = the frame
  end tell

  set castNumVisualStyle = mGetCastNum(goVisualStyles, iCurrentVisualStyleIndex)
  set theVisualStyleName = the name of cast castNumVisualStyle
  set theFont = word 2 of theVisualStyleName
  set theSize = word 3 of theVisualStyleName
  set theSeconds = integer(field "Seconds")

  set fps = integer(field "FPS")
  set nFrames = integer(theSeconds * fps)
  set baseLine = integer(field "BaseLine")
  set delayEnter = integer(field "DelayEnter")
  set nCycles = integer(field "Cycles")
  set markFirst = mGetValue(goMarkFrame)


  -- Call the ScoreMgr to set up the score, # of frames, and 1 channel
  --  set nTotalFrames = (delayEnter + nFrames) * nCycles
  set nTotalFrames = nFrames * nCycles
  if not(mInit(goScoreMgr, nTotalFrames, 1)) then
    return
  end if

  set theCh = mGetNextSelectedChannel(goScoreMgr)
  set theFrameNum = mGetStartFrame(goScoreMgr)

  set castNumSource = mModifyRichTextCM(goCastMgr, ¼
                the text of field "BannersText", theFont, theSize)
  if castNumSource = 0 then  -- error
    return
  end if

  -- The following does an effective "Convert to bitmap" into a
  -- known bitmap cast member.
  set the picture of member gCastNumTextAsBitmap = ¼
        the picture of member castNumSource
  set widthOfTextAsBitmap = the width of member gCastNumTextAsBitmap
  set heightOfTextAsBitmap = the height of member castNumSource / ¼
                                                the number of lines in (the text of member castNumSource)


  -- Do specific calculations depending on motion style

  if (iCurrentMotionStyleIndex = ikMotionRightToLeft) or ¼
      (iCurrentMotionStyleIndex = ikMotionLeftToRight) then
    set yStart = baseline
    set yEnd = baseLine
    set yInc = 0

    if (iCurrentMotionStyleIndex = ikMotionRightToLeft)  then
      set xStart = mGetStageRight(goScoreMgr)  + 10
      set xEnd = 0 - widthOfTextAsBitmap - 10
      set xInc = float( xEnd - xStart ) / float(nFrames)

    else  -- Left to right
      set xStart = 0 - widthOfTextAsBitmap - 10
      set xEnd = mGetStageRight(goScoreMgr) + 10
      set xInc = float( xEnd - xStart ) / float(nFrames)
    end if

  else  -- up or down
    set xStart = (mGetStageWidth(goScoreMgr) / 2) - (widthOfTextAsBitmap / 2)
    set xEnd = xStart
    set xInc = 0
    if (iCurrentMotionStyleIndex = ikMotionUp)  then
      set yStart = mGetStageHeight(goScoreMgr) + heightOfTextAsBitmap + 1
      set yEnd = 0 - heightOfTextAsBitmap - 10
      set yInc = float( yEnd - yStart ) / float(nFrames)

    else  -- Down
      set yStart = 0 - heightOfTextAsBitmap - 10
      set yEnd = mGetStageHeight(goScoreMgr) + heightOfTextAsBitmap + 10
      set yInc = float( yEnd - yStart ) / float(nFrames)

    end if
  end if

  set theForeColor  = 255
  set theBackColor  = 0

  --  Copy the cast member into the source movie's cast

  set castNumTarget = mFindFreeCastRun(goCastMgr, 1, 1)
  copyToClipBoard member castNumSource
  tell the stage
    pasteClipboardInto member castNumTarget
    set the name of member castNumTarget  = "RichText" && string(the ticks)
  end tell

  --  Finally we are ready to generate frames

  -- Mark first frame upon request
  if markFirst  then
    set theLabel  = "AW.Banner." & word 1 of the text of field "BannersText" & " " & ¼
              mGetGeneratedScoreSelection(goScoreMgr)
    mWriteFrameLabel(goScoreMgr, theFrameNum, theLabel)
  end if

  -- Generate the score fragment
  repeat with thisCycle = 1 to nCycles
    -- Insert delay at entry upon request
    --    if  delayEnter > 0  then
    --      mWriteFrameDelay(goScoreMgr, theFrameNum, delayEnter)
    --     set theFrameNum = theFrameNum + delayEnter
    --    end if
    if delayEnter > 0 then
      mWriteFrameDelay(goScoreMgr, theFrameNum, delayEnter)
      mWriteFrameTempo(goScoreMgr, (theFrameNum + 1), fps)
    else
      mWriteFrameTempo(goScoreMgr, theFrameNum , fps)
      mWriteFrameTempo(goScoreMgr, (theFrameNum + 1), 0)
    end if
    --      mWriteFrameTempo(goScoreMgr, theFrameNum , fps)
    set xLoc = xStart
    set yLoc = yStart
    tell the stage
      beginRecording
        repeat with thisFrame = 1 to nFrames
          put theFrameNum && theCh  && castNumTarget  && xLoc && yLoc
          --      mWriteSprite(goScoreMgr, theFrameNum, theCh, castNumTarget, ¼
--                         theForeColor, theBackColor, round(xLoc), round(yLoc), 0, 0)
          set xLoc = integer(xLoc + .49)
          set yLoc = integer(yLoc  + .49)
          mWriteSpriteRange(goScoreMgr, theFrameNum, theCh, castNumTarget, ¼
                         theForeColor, theBackColor, xLoc, yLoc, 0, 0)
          set theFrameNum = theFrameNum + 1
          set xLoc = xLoc + xInc
          set yLoc = yLoc + yInc
        end repeat
      endRecording
    end tell
  end repeat

  go  label("Banners") + 2  -- to display reselect button

  if not(gDevelopmentFlag) then
    tell the stage
      go frame theStageFrame
    end tell
  end if

  mClean(goScoreMgr)

end mCreate



on mCleanup me
  global goMotionStyles
  global goSeconds
  global goFPS
  global goBaseLine
  global goDelayEnter
  global goCycles
  global goMarkFrame

  mCleanup(goMotionStyles)

  set iSaveSeconds =  mGetValue(goSeconds)
  set iSaveFPS = mGetValue(goFPS)
  set iSaveBaseLine = mGetValue(goBaseLine)
  set iSaveDelayEnter = mGetValue(goDelayEnter)
  set iSaveCycles = mGetValue(goCycles)
  set iSaveMark = mGetValue(goMarkFrame)
  mCleanup(goMarkFrame)
end mCleanup