home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Amiga MA Magazine 1998 #6
/
amigamamagazinepolishissue1998.iso
/
datatypes
/
akpng-datatype
/
install
< prev
next >
Wrap
Text File
|
1997-06-28
|
4KB
|
111 lines
;$VER: akPNG_Installer 43.91 (27.6.1997) #DOS © Msi Software
FAILAT 21
;Check OS version!
c/akT OS 39
IF WARN
ECHO "You need OS 3.0 or later!"
ASK "Press return!"
QUIT
ENDIF
;Display old and new dt version etc!
c/akT >ENV:akver VER classes/Datatypes/akPNG.datatype
c/akT >ENV:akverold VER Sys:Classes/Datatypes/akPNG.datatype
IF NOT WARN
C:RequestChoice >NIL: "Andreas Ralph Kleinert presents:" "$akver" "Install/Update"
ELSE
C:RequestChoice >NIL: "Andreas Ralph Kleinert presents:" "$akver*N(old: $akverold)" "Install/Update"
ENDIF
UNSETENV akver
UNSETENV akverold
;Create dt prefs drawer if not found!
IF NOT EXISTS SYS:Prefs/DataTypes
C:Makedir >NIL: SYS:Prefs/DataTypes
C:Copy >NIL: prefs/datatypes.info SYS:Prefs/DataTypes.info CLONE
ENDIF
;Move any dtprefs to sys:prefs/datatypes!
IF EXISTS sys:prefs/akPNGprefs
C:Rename >NIL: sys:prefs/akPNGprefs#? sys:prefs/datatypes
ENDIF
;Create ENV:Datatypes if not found!
IF NOT EXISTS ENV:Datatypes
C:Makedir >NIL: ENV:Datatypes ENVARC:Datatypes
ENDIF
;Install dtprefs if not found or current one is old!
c/akT CHK prefs/datatypes/akPNGPrefs SYS:prefs/datatypes/akPNGPrefs
IF WARN
C:Copy >NIL: prefs/datatypes/akPNGPrefs SYS:prefs/datatypes CLONE
IF NOT EXISTS
C:Copy >NIL: prefs/datatypes/akPNGPrefs.info SYS:prefs/datatypes CLONE
ENDIF
ENDIF
;Install correct dt!
c/akT CHK classes/datatypes/akPNG.datatype SYS:classes/datatypes/akPNG.datatype
IF WARN
c/akT CPU 060
IF NOT WARN
C:Copy >NIL: classes/datatypes/akPNG.datatype.060 SYS:Classes/datatypes/akPNG.datatype CLONE
ELSE
c/akT CPU 040
IF NOT WARN
C:Copy >NIL: classes/datatypes/akPNG.datatype.040 SYS:Classes/datatypes/akPNG.datatype CLONE
ELSE
c/akT CPU 030
IF NOT WARN
C:Copy >NIL: classes/datatypes/akPNG.datatype.030 SYS:Classes/datatypes/akPNG.datatype CLONE
ELSE
c/akT CPU 020
IF NOT WARN
C:Copy >NIL: classes/datatypes/akPNG.datatype.030 SYS:Classes/datatypes/akPNG.datatype CLONE
ELSE
C:Copy >NIL: classes/datatypes/akPNG.datatype SYS:Classes/datatypes/akPNG.datatype CLONE
ENDIF
ENDIF
ENDIF
ENDIF
;Move any old dt headers to storage!
Rename >NIL: SYS:Devs/Datatypes/#?PNG SYS:Storage/Datatypes/
;Install new dt header!
C:Copy >NIL: devs/datatypes/PNG DEVS:DataTypes
IF NOT EXISTS DEVS:DataTypes/PNG.info
C:Copy >NIL: devs/datatypes/PNG.info DEVS:DataTypes
ENDIF
;If VMEM assign not found, assign it and add to user-startup!
c/akT ASN vmem
IF WARN
C:RequestChoice >NIL: "ak Installer" "The VMEM: assign was not found!*NIt is needed by this datatype,*Nto be used as temporary directory." "Assign"
C:RequestFile >ENV:akvmem "SYS:" TITLE="Please select temporary dir:" SAVEMODE DRAWERSONLY NOICONS
ECHO >>S:User-Startup "*N;BEGIN VMEM"
ECHO >>S:User-Startup "Assign >NIL: VMEM: $akvmem"
ECHO >>S:User-Startup ";END VMEM"
C:Assign >NIL: VMEM: $akvmem
UNSETENV akvmem
ENDIF
;Change dir to docs!
CD Docs
;Show guide and start dtprefs!
Run >NIL: MultiView akPNG.guide
Run >NIL: /Prefs/DataTypes/akPNGPrefs
;Install completed message!
C:RequestChoice >NIL: "ak Installer" "Install completed!*NPlease reboot the system,*Nto use the new datatype!" "Ok"
ELSE
;Install not needed message!
C:RequestChoice >NIL: "ak Installer" "Install not needed!*NYou have the same or a higher version!" "Ok"
ENDIF
;Clean up memory/free resources!
C:Avail >NIL: FLUSH