home *** CD-ROM | disk | FTP | other *** search
/ Hráč 1997 February / Hrac_09_1997-02_cd.bin / UTILS / QUAKE / EXTRA / KILLER90.ZIP / SRC / PLATS.QC < prev    next >
Text File  |  1996-11-28  |  8KB  |  367 lines
  1.  
  2.  
  3. void() plat_center_touch;
  4. void() plat_outside_touch;
  5. void() plat_trigger_use;
  6. void() plat_go_up;
  7. void() plat_go_down;
  8. void() plat_crush;
  9. float PLAT_LOW_TRIGGER = 1;
  10.  
  11. void() plat_spawn_inside_trigger =
  12. {
  13.     local entity    trigger;
  14.     local vector    tmin, tmax;
  15.  
  16. //
  17. // middle trigger
  18. //    
  19.     trigger = spawn();
  20.     trigger.touch = plat_center_touch;
  21.     trigger.movetype = MOVETYPE_NONE;
  22.     trigger.solid = SOLID_TRIGGER;
  23.     trigger.enemy = self;
  24.     
  25.     tmin = self.mins + '25 25 0';
  26.     tmax = self.maxs - '25 25 -8';
  27.     tmin_z = tmax_z - (self.pos1_z - self.pos2_z + 8);
  28.     if (self.spawnflags & PLAT_LOW_TRIGGER)
  29.         tmax_z = tmin_z + 8;
  30.     
  31.     if (self.size_x <= 50)
  32.     {
  33.         tmin_x = (self.mins_x + self.maxs_x) / 2;
  34.         tmax_x = tmin_x + 1;
  35.     }
  36.     if (self.size_y <= 50)
  37.     {
  38.         tmin_y = (self.mins_y + self.maxs_y) / 2;
  39.         tmax_y = tmin_y + 1;
  40.     }
  41.     
  42.     setsize (trigger, tmin, tmax);
  43. };
  44.  
  45. void() plat_hit_top =
  46. {
  47.     sound (self, CHAN_VOICE, self.noise1, 1, ATTN_NORM);
  48.     self.state = STATE_TOP;
  49.     self.think = plat_go_down;
  50.     self.nextthink = self.ltime + 3;
  51. };
  52.  
  53. void() plat_hit_bottom =
  54. {
  55.     sound (self, CHAN_VOICE, self.noise1, 1, ATTN_NORM);
  56.     self.state = STATE_BOTTOM;
  57. };
  58.  
  59. void() plat_go_down =
  60. {
  61.     sound (self, CHAN_VOICE, self.noise, 1, ATTN_NORM);
  62.     self.state = STATE_DOWN;
  63.     SUB_CalcMove (self.pos2, self.speed, plat_hit_bottom);
  64. };
  65.  
  66. void() plat_go_up =
  67. {
  68.     sound (self, CHAN_VOICE, self.noise, 1, ATTN_NORM);
  69.     self.state = STATE_UP;
  70.     SUB_CalcMove (self.pos1, self.speed, plat_hit_top);
  71. };
  72.  
  73. void() plat_center_touch =
  74. {
  75.         if ((other.classname != "player") &&
  76.             (other.classname != "clone") &&
  77.             (other.classname != "cujo"))
  78.         return;
  79.         
  80.     if (other.health <= 0)
  81.         return;
  82.  
  83.     self = self.enemy;
  84.     if (self.state == STATE_BOTTOM)
  85.         plat_go_up ();
  86.     else if (self.state == STATE_TOP)
  87.         self.nextthink = self.ltime + 1;    // delay going down
  88. };
  89.  
  90. void() plat_outside_touch =
  91. {
  92.     if ((other.classname != "player") && (other.classname != "clone"))
  93.         return;
  94.  
  95.     if (other.health <= 0)
  96.         return;
  97.         
  98. //dprint ("plat_outside_touch\n");
  99.     self = self.enemy;
  100.     if (self.state == STATE_TOP)
  101.         plat_go_down ();
  102. };
  103.  
  104. void() plat_trigger_use =
  105. {
  106.     if (self.think)
  107.         return;        // allready activated
  108.     plat_go_down();
  109. };
  110.  
  111.  
  112. void() plat_crush =
  113. {
  114. //dprint ("plat_crush\n");
  115.  
  116.     T_Damage (other, self, self, 1);
  117.     
  118.     if (self.state == STATE_UP)
  119.         plat_go_down ();
  120.     else if (self.state == STATE_DOWN)
  121.         plat_go_up ();
  122.     else
  123.         objerror ("plat_crush: bad self.state\n");
  124. };
  125.  
  126. void() plat_use =
  127. {
  128.     self.use = SUB_Null;
  129.     if (self.state != STATE_UP)
  130.         objerror ("plat_use: not in up state");
  131.     plat_go_down();
  132. };
  133.  
  134.  
  135. /*QUAKED func_plat (0 .5 .8) ? PLAT_LOW_TRIGGER
  136. speed    default 150
  137.  
  138. Plats are always drawn in the extended position, so they will light correctly.
  139.  
  140. If the plat is the target of another trigger or button, it will start out disabled in the extended position until it is trigger, when it will lower and become a normal plat.
  141.  
  142. If the "height" key is set, that will determine the amount the plat moves, instead of being implicitly determined by the model's height.
  143. Set "sounds" to one of the following:
  144. 1) base fast
  145. 2) chain slow
  146. */
  147.  
  148.  
  149. void() func_plat =
  150.  
  151. {
  152. local entity t;
  153.  
  154.     if (!self.t_length)
  155.         self.t_length = 80;
  156.     if (!self.t_width)
  157.         self.t_width = 10;
  158.  
  159.     if (self.sounds == 0)
  160.         self.sounds = 2;
  161. // FIX THIS TO LOAD A GENERIC PLAT SOUND
  162.  
  163.     if (self.sounds == 1)
  164.     {
  165.         precache_sound ("plats/plat1.wav");
  166.         precache_sound ("plats/plat2.wav");
  167.         self.noise = "plats/plat1.wav";
  168.         self.noise1 = "plats/plat2.wav";
  169.     }
  170.  
  171.     if (self.sounds == 2)
  172.     {
  173.         precache_sound ("plats/medplat1.wav");
  174.         precache_sound ("plats/medplat2.wav");
  175.         self.noise = "plats/medplat1.wav";
  176.         self.noise1 = "plats/medplat2.wav";
  177.     }
  178.  
  179.  
  180.     self.mangle = self.angles;
  181.     self.angles = '0 0 0';
  182.  
  183.     self.classname = "plat";
  184.     self.solid = SOLID_BSP;
  185.     self.movetype = MOVETYPE_PUSH;
  186.     setorigin (self, self.origin);    
  187.     setmodel (self, self.model);
  188.     setsize (self, self.mins , self.maxs);
  189.  
  190.     self.blocked = plat_crush;
  191.     if (!self.speed)
  192.         self.speed = 150;
  193.  
  194. // pos1 is the top position, pos2 is the bottom
  195.     self.pos1 = self.origin;
  196.     self.pos2 = self.origin;
  197.     if (self.height)
  198.         self.pos2_z = self.origin_z - self.height;
  199.     else
  200.         self.pos2_z = self.origin_z - self.size_z + 8;
  201.  
  202.     self.use = plat_trigger_use;
  203.  
  204.     plat_spawn_inside_trigger ();    // the "start moving" trigger    
  205.  
  206.     if (self.targetname)
  207.     {
  208.         self.state = STATE_UP;
  209.         self.use = plat_use;
  210.     }
  211.     else
  212.     {
  213.         setorigin (self, self.pos2);
  214.         self.state = STATE_BOTTOM;
  215.     }
  216. };
  217.  
  218. //============================================================================
  219.  
  220. void() train_next;
  221. void() func_train_find;
  222.  
  223. void() train_blocked =
  224. {
  225.     if (time < self.attack_finished)
  226.         return;
  227.     self.attack_finished = time + 0.5;
  228.     T_Damage (other, self, self, self.dmg);
  229. };
  230. void() train_use =
  231. {
  232.     if (self.think != func_train_find)
  233.         return;        // already activated
  234.     train_next();
  235. };
  236.  
  237. void() train_wait =
  238. {
  239.     if (self.wait)
  240.     {
  241.         self.nextthink = self.ltime + self.wait;
  242.         sound (self, CHAN_VOICE, self.noise, 1, ATTN_NORM);
  243.     }
  244.     else
  245.         self.nextthink = self.ltime + 0.1;
  246.     
  247.     self.think = train_next;
  248. };
  249.  
  250. void() train_next =
  251. {
  252.     local entity    targ;
  253.  
  254.     targ = find (world, targetname, self.target);
  255.     self.target = targ.target;
  256.     if (!self.target)
  257.         objerror ("train_next: no next target");
  258.     if (targ.wait)
  259.         self.wait = targ.wait;
  260.     else
  261.         self.wait = 0;
  262.     sound (self, CHAN_VOICE, self.noise1, 1, ATTN_NORM);
  263.     SUB_CalcMove (targ.origin - self.mins, self.speed, train_wait);
  264. };
  265.  
  266. void() func_train_find =
  267.  
  268. {
  269.     local entity    targ;
  270.  
  271.     targ = find (world, targetname, self.target);
  272.     self.target = targ.target;
  273.     setorigin (self, targ.origin - self.mins);
  274.     if (!self.targetname)
  275.     {    // not triggered, so start immediately
  276.         self.nextthink = self.ltime + 0.1;
  277.         self.think = train_next;
  278.     }
  279. };
  280.  
  281. /*QUAKED func_train (0 .5 .8) ?
  282. Trains are moving platforms that players can ride.
  283. The targets origin specifies the min point of the train at each corner.
  284. The train spawns at the first target it is pointing at.
  285. If the train is the target of a button or trigger, it will not begin moving until activated.
  286. speed    default 100
  287. dmg        default    2
  288. sounds
  289. 1) ratchet metal
  290.  
  291. */
  292. void() func_train =
  293. {    
  294.     if (!self.speed)
  295.         self.speed = 100;
  296.     if (!self.target)
  297.         objerror ("func_train without a target");
  298.     if (!self.dmg)
  299.         self.dmg = 2;
  300.  
  301.     if (self.sounds == 0)
  302.     {
  303.         self.noise = ("misc/null.wav");
  304.         precache_sound ("misc/null.wav");
  305.         self.noise1 = ("misc/null.wav");
  306.         precache_sound ("misc/null.wav");
  307.     }
  308.  
  309.     if (self.sounds == 1)
  310.     {
  311.         self.noise = ("plats/train2.wav");
  312.         precache_sound ("plats/train2.wav");
  313.         self.noise1 = ("plats/train1.wav");
  314.         precache_sound ("plats/train1.wav");
  315.     }
  316.  
  317.     self.cnt = 1;
  318.     self.solid = SOLID_BSP;
  319.     self.movetype = MOVETYPE_PUSH;
  320.     self.blocked = train_blocked;
  321.     self.use = train_use;
  322.     self.classname = "train";
  323.  
  324.     setmodel (self, self.model);
  325.     setsize (self, self.mins , self.maxs);
  326.     setorigin (self, self.origin);
  327.  
  328. // start trains on the second frame, to make sure their targets have had
  329. // a chance to spawn
  330.     self.nextthink = self.ltime + 0.1;
  331.     self.think = func_train_find;
  332. };
  333.  
  334. /*QUAKED misc_teleporttrain (0 .5 .8) (-8 -8 -8) (8 8 8)
  335. This is used for the final bos
  336. */
  337. void() misc_teleporttrain =
  338. {    
  339.     if (!self.speed)
  340.         self.speed = 100;
  341.     if (!self.target)
  342.         objerror ("func_train without a target");
  343.  
  344.     self.cnt = 1;
  345.     self.solid = SOLID_NOT;
  346.     self.movetype = MOVETYPE_PUSH;
  347.     self.blocked = train_blocked;
  348.     self.use = train_use;
  349.     self.avelocity = '100 200 300';
  350.  
  351.     self.noise = ("misc/null.wav");
  352.     precache_sound ("misc/null.wav");
  353.     self.noise1 = ("misc/null.wav");
  354.     precache_sound ("misc/null.wav");
  355.  
  356.     precache_model2 ("progs/teleport.mdl");
  357.     setmodel (self, "progs/teleport.mdl");
  358.     setsize (self, self.mins , self.maxs);
  359.     setorigin (self, self.origin);
  360.  
  361. // start trains on the second frame, to make sure their targets have had
  362. // a chance to spawn
  363.     self.nextthink = self.ltime + 0.1;
  364.     self.think = func_train_find;
  365. };
  366.  
  367.