home *** CD-ROM | disk | FTP | other *** search
/ Amiga MA Magazine 1998 #6 / amigamamagazinepolishissue1998.iso / coders / jËzyki_programowania / oberon / system / graphicframes.mod (.txt) < prev    next >
Oberon Text  |  2012-04-20  |  18KB  |  485 lines
  1. Syntax10.Scn.Fnt
  2. MODULE GraphicFrames; (*NW 18.4.88 / 30.6.93*)
  3.     IMPORT Display, Viewers, Input, Fonts, Texts, Graphics, Oberon, MenuViewers;
  4.     CONST (*update message ids*)
  5.         restore = 0;
  6.         drawobj = 1; drawobjs = 2; drawobjd = 3;
  7.         drawnorm = 4; drawsel = 5; drawdel = 6;
  8.         markW = 5;
  9.     TYPE
  10.         Frame* = POINTER TO FrameDesc;
  11.         Location* = POINTER TO LocDesc;
  12.         LocDesc* = RECORD
  13.                 x*, y*: INTEGER;
  14.                 next*: Location
  15.             END ;
  16.         FrameDesc* = RECORD (Display.FrameDesc)
  17.                 graph*: Graphics.Graph;
  18.                 Xg*, Yg*: INTEGER;  (*pos rel to graph origin*)
  19.                 X1*, Y1*: INTEGER;  (*right and upper margins*)
  20.                 x*, y*, col*: INTEGER;  (*x = X + Xg, y = Y + Yg*)
  21.                 marked*, ticked*: BOOLEAN;
  22.                 mark*: LocDesc
  23.             END ;
  24.         DrawMsg* = RECORD (Graphics.Msg)
  25.                 f*: Frame;
  26.                 x*, y*, col*, mode*: INTEGER
  27.             END ;
  28.         CtrlMsg* = RECORD (Graphics.Msg)
  29.                 f*: Frame;
  30.                 res*: INTEGER
  31.             END ;
  32.         UpdateMsg = RECORD (Display.FrameMsg)
  33.                 id: INTEGER;
  34.                 graph: Graphics.Graph;
  35.                 obj: Graphics.Object
  36.             END ;
  37.         SelQuery = RECORD (Display.FrameMsg)
  38.                 f: Frame; time: LONGINT
  39.             END ;
  40.         FocusQuery = RECORD (Display.FrameMsg)
  41.                 f: Frame
  42.             END ;
  43.         PosQuery = RECORD (Display.FrameMsg)
  44.                 f: Frame; x, y: INTEGER
  45.             END ;
  46.         DispMsg = RECORD (Display.FrameMsg)
  47.                 x1, y1, w: INTEGER;
  48.                 pat: Display.Pattern;
  49.                 graph: Graphics.Graph
  50.             END ;
  51.     VAR Crosshair*: Oberon.Marker;
  52.         newcap: Graphics.Caption;
  53.         DW, DH, CL: INTEGER;
  54.         W: Texts.Writer;
  55.     (*Exported procedures:
  56.         Restore, Focus, Selected, This, Draw, DrawNorm, Erase,
  57.         DrawObj, EraseObj, Change, Defocus, Deselect, Macro, New*)
  58.     PROCEDURE Restore*(F: Frame);
  59.         VAR x, x0, y: INTEGER; M: DrawMsg;
  60.     BEGIN F.X1 := F.X + F.W; F.Y1 := F.Y + F.H;
  61.         F.x := F.X + F.Xg; F.y := F.Y1 + F.Yg; F.marked := FALSE; F.mark.next := NIL;
  62.         Oberon.RemoveMarks(F.X, F.Y, F.W, F.H); Display.ReplConst(F.col, F.X, F.Y, F.W, F.H, 0);
  63.         IF F.ticked THEN
  64.             y := F.Yg MOD 16 + F.Y1 - 16; x0 := F.Xg MOD 16 + F.X;
  65.             WHILE y >= F.Y DO
  66.                 x := x0;
  67.                 WHILE x < F.X1 DO Display.Dot(Display.white, x, y, 0); INC(x, 16) END ;
  68.                 DEC(y, 16)
  69.             END
  70.         END ;
  71.         M.f := F; M.x := F.x; M.y := F.y; M.col := 0; M.mode := 0; Graphics.Draw(F.graph, M)
  72.     END Restore;
  73.     PROCEDURE Focus*(): Frame;
  74.         VAR FQ: FocusQuery;
  75.     BEGIN FQ.f := NIL; Viewers.Broadcast(FQ); RETURN FQ.f
  76.     END Focus;
  77.     PROCEDURE Selected*(): Frame;
  78.         VAR SQ: SelQuery;
  79.     BEGIN SQ.f := NIL; SQ.time := 0; Viewers.Broadcast(SQ); RETURN SQ.f
  80.     END Selected;
  81.     PROCEDURE This*(x, y: INTEGER): Frame;
  82.         VAR PQ: PosQuery;
  83.     BEGIN PQ.f := NIL; PQ.x := x; PQ.y := y; Viewers.Broadcast(PQ); RETURN PQ.f
  84.     END This;
  85.     PROCEDURE Draw*(F: Frame);
  86.         VAR UM: UpdateMsg;
  87.     BEGIN UM.id := drawsel; UM.graph := F.graph; Viewers.Broadcast(UM)
  88.     END Draw;
  89.     PROCEDURE DrawNorm(F: Frame);
  90.         VAR UM: UpdateMsg;
  91.     BEGIN UM.id := drawnorm; UM.graph := F.graph; Viewers.Broadcast(UM)
  92.     END DrawNorm;
  93.     PROCEDURE Erase*(F: Frame);
  94.         VAR UM: UpdateMsg;
  95.     BEGIN UM.id := drawdel; UM.graph := F.graph; Viewers.Broadcast(UM)
  96.     END Erase;
  97.     PROCEDURE DrawObj*(F: Frame; obj: Graphics.Object);
  98.         VAR UM: UpdateMsg;
  99.     BEGIN UM.id := drawobj; UM.graph := F.graph; UM.obj := obj; Viewers.Broadcast(UM)
  100.     END DrawObj;
  101.     PROCEDURE EraseObj*(F: Frame; obj: Graphics.Object);
  102.         VAR UM: UpdateMsg;
  103.     BEGIN UM.id := drawobjd; UM.graph := F.graph; UM.obj := obj; Viewers.Broadcast(UM)
  104.     END EraseObj;
  105.     PROCEDURE Change*(F: Frame; VAR msg: Graphics.Msg);
  106.     BEGIN
  107.         IF F # NIL THEN Erase(F); Graphics.Handle(F.graph, msg); Draw(F) END
  108.     END Change;
  109.     PROCEDURE FlipMark(x, y: INTEGER);
  110.     BEGIN
  111.         Display.ReplConst(Display.white, x-7, y, 15, 1, 2);
  112.         Display.ReplConst(Display.white, x, y-7, 1, 15, 2)
  113.     END FlipMark;
  114.     PROCEDURE Defocus*(F: Frame);
  115.         VAR m: Location;
  116.     BEGIN newcap := NIL;
  117.         IF F.marked THEN
  118.             FlipMark(F.mark.x, F.mark.y); m := F.mark.next;
  119.             WHILE m # NIL DO FlipMark(m.x, m.y); m := m.next END ;
  120.             F.marked := FALSE; F.mark.next := NIL
  121.         END
  122.     END Defocus;
  123.     PROCEDURE Deselect*(F: Frame);
  124.         VAR UM: UpdateMsg;
  125.     BEGIN
  126.         IF F # NIL THEN
  127.             UM.id := drawnorm; UM.graph := F.graph; Viewers.Broadcast(UM);
  128.             Graphics.Deselect(F.graph)
  129.         END
  130.     END Deselect;
  131.     PROCEDURE Macro*(VAR Lname, Mname: ARRAY OF CHAR);
  132.         VAR x, y: INTEGER;
  133.             F: Frame;
  134.             mac: Graphics.Macro; mh: Graphics.MacHead;
  135.             L: Graphics.Library;
  136.     BEGIN F := Focus();
  137.         IF F # NIL THEN
  138.             x := F.mark.x - F.x; y := F.mark.y - F.y;
  139.             L := Graphics.ThisLib(Lname, FALSE);
  140.             IF L # NIL THEN
  141.                 mh := Graphics.ThisMac(L, Mname);
  142.                 IF mh # NIL THEN
  143.                     Deselect(F); Defocus(F);
  144.                     NEW(mac); mac.x := x; mac.y := y; mac.w := mh.w; mac.h := mh.h;
  145.                     mac.mac := mh; mac.do := Graphics.MacMethod; mac.col := Oberon.CurCol;
  146.                     Graphics.Add(F.graph, mac); DrawObj(F, mac)
  147.                 END
  148.             END
  149.         END
  150.     END Macro;
  151.     PROCEDURE CaptionCopy(F: Frame;
  152.             x1, y1: INTEGER; T: Texts.Text; beg, end: LONGINT): Graphics.Caption;
  153.         VAR ch: CHAR;
  154.             dx, w, x2, y2, w1, h1: INTEGER;
  155.             cap: Graphics.Caption;
  156.             pat: Display.Pattern;
  157.             R: Texts.Reader;
  158.     BEGIN Texts.Write(W, 0DX);
  159.         NEW(cap); cap.len := SHORT(end - beg);
  160.         cap.pos := SHORT(Graphics.T.len)+1; cap.do := Graphics.CapMethod;
  161.         Texts.OpenReader(R, T, beg); Texts.Read(R, ch); W.fnt := R.fnt; W.col := R.col; w := 0;
  162.         cap.x := x1 - F.x; cap.y := y1 - F.y + R.fnt.minY;
  163.         WHILE beg < end DO
  164.             Display.GetChar(R.fnt.raster, ch, dx, x2, y2, w1, h1, pat);
  165.             INC(w, dx); INC(beg); Texts.Write(W, ch); Texts.Read(R, ch)
  166.         END ;
  167.         cap.w := w; cap.h := W.fnt.height; cap.col := W.col;
  168.         Texts.Append(Graphics.T, W.buf); Graphics.Add(F.graph, cap); RETURN cap
  169.     END CaptionCopy;
  170.     PROCEDURE SendCaption(cap: Graphics.Caption);
  171.         VAR M: Oberon.CopyOverMsg;
  172.     BEGIN
  173.         M. text := Graphics.T; M.beg := cap.pos; M.end := M.beg + cap.len; Viewers.Broadcast(M)
  174.     END SendCaption;
  175.     PROCEDURE Edit(F: Frame; x0, y0: INTEGER; k0: SET);
  176.         VAR obj: Graphics.Object;
  177.             x1, y1, w, h, t: INTEGER;
  178.             beg, end, time: LONGINT;
  179.             k1, k2: SET;
  180.             mark, newmark: Location;
  181.             T: Texts.Text;
  182.             Fd: Frame;
  183.             G: Graphics.Graph;
  184.             CM: CtrlMsg;
  185.         PROCEDURE NewLine(x, y, w, h: INTEGER);
  186.             VAR line: Graphics.Line;
  187.         BEGIN NEW(line); line.col := Oberon.CurCol; line.x := x - F.x; line.y := y - F.y;
  188.             line.w := w; line.h := h; line.do := Graphics.LineMethod; Graphics.Add(G, line)
  189.         END NewLine;
  190.     BEGIN k1 := k0; G := F.graph;
  191.         IF k0 = {1} THEN
  192.             obj := Graphics.ThisObj(G, x0 - F.x, y0 - F.y);
  193.             IF (obj # NIL) & ~obj.selected THEN
  194.                 CM.f := F; CM.res := 0; obj.do.handle(obj, CM);
  195.                 IF CM.res # 0 THEN (*done*) k0 := {} END
  196.             END
  197.         END ;
  198.         REPEAT Input.Mouse(k2, x1, y1); k1 := k1 + k2;
  199.             DEC(x1, (x1-F.x) MOD 4); DEC(y1, (y1-F.y) MOD 4);
  200.             Oberon.DrawCursor(Oberon.Mouse, Oberon.Arrow, x1, y1)
  201.         UNTIL  k2 = {};
  202.         Oberon.FadeCursor(Oberon.Mouse);
  203.         IF k0 = {2} THEN (*left key*)
  204.             w := ABS(x1-x0); h := ABS(y1-y0);
  205.             IF k1 = {2} THEN
  206.                 IF (w < 7) & (h < 7) THEN (*set mark*)
  207.                     IF (x1 - markW >= F.X) & (x1 + markW < F.X1) &
  208.                         (y1 - markW >= F.Y) & (y1 + markW < F.Y1) THEN
  209.                         Defocus(F); Oberon.PassFocus(Viewers.This(F.X, F.Y));
  210.                         F.mark.x := x1; F.mark.y := y1; F.marked := TRUE; FlipMark(x1, y1)
  211.                     END
  212.                 ELSE (*draw line*) Deselect(F);
  213.                     IF w < h THEN
  214.                         IF y1 < y0 THEN y0 := y1 END ;
  215.                         NewLine(x0, y0, Graphics.width, h)
  216.                     ELSE
  217.                         IF x1 < x0 THEN x0 := x1 END ;
  218.                         NewLine(x0, y0, w, Graphics.width)
  219.                     END ;
  220.                     Draw(F)
  221.                 END
  222.             ELSIF k1 = {2, 1} THEN (*copy selection to caret mark*)
  223.                 Deselect(F); Oberon.GetSelection(T, beg, end, time);
  224.                 IF time >= 0 THEN DrawObj(F, CaptionCopy(F, x1, y1, T, beg, end)) END
  225.             ELSIF k1 = {2, 0} THEN
  226.                 IF F.marked THEN (*set secondary mark*)
  227.                         NEW(newmark); newmark.x := x1; newmark.y := y1; newmark.next := NIL;
  228.                     FlipMark(x1, y1); mark := F.mark.next;
  229.                     IF mark = NIL THEN F.mark.next := newmark ELSE
  230.                         WHILE mark.next # NIL DO mark := mark.next END ;
  231.                         mark.next := newmark
  232.                     END
  233.                 END
  234.             END
  235.         ELSIF k0 = {1} THEN (*middle key*)
  236.             IF k1 = {1} THEN (*move*)
  237.                 IF (x0 # x1) OR (y0 # y1) THEN
  238.                     Fd := This(x1, y1); Erase(F);
  239.                     IF Fd = F THEN Graphics.Move(G, x1-x0, y1-y0)
  240.                     ELSIF (Fd # NIL) & (Fd.graph = G) THEN
  241.                         Graphics.Move(G, (x1-Fd.x-x0+F.x) DIV 4 * 4, (y1-Fd.y-y0+F.y) DIV 4 * 4)
  242.                     END ;
  243.                     Draw(F)
  244.                 END
  245.             ELSIF k1 = {1, 2} THEN (*copy*)
  246.                 Fd := This(x1, y1);
  247.                 IF Fd # NIL THEN DrawNorm(F);
  248.                     IF Fd = F THEN Graphics.Copy(G, G, x1-x0, y1-y0)
  249.                     ELSE Deselect(Fd);
  250.                         Graphics.Copy(G, Fd.graph, (x1-Fd.x-x0+F.x) DIV 4 * 4, (y1-Fd.y-y0+F.y) DIV 4 * 4)
  251.                     END ;
  252.                     Draw(Fd)
  253.                 END
  254.             ELSIF k1 = {1, 0} THEN (*shift graph origin*)
  255.                 INC(F.Xg, x1-x0); INC(F.Yg, y1-y0); Restore(F)
  256.             END
  257.         ELSIF k0 = {0} THEN (*right key: select*)
  258.             newcap := NIL;
  259.             IF (ABS(x0-x1) < 7) & (ABS(y0-y1) < 7) THEN
  260.                 IF ~(2 IN k1) THEN Deselect(F) END ;
  261.                 obj := Graphics.ThisObj(G, x1 - F.x, y1 - F.y);
  262.                 IF obj # NIL THEN
  263.                     Graphics.SelectObj(G, obj); DrawObj(F, obj);
  264.                     IF (k1 = {0, 1}) & (obj IS Graphics.Caption) THEN
  265.                         SendCaption(obj(Graphics.Caption))
  266.                     END
  267.                 END
  268.             ELSE Deselect(F);
  269.                 IF x1 < x0 THEN t := x0; x0 := x1; x1 := t END ;
  270.                 IF y1 < y0 THEN t := y0; y0 := y1; y1 := t END ;
  271.                 Graphics.SelectArea(G, x0 - F.x, y0 - F.y, x1 - F.x, y1 - F.y); Draw(F)
  272.             END
  273.         END
  274.     END Edit;
  275.     PROCEDURE NewCaption(F: Frame; col: INTEGER; font: Fonts.Font);
  276.     BEGIN Texts.Write(W, 0DX);
  277.         NEW(newcap); newcap.x := F.mark.x - F.x; newcap.y := F.mark.y - F.y + font.minY;
  278.         newcap.w := 0; newcap.h := font.height; newcap.col := col;
  279.         newcap.pos := SHORT(Graphics.T.len + 1); newcap.len := 0;
  280.         newcap.do := Graphics.CapMethod; Graphics.Add(F.graph, newcap); W.fnt := font
  281.     END NewCaption;
  282.     PROCEDURE InsertChar(F: Frame; ch: CHAR);
  283.         VAR w1, h1: INTEGER; DM: DispMsg;
  284.     BEGIN DM.graph := F.graph;
  285.         Display.GetChar(W.fnt.raster, ch, DM.w, DM.x1, DM.y1, w1, h1, DM.pat); DEC(DM.y1, W.fnt.minY);
  286.         IF newcap.x + newcap.w + DM.w + F.x < F.X1 THEN
  287.             Viewers.Broadcast(DM); INC(newcap.w, DM.w); INC(newcap.len); Texts.Write(W, ch)
  288.         END ;
  289.         Texts.Append(Graphics.T, W.buf)
  290.     END InsertChar;
  291.     PROCEDURE DeleteChar(F: Frame);
  292.         VAR w1, h1: INTEGER; ch: CHAR; pos: LONGINT;
  293.             DM: DispMsg; R: Texts.Reader;
  294.     BEGIN DM.graph := F.graph;
  295.         IF newcap.len > 0 THEN
  296.             pos := Graphics.T.len; Texts.OpenReader(R, Graphics.T, pos-1);  (*backspace*)
  297.             Texts.Read(R, ch);
  298.             IF ch >= " " THEN
  299.                 Display.GetChar(R.fnt.raster, ch, DM.w, DM.x1, DM.y1, w1, h1, DM.pat);
  300.                 DEC(newcap.w, DM.w); DEC(newcap.len); DEC(DM.y1, R.fnt.minY);
  301.                 Viewers.Broadcast(DM); Texts.Delete(Graphics.T, pos-1, pos)
  302.             END
  303.         END
  304.     END DeleteChar;
  305.     PROCEDURE GetSelection(F: Frame; VAR text: Texts.Text; VAR beg, end, time: LONGINT);
  306.         VAR obj: Graphics.Object;
  307.     BEGIN obj := F.graph.sel;
  308.         IF (obj # NIL) & (obj IS Graphics.Caption) & (F.graph.time >= time) THEN
  309.             WITH obj: Graphics.Caption DO beg := obj.pos; end := obj.pos + obj.len END ;
  310.             text := Graphics.T; time := F.graph.time
  311.         END
  312.     END GetSelection;
  313.     PROCEDURE Handle*(G: Display.Frame; VAR M: Display.FrameMsg);
  314.         VAR x, y: INTEGER;
  315.             DM: DispMsg; dM: DrawMsg;
  316.             G1: Frame;
  317.         PROCEDURE move(G: Frame; dx, dy: INTEGER);
  318.             VAR M: UpdateMsg;
  319.         BEGIN Defocus(G); Oberon.FadeCursor(Oberon.Mouse);
  320.             M.id := drawdel; M.graph := G.graph;  Viewers.Broadcast(M);
  321.             Graphics.Move(G.graph, dx, dy); M.id := drawsel; Viewers.Broadcast(M)
  322.         END move;
  323.     BEGIN
  324.         WITH G: Frame DO
  325.             IF M IS Oberon.InputMsg THEN
  326.                 WITH M: Oberon.InputMsg DO
  327.                     IF M.id = Oberon.track THEN
  328.                         x := M.X - (M.X - G.x) MOD 4; y := M.Y - (M.Y - G.y) MOD 4;
  329.                         IF M.keys # {} THEN Edit(G, x, y, M.keys)
  330.                         ELSE Oberon.DrawCursor(Oberon.Mouse, Oberon.Arrow, x, y)
  331.                         END
  332.                     ELSIF M.id = Oberon.consume THEN
  333.                         IF M.ch = 7FX THEN
  334.                             IF newcap # NIL THEN DeleteChar(G)
  335.                             ELSE Oberon.FadeCursor(Oberon.Mouse); Defocus(G); Erase(G); Graphics.Delete(G.graph)
  336.                             END
  337.                         ELSIF M.ch = 91X THEN Restore(G)
  338.                         ELSIF M.ch = 93X THEN G.Xg := -1; G.Yg := 0; Restore(G)  (*reset*)
  339.                         ELSIF M.ch = 0C1X THEN move(G, 0, 1)
  340.                         ELSIF M.ch = 0C2X THEN move(G, 0, -1)
  341.                         ELSIF M.ch = 0C3X THEN move(G, 1, 0)
  342.                         ELSIF M.ch = 0C4X THEN move(G, -1, 0)
  343.                         ELSIF (M.ch >= 20X) & (M.ch <0B0X) THEN
  344.                             IF newcap # NIL THEN InsertChar(G, M.ch)
  345.                             ELSIF G.marked THEN
  346.                                 Defocus(G); Deselect(G); NewCaption(G, M.col, M.fnt); InsertChar(G, M.ch)
  347.                             END
  348.                         END
  349.                     END
  350.                 END
  351.             ELSIF M IS UpdateMsg THEN
  352.                 WITH M: UpdateMsg DO
  353.                     IF M.graph = G.graph THEN
  354.                         dM.f := G; dM.x := G.x; dM.y := G.y; dM.col := 0;
  355.                         CASE M.id OF
  356.                           restore: Restore(G)
  357.                         | drawobj:  dM.mode := 0; M.obj.do.draw(M.obj, dM)
  358.                         | drawobjs: dM.mode := 1; M.obj.do.draw(M.obj, dM)
  359.                         | drawobjd: dM.mode := 3; M.obj.do.draw(M.obj, dM)
  360.                         | drawsel:  dM.mode := 0; Graphics.DrawSel(G.graph, dM)
  361.                         | drawnorm: dM.mode := 2; Graphics.DrawSel(G.graph, dM)
  362.                         | drawdel:  dM.mode := 3; Graphics.DrawSel(G.graph, dM)
  363.                         END
  364.                     END
  365.                 END
  366.             ELSIF M IS SelQuery THEN
  367.                 WITH M: SelQuery DO
  368.                     IF (G.graph.sel # NIL) & (M.time < G.graph.time) THEN
  369.                         M.f := G; M.time := G.graph.time
  370.                     END
  371.                 END
  372.             ELSIF M IS FocusQuery THEN
  373.                 IF G.marked THEN M(FocusQuery).f := G END
  374.             ELSIF M IS PosQuery THEN
  375.                 WITH M: PosQuery DO
  376.                     IF (G.X <= M.x) & (M.x < G.X1) & (G.Y <= M.y) & (M.y < G.Y1) THEN M.f := G END
  377.                 END
  378.             ELSIF M IS DispMsg THEN
  379.                 DM := M(DispMsg);
  380.                 x := G.x + newcap.x + newcap.w; y := G.y + newcap.y;
  381.                 IF (DM.graph = G.graph) & (x >= G.X) & (x + DM.w < G.X1) & (y >= G.Y) & (y < G.Y1) THEN
  382.                     Display.CopyPattern(Oberon.CurCol, DM.pat, x + DM.x1, y + DM.y1, 2);
  383.                     Display.ReplConst(Display.white, x, y, DM.w, newcap.h, 2)
  384.                 END
  385.             ELSIF M IS Oberon.ControlMsg THEN
  386.                 WITH M: Oberon.ControlMsg DO
  387.                     IF M.id = Oberon.neutralize THEN
  388.                         Oberon.RemoveMarks(G.X, G.Y, G.W, G.H); Defocus(G);
  389.                         DrawNorm(G); Graphics.Deselect(G.graph)
  390.                     ELSIF M.id = Oberon.defocus THEN Defocus(G)
  391.                     END
  392.                 END
  393.             ELSIF M IS Oberon.SelectionMsg THEN
  394.                 WITH M: Oberon.SelectionMsg DO GetSelection(G, M.text, M.beg, M.end, M.time) END
  395.             ELSIF M IS Oberon.CopyMsg THEN
  396.                 Oberon.RemoveMarks(G.X, G.Y, G.W, G.H); Defocus(G);
  397.                 NEW(G1); G1^ := G^; M(Oberon.CopyMsg).F := G1
  398.             ELSIF M IS MenuViewers.ModifyMsg THEN
  399.                 WITH M: MenuViewers.ModifyMsg DO G.Y := M.Y; G.H := M.H; Restore(G) END
  400.             ELSIF M IS Oberon.CopyOverMsg THEN
  401.                 WITH M: Oberon.CopyOverMsg DO
  402.                     IF G.marked THEN
  403.                         DrawObj(G, CaptionCopy(G, G.mark.x, G.mark.y, M.text, M.beg, M.end))
  404.                     END
  405.                 END
  406.             END
  407.         END
  408.     END Handle;
  409.     (*------------------- Methods -----------------------*)
  410.     PROCEDURE DrawLine(obj: Graphics.Object; VAR M: Graphics.Msg);
  411.         (*M.mode = 0: draw according to state,
  412.                 = 1: normal -> selected,
  413.                 = 2: selected -> normal,
  414.                 = 3: erase*)
  415.         VAR x, y, w, h, col: INTEGER; f: Frame;
  416.     BEGIN 
  417.         WITH M: DrawMsg DO
  418.             x := obj.x + M.x; y := obj.y + M.y; w := obj.w; h := obj.h; f := M.f;
  419.             IF (x+w > f.X) & (x < f.X1) & (y+h > f.Y) & (y < f.Y1) THEN
  420.                 IF M.col = Display.black THEN col := obj.col ELSE col := M.col (*macro*) END ;
  421.                 IF (M.mode = 0) & obj.selected OR (M.mode = 1) THEN
  422.                     Display.ReplPatternC(f, col, Display.grey2, x, y, w, h, x, y, 0)
  423.                 ELSIF M.mode = 3 THEN Display.ReplConstC(f, f.col, x, y, w, h, 0)  (*erase*)
  424.                 ELSE Display.ReplConstC(f, col, x, y, w, h, 0)
  425.                 END
  426.             END
  427.         END
  428.     END DrawLine;
  429.     PROCEDURE DrawCaption(obj: Graphics.Object; VAR M: Graphics.Msg);
  430.         VAR x, y, dx, x0, x1, y0, y1, w, h, w1, h1, col: INTEGER;
  431.             f: Frame;
  432.             ch: CHAR; pat: Display.Pattern; fnt: Fonts.Font;
  433.             R: Texts.Reader;
  434.     BEGIN
  435.         WITH M: DrawMsg DO
  436.             x := obj.x + M.x; y := obj.y + M.y; w := obj.w; h := obj.h; f := M.f;
  437.             IF (f.X <= x) & (x <= f.X1) & (f.Y <= y) & (y+h <= f.Y1) THEN
  438.                 IF x+w > f.X1 THEN w := f.X1-x END ;
  439.                 Texts.OpenReader(R, Graphics.T, obj(Graphics.Caption).pos); Texts.Read(R, ch);
  440.                 IF M.mode = 0 THEN
  441.                     IF ch >= " " THEN
  442.                         IF M.col = Display.black THEN col := obj.col ELSE col := M.col (*macro*) END ;
  443.                         fnt := R.fnt; x0 := x; y0 := y - fnt.minY;
  444.                         LOOP
  445.                             Display.GetChar(fnt.raster, ch, dx, x1, y1, w1, h1, pat);
  446.                             IF x0+x1+w1 <= f.X1 THEN Display.CopyPattern(col, pat, x0+x1, y0+y1, 1) ELSE EXIT END ;
  447.                             INC(x0, dx); Texts.Read(R, ch);
  448.                             IF ch < " " THEN EXIT END
  449.                         END ;
  450.                         IF obj.selected THEN Display.ReplConst(Display.white, x, y, w, h, 2) END
  451.                     END
  452.                 ELSIF M.mode < 3 THEN Display.ReplConst(Display.white, x, y, w, h, 2)
  453.                 ELSE Display.ReplConst(f.col, x, y, w, h, 0)
  454.                 END
  455.             END
  456.         END
  457.     END DrawCaption;
  458.     PROCEDURE DrawMacro(obj: Graphics.Object; VAR M: Graphics.Msg);
  459.         VAR x, y, w, h: INTEGER;
  460.             f: Frame; M1: DrawMsg;
  461.     BEGIN
  462.         WITH M: DrawMsg DO
  463.             x := obj.x + M.x; y := obj.y + M.y; w := obj.w; h := obj.h; f := M.f;
  464.             IF (x+w > f.X) & (x < f.X1) & (y+h > f.Y) & (y < f.Y1) THEN
  465.                 M1.x := x; M1.y := y;
  466.                 IF M.mode = 0 THEN
  467.                     M1.f := f; M1.col := obj.col; M1.mode := 0; Graphics.DrawMac(obj(Graphics.Macro).mac, M1);
  468.                     IF obj.selected THEN Display.ReplConstC(f, Display.white, x, y, w, h, 2) END
  469.                 ELSIF M.mode < 3 THEN Display.ReplConstC(f, Display.white, x, y, w, h, 2)
  470.                 ELSE Display.ReplConstC(f, f.col, x, y, w, h, 0)
  471.                 END
  472.             END
  473.         END
  474.     END DrawMacro;
  475.     (*---------------------------------------------------------------*)
  476.     PROCEDURE Open*(G: Frame; graph: Graphics.Graph; X, Y, col: INTEGER; ticked: BOOLEAN); 
  477.     BEGIN G.graph := graph; G.Xg := X; G.Yg := Y; G.col := col; G.marked := FALSE;
  478.         G.mark.next := NIL; G.ticked := ticked; G.handle := Handle
  479.     END Open;
  480. BEGIN DW := Display.Width - 8; DH := Display.Height - 8; CL := Display.ColLeft;
  481.     Texts.OpenWriter(W);
  482.     Graphics.LineMethod.draw := DrawLine; Graphics.CapMethod.draw := DrawCaption;
  483.     Graphics.MacMethod.draw := DrawMacro
  484. END GraphicFrames.
  485.