home *** CD-ROM | disk | FTP | other *** search
/ Amiga MA Magazine 1998 #6 / amigamamagazinepolishissue1998.iso / coders / jËzyki_programowania / ace_basic / ace / include / play_sound.h < prev    next >
Text File  |  1977-12-31  |  3KB  |  176 lines
  1. { 
  2.   << play a sound file! >>
  3.  
  4.   Currently handles IFF 8SVX format.
  5.   If format is unknown, a default 
  6.   sampling rate is assumed. 
  7.   
  8.   Author: David J Benn
  9.     Date: 6th,7th April,16th May,
  10.       30th June,
  11.       1st,3rd,4th,8th July,
  12.       22nd November 1992,
  13.       7th January 1993
  14. }
  15.  
  16. library exec
  17.  
  18. declare function AllocMem& library exec
  19. declare function FreeMem   library exec
  20. declare function xRead&       library dos
  21.  
  22. const NOTOK=-1
  23. const OK=0
  24.  
  25. longint offset&,samples_per_second&
  26.  
  27. SUB parse_sample(f$)
  28. shared offset&,samples_per_second&
  29. const default_rate=10000&
  30.  
  31.  { if IFF 8SVX sample, return
  32.    offset from start of file to
  33.    sample data and sampling rate in
  34.    samples per second. }
  35.  
  36.  open "I",1,f$
  37.  
  38.  '..FORM#### ?
  39.  dummy$ = input$(8,#1)
  40.  
  41.  '..8SVX ?
  42.  x$ = input$(4,#1)
  43.  if x$="8SVX" then
  44.    sample_format$="IFF 8SVX"
  45.  
  46.    '..skip VHDR###
  47.    dummy$ = input$(8,#1)
  48.  
  49.    '..skip ULONGs x 3 
  50.    dummy$ = input$(12,#1)
  51.  
  52.    '..get sampling rate bytes
  53.    hi%=asc(input$(1,#1))  '..high byte
  54.    lo%=asc(input$(1,#1))  '..low byte
  55.    samples_per_second&=hi%*256 + lo%
  56.  
  57.    '..find BODY
  58.    '..skip rest of Voice8Header structure
  59.    dummy$ = input$(6,#1)
  60.  
  61.    offset&=40  '..bytes up to this point
  62.    repeat 
  63.     repeat
  64.       x$=input$(1,#1)
  65.       offset&=offset&+1
  66.     until x$="B" and not eof(1)
  67.     if not eof(1) then
  68.       body$=input$(3,#1)
  69.       offset&=offset&+3
  70.     end if
  71.    until body$="ODY" and not eof(1) 
  72.  
  73.    if not eof(1) then
  74.      x$=input$(4,#1)  '..skip ####   
  75.      offset&=offset&+4
  76.    else
  77.      close 1
  78.      parse_sample=NOTOK
  79.      exit sub
  80.    end if
  81.    close 1
  82.  else
  83.    close 1
  84.    sample_format$="unknown"
  85.    offset&=0
  86.    samples_per_second&=default_rate
  87.    parse_sample=OK
  88.  end if
  89.  
  90. END SUB
  91.  
  92.  
  93. SUB play_sound(f$)
  94. shared offset&,samples_per_second&
  95. const maxsample=131070
  96. const channel=1
  97.  
  98. dim   wave_ptr&(100)
  99.  
  100. '..file size?
  101. open "I",1,f$
  102. f_size&=lof(1)
  103. close 1
  104.  
  105. if f_size&=0 then 
  106.   play_sound=NOTOK
  107.   library close exec
  108.   exit sub
  109. end if
  110.  
  111. '..parse the sample
  112. if parse_sample(f$) = NOTOK then
  113.   play_sound=NOTOK
  114.   library close exec
  115.   exit sub
  116. end if
  117.  
  118. '..get the sample bytes
  119. buffer&=AllocMem(f_size&,MEMF_CHIP) '...f_size& bytes of CHIP RAM
  120. if buffer& = NULL then 
  121.   avail&=fre(MEMF_CHIP)  '..max. contiguous CHIP RAM
  122.   play_sound=NOTOK
  123.   library close exec
  124.   exit sub
  125. end if
  126.  
  127. '..read whole sample
  128. open "I",1,f$  
  129. fh&=handle(1)
  130. if fh&=0 then clean.up
  131. bytes&=xRead(fh&,buffer&,f_size&)
  132. close 1
  133.  
  134. '..calculate period
  135. per& = 3579546 \ samples_per_second&  
  136.   
  137. '...setup waveform table for voice 0
  138. sz&=f_size&-offset&
  139.  
  140. if sz& <= maxsample then
  141.   '..play it in one go
  142.   wave channel,buffer&+offset&,sz&
  143.   dur&=.279365*per&*bytes&/1e6*18.2
  144.   sound per&,dur&,,channel
  145. else
  146.   segments&=sz&\maxsample
  147.   buf&=buffer&+offset&
  148.  
  149.   '..get the segment pointers
  150.   for i&=0 to segments&
  151.     wave_ptr&(i&)=buf&+maxsample*i&
  152.   next
  153.  
  154.   '..play sample in segments
  155.   for i&=0 to segments&
  156.     if sz& >= maxsample then 
  157.        wave channel,wave_ptr&(i&),maxsample 
  158.        bytes&=maxsample
  159.     else 
  160.        wave channel,wave_ptr&(i&),sz&
  161.        bytes&=sz&
  162.     end if
  163.     dur&=.279365*per&*bytes&/1e6*18.2
  164.     sound per&,dur&,,channel
  165.     sz&=sz&-maxsample
  166.   next   
  167. end if
  168.   
  169. clean.up:
  170.  FreeMem(buffer&,f_size&)
  171.  library close exec
  172.  
  173.  play_sound=OK
  174.  
  175. END SUB
  176.