Amiga MA Magazine 1998 #6/amigamamagazinepolishissue1998.iso/polminet/inne/stfax/install

Text File | 1997-06-19 | 5KB | 221 lines

; $VER: STFax-Install 1.11 (14.6.97)

(if (exists "STFax:" (noreq))
   (set @default-dest (pathonly (expandpath "STFax:")))
)

(complete 0)

(set InstallDir
   (askdir
      (prompt "Where do you want to install STFax?"
              " (a drawer called 'STFax' will be created there)")
      (help @askdir-help)
      (default @default-dest)
   )
)

(Set DestDir
   (tackon InstallDir "STFax")
)

(Set FaxInDir
   (tackon DestDir "Fax_In")
)

(Set FaxOutDir
   (tackon DestDir "Fax_Out")
)

(Set ConfigDir
   (tackon DestDir "Config")
)

(Set LocaleDir
   (tackon DestDir "Catalogs")
)

(Set ContribDir
   (tackon DestDir "Contributions")
)

(set @default-dest  DestDir)

(makedir DestDir)

(copyfiles
   (source "/STFax.info")
   (dest InstallDir)
   (infos)
   (noposition)
)

(complete 10)

(if (<= (/ (getversion) 65536) 38)
   (set Kick2 1)
   (set Kick2 0)
)

(copyfiles (source "STFax")            (dest DestDir))

(if (= (exists (tackon DestDir "STFax.info")) 0)
   (copyfiles (source "STFax.info")       (dest DestDir)   (noposition))
)

(if (= (exists (tackon DestDir "STFax.guide.info")) 0)
   (copyfiles (source "STFax.guide.info") (dest DestDir)   (noposition))
)

(if (= (exists (tackon DestDir "NoData.txt")) 0)
   (copyfiles (source "NoData.txt")       (dest DestDir))
)

(copyfiles (source "Catalogs.info")    (dest DestDir)   (noposition))
(copyfiles (source "Rexx")             (dest DestDir)   (noposition) (infos) (all))

(complete 20)

(copyfiles
  (source "Devs/Printers/STFaxPrt")
  (dest "DEVS:Printers")
)

(complete 25)

(select
   (askchoice
      (prompt "Which documentation should I install?")
      (help @askoption-help)
      (choices "English" "Italiano")
      (default 0)
   )
; case 0  ---  English
      (
          (copyfiles (source "STFax.guide")        (dest DestDir))
          (copyfiles (source "ReadMe_Now!")        (dest DestDir))
          (copyfiles (source "ReadMe_Now!.info")   (dest DestDir) (noposition))
          (copyfiles (source "OrderForm.txt")      (dest DestDir))
          (copyfiles (source "OrderForm.txt.info") (dest DestDir) (noposition))
      )
; case 1  ---  Italiano
      (
          (copyfiles (source "docs/italiano/STFax.guide")          (dest DestDir))
          (copyfiles (source "docs/italiano/Leggimi_Ora!")         (dest DestDir))
          (copyfiles (source "docs/italiano/ModRegistrazione.txt") (dest DestDir))
          (copyfiles
              (source "ReadMe_Now!.info")
              (dest DestDir)
              (newname "Leggimi_Ora!.info")
              (noposition)
          )
          (copyfiles
              (source "OrderForm.txt.info")
              (dest DestDir)
              (newname "ModRegistrazione.txt.info")
              (noposition)
          )
      )
)


(complete 30)

(if (exists "STFax.key")
  (copyfiles
     (source "STFax.key")
     (dest DestDir)
  )
)

(if Kick2
   (tooltype
      (dest (tackon DestDir "STFax.guide"))
      (setdefaulttool "AmigaGuide")
   )
)

(complete 40)

(makedir LocaleDir (infos))

(copyfiles
  (source "Catalogs")
  (dest LocaleDir)
  (pattern "IEditor#?.c#?")
)

(complete 50)

(makedir FaxInDir   (infos))
(makedir FaxOutDir  (infos))
(makedir ConfigDir)

(complete 60)

(copyfiles
  (source "Devs/Datatypes")
  (dest "DEVS:Datatypes")
  (pattern "#?")
  (infos)
  (noposition)
)

(copylib
       (prompt "Installing STFax.datatype...")
       (help   "This will install the STFax.datatype: it will let "
               "you import STFax faxes into any program that supports "
               "datatypes.")
       (source "Classes/Datatypes/STFax.datatype")
       (dest   "SYS:Classes/Datatypes")
       (confirm)
)

(complete 70)

(startup "STFax"
        (prompt "Editing your S:User-Startup")
        (help   "The Installer will add one assign needed by STFax")
        (command (cat "    Assign STFax: \"" DestDir "\" >NIL:"))
)

(makeassign "STFax" DestDir)

(complete 80)

(copyfiles
        (prompt "Copying catalog files")
        (help @copyfiles-help)
        (source "Catalogs")
        (dest LocaleDir)
        (choices "ÃeÓtina" "català" "dansk" "deutsch" "español"
                 "français" "greek" "italiano" "nederlands" "norsk"
                 "polski" "russian" "svenska" "turkçe")
        (confirm)
)

(complete 90)

(copyfiles
        (prompt "Copying contributions")
        (help @copyfiles-help)
        (source "Contributions")
        (dest ContribDir)
        (choices "Multi2STFax" "Multi2STFax.doc"
                 "NewIcons"
                 "fax2ps" "fax2ps.doc"
                 "GP2STFax" "GP2STFax.doc")
        (confirm)
        (infos)
)

(if (exists ContribDir)
        (copyfiles
            (source "Contributions.info")
            (dest DestDir)
            (noposition)
        )
)

(complete 100)