home *** CD-ROM | disk | FTP | other *** search
/ Hráč 1997 December / Hrac_16_1997-12_cd.bin / UTILS / 3DFx / GLMENU.ZIP / glmenu.bat
DOS Batch File  |  1997-04-17  |  4KB  |  119 lines
  1. @echo off
  2. REM ============================================================================
  3. REM Batch file originally programmed by Mark D. Rejhon <marky@ottawa.com>
  4. REM Public domain, freely modifiable and distributable.  Just leave my
  5. REM name in here for credit, that's all! :)  You may add your blurb here.
  6. REM ============================================================================
  7.  
  8. cls
  9. if exist GLQUAKE.EXE goto :GLQEXISTS
  10. echo.
  11. echo ERROR:
  12. echo This batch file needs to be run in the same directory as GLQUAKE.EXE
  13. echo Please make sure that this batch file is in your \QUAKE directory.
  14. echo.
  15. pause
  16. goto :END
  17. :GLQEXISTS
  18.  
  19. REM If user is running 120Hz refresh, change to 60Hz for purpose of GLQuake.
  20. if !%SST_SCREENREFRESH%!==!120! echo.
  21. if !%SST_SCREENREFRESH%!==!120! echo The refresh rate is 120Hz which slows down the DAC on the 3Dfx card.
  22. if !%SST_SCREENREFRESH%!==!120! echo Setting to 60Hz for better GLQuake performance.
  23. if !%SST_SCREENREFRESH%!==!120! set SST_SCREENREFRESH=60
  24.  
  25. REM Display menu
  26. echo.
  27. echo ──────────────────────────────────────────────────────────────────────────────
  28. echo GLQuake 3Dfx Performance Menu by Mark D. Rejhon (ag115@freenet.carleton.ca)
  29. echo Framerates in rightmost column is 'TIMEDEMO DEMO2' test on my P166 system.
  30. echo ──────────────────────────────────────────────────────────────────────────────
  31. echo.
  32. echo 1) 512x384 Max framerate, without tearing - Fastest and Smoothest      - 43fps
  33. echo 2) 512x384 Limit framerate to max 36fps   - More consistent framerate  - 35fps
  34. echo 3) 512x384 Full blast maximum framerate   - With tearing, may be jumpy - 50fps
  35. echo 4) 640x480 Max framerate, without tearing - Fast and Smooth            - 32fps
  36. echo 5) 640x480 Limit framerate to max 30fps   - More consistent framerate  - 29fps
  37. echo 6) 640x480 Full blast maximum framerate   - With tearing, may be jumpy - 41fps
  38. echo.
  39. echo ──────────────────────────────────────────────────────────────────────────────
  40. choice /N /C:12345678 Please enter the number of your choice above:
  41. cls
  42. echo.
  43. if errorlevel 6 goto R640FULL:
  44. if errorlevel 5 goto R640MAX30:
  45. if errorlevel 4 goto R640MAX60:
  46. if errorlevel 3 goto R512FULL:
  47. if errorlevel 2 goto R512MAX36:
  48. if errorlevel 1 goto R512MAX72:
  49.  
  50. :R512MAX72
  51. echo Now running 512x384 max framerate, without tearing.
  52. set SST_SWAP_EN_WAIT_ON_VSYNC=1
  53. set FX_GLIDE_SWAPINTERVAL=1
  54. set GLQUAKE_OPTIONS=-width 512 -height 384
  55. goto :RUNGLQ
  56.  
  57. :R512MAX36
  58. echo Now running 512x384 limit framerate to max 36fps.
  59. set SST_SWAP_EN_WAIT_ON_VSYNC=1
  60. set FX_GLIDE_SWAPINTERVAL=2
  61. set GLQUAKE_OPTIONS=-width 512 -height 384
  62. goto :RUNGLQ
  63.  
  64. :R512FULL
  65. echo Now running 512x384 full blast maximum framerate, with tearing.
  66. set SST_SWAP_EN_WAIT_ON_VSYNC=0
  67. set FX_GLIDE_SWAPINTERVAL=0
  68. set GLQUAKE_OPTIONS=-width 512 -height 384
  69. goto :RUNGLQ
  70.  
  71. :R640MAX60
  72. echo Now running 640x480 max framerate, without tearing.
  73. set SST_SWAP_EN_WAIT_ON_VSYNC=1
  74. set FX_GLIDE_SWAPINTERVAL=1
  75. set GLQUAKE_OPTIONS=-width 640 -height 480
  76. goto :RUNGLQ
  77.  
  78. :R640MAX30
  79. echo Now running 640x480 limit framerate to max 30fps.
  80. set SST_SWAP_EN_WAIT_ON_VSYNC=1
  81. set FX_GLIDE_SWAPINTERVAL=2
  82. set GLQUAKE_OPTIONS=-width 640 -height 480
  83. goto :RUNGLQ
  84.  
  85. :R640FULL
  86. echo Now running 640x480 full blast maximum framerate, with tearing.
  87. set SST_SWAP_EN_WAIT_ON_VSYNC=0
  88. set FX_GLIDE_SWAPINTERVAL=0
  89. set GLQUAKE_OPTIONS=-width 640 -height 480
  90. goto :RUNGLQ
  91.  
  92. :RUNGLQ
  93. REM Make sure we did not run out of environment variables memory.
  94. cls
  95. if !%SST_SWAP_EN_WAIT_ON_VSYNC%!==!! goto :ENVERROR
  96. if !%FX_GLIDE_SWAPINTERVAL%!==!! goto :ENVERROR
  97. if !%GLQUAKE_OPTIONS%!==!! goto :ENVERROR
  98. glquake %GLQUAKE_OPTIONS% +_windowed_mouse 1 -window -nocdaudio %1 %2 %3 %4 %5 %6 %7 %8 %9
  99. goto :END
  100.  
  101. :ENVERROR
  102. echo.
  103. echo ERROR: Out of environment space.
  104. echo WHY:   Required for performance enhancing environment variables.
  105. echo.
  106. echo You can fix this problem with these instructions:
  107. echo 1. Hit Alt-Space or right click on the upper-left corner icon for this window.
  108. echo 2. Select "Properties" on the menu that appears.
  109. echo 3. Select the "Memory" tab on the window that appears.
  110. echo 4. Set the "Initial Environment" textbox to the value "2048".
  111. echo 5. Click on "OK"
  112. echo 6. Close this DOS window and then try again
  113. echo.
  114. pause
  115. goto :END
  116.  
  117. :END
  118.  
  119.